Télécharger la plaquette Cast3M


fr en

Télécharger four2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  four2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *           Test Four2.dgibi: Jeux de données         *
  5. *           ---------------------------------         *
  6. *                                                     *
  7.  
  8. *******************************************************
  9. *           Test four2.dgibi: Jeux de données         *
  10. *           ---------------------------------         *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21.   OPTI ECHO 1   ;
  22.   OPTI TRAC PSC   ;
  23. SINO ;
  24.   OPTI ECHO 0   ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *************************************************************************
  29. *  TEST FOUR2
  30. *
  31. *  CYLINDRE INFINI SOUS PRESSION EXTERNE(NU=0)
  32. *
  33. * Soit un cylindre infini soumis a une pression externe.
  34. *
  35. * Une analyse de flambage permet de determiner la charge critique 
  36. * associée aux 10 premiers modes de Fourier de la structure : 
  37. * (u = u°*cos(2*Teta) )
  38. * (u = u°*cos(3*Teta) )
  39. * (u = u°*cos(4*Teta) )
  40. * (u = u°*cos(5*Teta) )
  41. * ...
  42. * Les éléments utilisés sont des éléments massifs.
  43. *
  44. * Comparaison a une solution analytique
  45. *************************************************************************
  46. *
  47. TITRE 'CYLINDRE INFINI SOUS PRESSION EXTERNE';
  48. OPTI DIME 2 ELEM qua8 MODE FOUR 0;
  49. *
  50. *------------------ CONSTRUCTION DE LA GEOMETRIE ------------------------
  51. *
  52. PA1=999.5 0.;PB1=999.5 10.;PO1=0. 0.;PO2=0. 10.;
  53. PA2=1000.5 0.;PB2=1000.5 10.;
  54. L1 =  PA1 DROI 5 PA2;
  55. L2 =  PA2 DROI 19 PB2;
  56. L3 =  PB2 DROI 5 PB1;
  57. L4 =  PB1 DROI 19 PA1;
  58.  
  59. CYL = DALLER L1 L2 L3 L4 PLAN;
  60. SI (NEG GRAPH 'N');
  61.   TRAC 'QUAL' CYL;
  62. FINSI;
  63.  
  64. MOD1=MODE CYL MECANIQUE ELASTIQUE qua8;
  65.  
  66. *
  67. *--- DECLARATION DE FOURIER NOHARM POUR LES OBJETS QUI SERONT UTILISES --
  68. *------------- POUR PLUSIEURS NUMEROS D'HARMONIQUE ----------------------
  69. *
  70. OPTI MODE FOUR NOHARM;
  71. *
  72. *
  73. *-------------- CONDITIONS AUX LIMITES SYMETRIQUES ----------------------
  74. *
  75. SYMB=SYMT CYL DEPL PA1 PO1  0.05;
  76. SYMH=SYMT CYL DEPL PB1 PO2  0.05;
  77. CDL=SYMB ET SYMH;
  78. *
  79. *-------------- MATERIAU ET CARACTERISTIQUES ----------------------------
  80. *
  81. MAT =MATE MOD1 YOUN 20000. NU 0.;
  82. *
  83. *------ DECLARATION DE FOURIER MODE 0 POUR LE CALCUL DES CONTRAINTES ----
  84. *
  85. OPTI MODE FOUR 0;
  86.  
  87. FP=PRES MASS MOD1 1. L2 ;
  88. RIG=RIGI MOD1 MAT;
  89. *
  90. *
  91. AAA = RIG ET CDL et (bloq PA1 UT);
  92. U   = RESO AAA  FP ;
  93. SIG = SIGMA U MOD1 MAT;
  94. I   = 1;
  95. ERRMAX = 0.;
  96. REPE BOUC1 9;
  97.    I = I + 1;
  98. *
  99. *----- DECLARATION DE FOURIER MODE I POUR L'ANALYSE DE FLAMBAGE ---------
  100. *
  101.    OPTI MODE FOUR I;
  102.    MKSI = KSIGMA MOD1 MAT (SIG * -1.)  FLAM;
  103.    RIG  = RIGI MOD1 MAT ;
  104. *
  105. *--------- RECHERCHE DE LA 1ERE FREQUENCE PROPRE ------------------------
  106. *
  107.    MODF=VIBR PROC (PROG 0.01) (RIG ET CDL) MKSI;
  108.    W1 = MODF . MODES . 1 . FREQUENCE;
  109.    LAMBDA1=(W1 * 2. * PI) ** 2 * (SIGN W1);
  110.    LDUM = (20000./(1. - 0.))*((1./1000.)**3)/12.;
  111.    LTH1 = LDUM*I*I;   
  112.    ERR1   = (LTH1 - LAMBDA1)/LTH1*100;
  113.  
  114.    SAUT 1 LIGN ;
  115.    MESS 'Mode : ' I;
  116.    SAUT 1 LIGN ;
  117.    MESS '  K(SIG) SEUL  :   ON DOIT TROUVER LAMBDA=' LTH1;
  118.    MESS '                   LE CALCUL DONNE LAMBDA=' LAMBDA1;
  119.    MESS '     SOIT UN ECART DE                : ' ERR1 '%' ;
  120.    SAUT 1 LIGN ;
  121.  
  122.    ERRMAX = MAXI ABS (PROG ERRMAX ERR1);
  123. FIN BOUC1;
  124.  
  125. mess ' errmax vaut ' errmax '%';
  126. SI (ERRMAX < 1.4D0 );
  127.    ERRE 0;
  128. SINON ;
  129.    ERRE 5;
  130. FINSI;
  131.  
  132. FIN;
  133.  
  134.  
  135.  
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  
  142.  
  143.  
  144.  
  145.  
  146.  
  147.  
  148.  
  149.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales