Télécharger la plaquette Cast3M


fr en

Télécharger fsi4.dgibi

Retour à la liste

Numérotation des lignes : 

  1.  
  2. ************************************************************************
  3. ************************************************************************
  4. * fichier :  fsi4.dgibi
  5. *           Test Fsi4.dgibi: Jeux de données          *
  6. *           --------------------------------          *
  7. * CAS TEST DU 91/10/04     PROVENANCE : PETI
  8.  
  9. *******************************************
  10. *    Test fsi4.dgibi: jeux de données     *
  11. *    ---------------------------------    *
  12. *******************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22.   OPTI ECHO 1   ;
  23.   OPTI TRAC X   ;
  24. SINO ;
  25.   OPTI ECHO 0   ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *******************************************
  30. *                                         *
  31. *                TEST FSI4                *
  32. *                                         *
  33. *   CONCENTRIC SHELLS COUPLED BY FLUID    *
  34. *                                         *
  35. *  Calculation of the frequencies of two  *
  36. * concentric shells with springs coulped  *
  37. * by water in between. The inner radius   *
  38. * is 0.5m and the outer radius is 1.0m    *
  39. *                                         *
  40. *                                         *
  41. *                P5          P7           *
  42. *                 |         |             *
  43. *                 |         |             *
  44. *                 |         |             *
  45. *                 |  fluid  |             *
  46. *                 |         |             *
  47. *                 |         |             *
  48. *                 |         |             *
  49. *                 |         |             *
  50. *          ^^^^^^^ ^^^^^^^^^ ^^^^^^^      *
  51. *            K   P6    K   P8   K         *
  52. *                                         *
  53. *  The boundary conditions are            *
  54. *                                         *
  55. *      dp  |                              *
  56. *     ---- |                 = 0.         *
  57. *      dz  | h = 0. , 1.0                 *
  58. *                                         *
  59. *      dp  |                              *
  60. *     ---- |                 = 0.         *
  61. *      dr  | r = Ri , Ro                  *
  62. *******************************************
  63.  
  64. TEMPS;
  65.  
  67. OPTI MODE FOUR 1  ;
  68. OPTI ELEM QUA4;
  69.  
  70. *=========================================*
  71. *               geometry                  *
  72. *=========================================*
  73.  
  74. * Dimensions en mm
  75.  
  76. * Points
  77. P0 = 0. 0. ;
  78. N1 = 1        ; N2 = 1           ;
  79. P5 = 500.0 1000.0 ; P6 = 500.0 0.0 ;
  80. P7 = 1000. 1000.0 ; P8 = 1000. 0.0 ;
  81.  
  82. S5 =P5 D N1 P6 ; S6 = P8 D N1 P7 ;
  83.  
  84. STEEL = S5 ET S6                 ;
  85. WATER = (S5 PLUS (2.5 0.))  
  86.           TRAN N2 (495.0 0. )    ;
  87. RAC1  = RACC 3.0   WATER STEEL   ;
  88.  
  89. * OPTIO FOR TRACE
  90.  
  91. SI (NEG GRAPH 'N');
  92.   TITR ' FSI4 : MAILLAGE';
  93.   TRAC QUAL (WATER ET P0);
  94. FINSI;
  95.  
  96. *=========================================*
  97. *    modele - affecte - materiau
  98. *    rigidite - masse                     *
  99. *=========================================*
  100.  
  101. MODCOQ = MODE STEEL MECANIQUE COQ2 ;
  102. MODLIQ = MODE WATER LIQUIDE   LQU4;
  103. MODRAC = MODE RAC1 MECANIQUE  LIQUIDE RACO;
  104.  
  105. MATCOQ = MATE MODCOQ RHO 8.E-9  YOUN 2.E5  
  106.                      NU 0.3 ;
  107. MATLIQ = MATE (MODLIQ ET MODRAC)
  108.                RHO 1.E-9  RORF 1.E-9  
  109.                CSON 1435.0E3 CREF 1435.0E3 
  110.                LCAR 1000.    G 0.;
  111. CARCOQ = CARA MODCOQ EPAI 5.0  ;
  112. CARRAC = CARA MODRAC LIQU WATER;
  113. MATCOQ = MATCOQ ET CARCOQ;
  114. MATLIQ = MATLIQ ET CARRAC;
  115.  
  116. K     = 3.7458E4/2.0;
  117. PPNEW = PROG K ( -1*K) ( -1*K) K;
  118. RIG1  = RIGI  (MODCOQ ET MODLIQ ET MODRAC)
  119.               (MATCOQ ET MATLIQ)   ;
  120. MAS4 = MASS   (MODRAC ET MODLIQ  )(MATLIQ);
  121.  
  122. *=========================================*
  123. *                boundary conditions      *
  124. *=========================================*
  125.  
  126. RES1 = BLOQ UZ RT  (S5 ET S6)        ;
  127. RIG2 = (APPU UR UT K P8 ) ET 
  128.        (APPU UR UT K P6 ) ;
  129. RIG3 = ( MANU 'RIGI' type 'RIGIDITE' 
  130.         (P6 D 1 P8) (MOTS UR)  PPNEW )
  131.     ET ( MANU 'RIGI' type 'RIGIDITE' 
  132.         (P6 D 1 P8) (MOTS UT)  PPNEW );
  133. RIG4 = RIG1 ET RIG2 ET RIG3;
  134.  
  135. * theoretical value  of frequency
  136.  
  137. FRE1  = TABLE ;
  138. FRE1.1 = 18.88 ;
  139. FRE1.2 = 55.278;
  140. LIST1 = PROG FRE1.1 FRE1.2 ;             ;
  141.  
  142. *=========================================*
  143. *    calculation of the frequencies       *
  144. *                  and                    *
  145. *      extraction of some results         *
  146. *=========================================*
  147.  
  148. * Use of the operator VIBR. (option PROC)
  149.  
  150. RESUL = VIBR PROC LIST1 (RES1 ET RIG4 )  MAS4  ;
  151.  
  152. *=========================================*
  153. *                   results               *
  154. *=========================================*
  155.  
  156. MESS ' RESULTATS ';
  157. MESS ' --------- ';
  159.  
  160. FRE2 = TABL;
  161. MOD  = TABL;
  162. DEF  = TABL;
  163. ERG  = TABL;
  164.  
  165. I = 0;
  166. REPETER BLOC1 2;
  167.   I = I + 1;
  168.   FRE2.I = RESUL . MODES . I . FREQUENCE;
  169.   ERG.I = 100 * 
  170.         (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  171.   MESS ' MODE '  I     ;
  172.   MESS ' ----------';
  173.   MESS 'Frequence theorique :' FRE1.I 'Hz';
  174.   MESS 'Frequence calculee  :' FRE2.I 'Hz';
  175.   MESS '    Soit un ecart de : ' ERG.I '%';
  177. FIN BLOC1;
  178.  
  179. *=========================================*
  180. *                   code validation       *
  181. *=========================================*
  182.  
  183. ERGMAX = MAXI (PROG ERG.1 ERG.2 );
  184.  
  185. SI (ERGMAX <EG 5.);
  186.    ERRE 0;
  187. SINON;
  188.    ERRE 5;
  189. FINSI;
  190.  
  192. TEMPS;
  194.  
  195. FIN;
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  
  202.  
  203.  
  204.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales