Télécharger la plaquette Cast3M


fr en

Télécharger equ_chaleur2D_VF.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  equ_chaleur2D_VF.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ***********************************************************************
  5. * NOM         : equ_chaleur2D_VF.dgibi
  6. * ___
  7. *
  8. * DESCRIPTION : Solution stationnaire de l'équation de la chaleur  (2D)
  9. * ___________  
  10. *
  11. *               GEOMETRIE : Un carré
  12. *               ----------
  13. *
  14. *               y
  15. *                 ^   y=1
  16. *                 |------------
  17. *                 |           |
  18. *                 |           |
  19. *                 |           |
  20. *                 |x = 0      |x=1 
  21. *                 |           |    
  22. *                 |           |    
  23. *                O-----------------------------> x
  24. *                     y=0                                   
  25. *
  26. *
  27. *               EQUATIONS :
  28. *               ----------
  29. *
  30. *               - Equations :
  31. *
  32. *                  mu Laplacien(T) = 0 avec mu = 1 ici
  33. *                  
  34. *               - Conditions aux limites :
  35. *
  36. *                  conditions de von Neumann  sur tout le bord except en
  37. *                  (0;0); 
  38. *                  on prend la restriction de la solution exacte au bord
  39. *
  40. *               - Solution exacte :
  41. *
  42. *                  T(x,y)= alpha x + beta y + gamma xy + delta
  43. *
  44. *
  45. * DISCRETISATION : une méthode de Volume Finis d'ordre 2 en espace. 
  46. * ______________   
  47. *                 
  48. *                 
  49. *                 
  50. *
  51. *       Le maillage est construit avec l'opérateur SURF, il est perturbé
  52. *       par un bruit blanc gaussien.
  53. *
  54. * Opérateurs utilisés : PENT (methode 'DIAMANT')
  55. *                       LAPN (option VF implicite)
  56. *
  57. * RESOLUTION :     - Solveur BiCGStab
  58. * __________       - Préconditionneur ILU(0)
  59. *
  60. * TESTS EFFECTUES : Vérification de l'ordre 2 en espace de la méthode
  61. * _______________   (utilisation d'une norme pseudo-L2) et de la 
  62. *                   précision absolue sur le maillage le plus fin.
  63. *                   
  64. *                   
  65. *
  66. * LANGAGE     : GIBIANE-CASTEM 2000
  67. * AUTEUR      : A. Beccantini
  68. *               Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
  69. *               mél : gounand@semt2.smts.cea.fr
  70. ************************************************************************
  71. * VERSION    : v1, 15/04/02, version initiale
  72. * HISTORIQUE : v1, 15/04/02, création
  73. * HISTORIQUE :
  74. ************************************************************************
  75. * Prière de PRENDRE LE TEMPS de compléter les commentaires
  76. * en cas de modification de ce sous-programme afin de faciliter
  77. * la maintenance !
  78. ************************************************************************
  79.  interact= FAUX ;
  80.  complet = FAUX ;
  81.  graph   = FAUX ;
  82.  logxmgr = FAUX ;
  83. *
  84.  'OPTION' 'DIME' 2 'ELEM' QUA4 'MODE' 'PLAN' ;
  85.  'OPTION' 'ISOV' 'SULI' ;
  86.  'OPTION' 'ECHO' 0 ;
  87.  nbisov = 15 ;
  88.  'SI' ('NON' interact) ;
  89.    'OPTION' 'TRAC' 'PS' ;
  90.    'OPTION' 'ISOV' 'LIGNE' ;
  91.  'FINSI' ;  
  92. *
  93. ** Erreur Linfini entre deux Champoints.
  94. *
  95.  DEBPROC CALCERR vitp1*'CHPOINT' vit*'CHPOINT' ;
  96.     err = MAXI (vitp1 - vit) 'ABS' ;
  97.  FINPROC err ;
  98. *
  99. ** Erreur Pseudo L2 entre deux Champoints.
  100. *
  101. *
  102. * L2 = \sqrt{\frac{1}{vol} .
  103. *            \sum_{i} err_i^2 vol_i}
  104. *
  105.  DEBPROC CALCERR2 vitp1*'CHPOINT' vit*'CHPOINT' vol*'CHPOINT' ;
  106.    er2 = vitp1 '-' vit ;
  107.    compv  = 'EXTRAIRE' er2 'COMP' ;
  108.    er2 = 'PSCAL' er2 er2 compv compv ;
  109.    suppv  = 'EXTRAIRE' vol 'MAIL' ;
  110.    chpun = 'MANUEL' 'CHPO' suppv 1 'SCAL' 1 ;
  111.    voltot = 'XTY' chpun ('MOTS' 'SCAL') vol ('MOTS' 'SCAL') ;
  112.    error = 'XTY' er2 ('MOTS' 'SCAL') vol ('MOTS' 'SCAL') ;
  113.    error = error '/' voltot ;
  114.    error = error '**' 0.5 ;
  115.  FINPROC error ;
  116. *
  117. * Procédure paramétrée (raffinement)
  118. * renvoyant l'erreur en norme L2 sur la température.
  119. * On calcule une solution de l'équation de Laplace
  120. * (équations de la chaleur) ;
  121. *
  122.  'DEBPROC' CALCUL nraff*'ENTIER' ;
  123. *nraff=2 ;
  124. *
  125. * titre global pour les dessins
  126. *
  127.  titglob = 'CHAINE' ' ; nraff=' nraff ;
  128. *
  129. * Paramètres physiques
  130. *
  131. * 
  132.  cv=  1.0 ;
  133.  mu = 0.0 ;
  134.  kappa = 1.0 ;
  135.  rho = 1.0 ;
  136. *
  137. * Conditions aux limites et solution exacte:
  138. *
  139. * solex = (alpha '*' x) '+' (beta '*' y) '+' (gamma '*' x '*' y) '+'
  140. *         delta
  141. *
  142.  alpha = (** 2. 0.5) ;
  143.  beta  = (** 3. 0.5) ;
  144.  gamma = (** 5. 0.5)  ;
  145.  delta = (** 1.5 0.5) ;
  146. *
  147. *  Géométrie
  148. *
  149.  pA = 0.   0. ;
  150.  pB = 1.   0. ;
  151.  pC = 1.   1. ;
  152.  pD = 0.   1. ;
  153. *
  154. * Paramètres de la discrétisation de base
  155. *
  156.  'SI' complet ;
  157.     nAB = 8  ;
  158.     nBC = 7  ;
  159.     nCD = 5  ;
  160.     nDA = 9  ;
  161.  'SINON' ;
  162.     nAB = 3 ;
  163.     nBC = 4 ;
  164.     nCD = 5 ;
  165.     nDA = 6 ;
  166.  'FINSI' ;
  167. *
  168. * Rotation et translation aditionnelle + bruit blanc
  169. * + raffinement
  170. *
  171.  vtran = ((** 2 0.5) (* -1 (** 3 0.5))) ;
  172.  orig  = (0.D0 0.D0) ;
  173.  arot  = 11.3D0 ;
  174.  lesdens = 'PROG' (1. '/' nAB) (1. '/' nCD) (1. '/' nBC) (1. '/' nDA) ;
  175.  ampbruit = (0.15 * ('MINIMUM' lesdens)) ;
  176. *
  177. * Géométrie discrétisée
  178. *
  179.  bas    = 'DROIT' nAB pA pB ;
  180.  droite = 'DROIT' nBC pB pC ;
  181.  haut   = 'DROIT' nCD pC pD ;
  182.  gauche = 'DROIT' nDA pD pA ;
  183.  pourtour = bas 'ET' droite 'ET' haut 'ET' gauche ;
  184.  mt = 'SURFACE' pourtour 'PLAN' ;
  185. *
  186. * On rajoute le bruit
  187. *
  188.  pmt = 'CHANGER' mt 'POI1' ;
  189.  pcnt= 'CHANGER' pourtour 'POI1' ;
  190.  inmt= 'DIFF' pmt pcnt;
  191.  brbl1 = 'BRUIT' 'BLAN' 'GAUS' 0.D0 ampbruit inmt ;
  192.  brbl2 = 'BRUIT' 'BLAN' 'GAUS' 0.D0 ampbruit inmt ;
  193.  brbl = 'ET' ('NOMC' 'UX' brbl1) ('NOMC' 'UY' brbl2) ;
  194.  'DEPLACER' mt 'PLUS' brbl;
  195. *
  196. * On raffine nraff fois 
  197. *
  198.  'SI' (nraff > 0) ;
  199.     'REPETER' bcl nraff ;
  200.        mt  = 'CHANGER' mt 'QUADRATIQUE' ;
  201.        $mt = 'DOMA' mt 'MACRO' ;
  202.        mt  = ('DOMA '$mt 'MAILLAGE') ;
  203.        'MENAGE' ;
  204.     'FIN' bcl ;
  205.  'FINSI' ;
  206. *
  207. * Eventuellement, on trace le résultat
  208. *
  209.  'SI' graph ;
  210.      titgeo = 'CHAINE' 'mt ' 'NBPO=' ('NBNO' mt)
  211.                       ' NBELEM=' ('NBEL' mt) titglob ;
  212.     'TRACER' mt 'NOEUD' 'TITRE' titgeo ;
  213.  'FINSI' ;
  214. *
  215. * Definition des cotés gauche et bas
  216. *
  217.  cnt = 'CONTOUR' mt ;
  218.  gau = cnt 'ELEM' 'COMPRIS' PD PA 'COULEUR' 'VERT' ;
  219.  bas  = cnt 'ELEM' 'COMPRIS' PA PB 'COULEUR' 'TURQ' ;
  220.  'SI' graph ;
  221.     'TRACER' (gau 'ET' bas) 'TITRE' 'Coté bas et coté gauche' ;
  222.  'FINSI' ;
  223. *
  224. * Creation des modèles
  225. *
  226. * MODELS 
  227.  $mt   = 'MODE' mt 'EULER'  ;
  228.  $bas  = 'MODE' bas 'EULER'  ;
  229.  $gau  = 'MODE' gau 'EULER'  ;
  230.  $cnt  = 'MODE' cnt 'EULER'  ;
  231. * MODELS 
  232.  Tmt   = 'DOMA' $mt 'VF'  ;
  233.  Tbas  = 'DOMA' $bas 'VF'  ;
  234.  Tgau  = 'DOMA' $gau 'VF'  ;
  235.  Tcnt  = 'DOMA' $cnt 'VF'  ;
  236. * QUAF
  237.  Mmt    = Tmt   . 'QUAF' ;
  238.  Mgau   = Tgau  . 'QUAF' ;
  239.  Mbas   = Tbas  . 'QUAF' ;
  240.  Mcnt   = Tcnt  . 'QUAF' ;
  241.  'ELIM' (Mmt 'ET' Mgau 'ET' Mbas 'ET' Mcnt)  1.E-5 ;
  242. *
  243. * Solution exacte bilinéaire (sur le sommet)
  244. *
  245.  xx yy = 'COORDONNEE' ('DOMA' $mt 'SOMMET') ;
  246.  solex = (xx '*' alpha) '+' (yy '*' beta) '+'
  247.          (xx '*' yy '*' gamma) '+' delta ;
  248. *
  249. * Solution exacte aux centres
  250. *
  251.  xxc yyc = 'COORDONNEE' ('DOMA' $mt 'CENTRE') ;
  252.  solexc = (xxc '*' alpha) '+' (yyc '*' beta) '+'
  253.          (xxc '*' yyc '*' gamma) '+' delta ;
  254. *
  255. * Gradient exact (aux faces)
  256. *
  257.  xxf yyf = 'COORDONNEE' ('DOMA' $mt 'FACE') ;
  258.  gradtx = 'NOMC' 'UX' (alpha '+' (yyf '*' gamma)) 'NATU' 'DISCRET' ;
  259.  gradty = 'NOMC' 'UY' (beta  '+' (xxf '*' gamma)) 'NATU' 'DISCRET' ;
  260. * 
  261. * Mise en place du calcul numérique
  262. *
  263. * équation de Laplace
  264. *
  265. * on utilise une méthode de Newton pour résoudre :
  266. * - \Delta T = 0     (\Delta opérateur laplacien)
  267. * - avec T  donné sur gauche (CL de Dirichlet)
  268. *        grad(T) \cdot next donné ailleurs
  269. *
  270. * T_0 : estimation initiale de la solution
  271. * On a T_1 = T_0 - {\Delta'}^{-1} (\Delta T_0)
  272. *
  273. * L'opérateur 'LAPN' 'VF' nous donne la matrice \Delta' et le
  274. * résidu \Delta T_0.
  275. * On n'inverse bien évidemment pas \Delta' mais on résoud le système:
  276. * \Delta' IncT = \Delta T_0
  277. * => IncT = {\Delta'}^{-1} (\Delta T_0)
  278. *
  279. * La méthode de Newton doit converger en un pas (on vérifie que le
  280. * résidu (\Delta T_1) est nul après le premier pas.
  281. * 
  282. *
  283.  rho0 = 'MANUEL' 'CHPO' ('DOMA' $mt 'CENTRE') 1 'SCAL' 1.0 ;
  284.  v0   = 'MANUEL' 'CHPO' ('DOMA' $mt 'CENTRE') 2 'UX' 0.0 'UY' 0.0 ;
  285.  gradv0 mchamv = 'PENT' $mt 'FACE' 'DIAMANT' v0 ;
  286. *
  287.  t0 = 'MANU' 'CHPO' ('DOMA' $mt 'CENTRE') 1 'SCAL' 0.D0 ;
  288. *
  289. * We want to impose the temperature value close to pA
  290. * So we cannot impose von Neumann boundary conditions
  291. * close to PA
  292. *
  293.  cdir = 'MANUEL' 'POI1' pa ;
  294.  pdir1 = 'MANUEL' 'POI1' (('DOMA' $bas 'CENTRE') 'POIN' 'PROC' pA) ;
  295.  pdir2 = 'MANUEL' 'POI1' (('DOMA' $gau 'CENTRE') 'POIN' 'PROC' pA) ;
  296. * cvn = set of FACE centers where we impose von Neumann boundary
  297. * conditions
  298.  cvn = 'DIFF' ('DOMA' $cnt 'CENTRE') pdir1 ;
  299.  cvn = 'DIFF' cvn pdir2 ;
  300.  'SI' graph ;
  301.    'TRACER' (mt et (cvn 'COULEUR' 'ROUG')) 'TITRE' 'Von Neumann B.C.' ;
  302.  'FINSI' ;  
  303.  tlim = 'REDU' solex cdir ;
  304.  qchal = -1.0 '*' kappa  '*' (gradtx 'ET' gradty) ;
  305.  qlim = 'REDU' qchal cvn ;
  306.  gradt0 mchamt = 'PENT'  $mt
  307.                        'FACE' 'DIAMANT' t0
  308.                        'CLIM' tlim ;
  309. * Jacobian
  310. * We use the 'NS' jacobian                        
  311.  listinco = 'MOTS' 'RN' 'RUXN' 'RUYN' 'RETN' ;
  312.  jaco chpres dt = 'LAPN' 'VF' 'PROPCOST' 'RESI' 'IMPL'
  313.      $mt mu kappa cv rho0 v0 t0 gradv0 gradt0 mchamv mchamt
  314.      'QIMP' qlim 'TIMP' tlim  listinco ;
  315.  mamat = 'KOPS' 'MULT' -1.0D0 jaco ;
  316. * Identity matrix for momentum and density contribution 
  317.  mati = 'KOPS' 'MATIDE' ('MOTS' 'RN' 'RUXN' 'RUYN')
  318.       ('DOMA' $mt 'CENTRE') 'MATRIK' ;
  319.  matot = 'ET' mamat mati ;
  320. *
  321.  rv = 'EQEX' ;
  322.  rv . 'METHINV' . 'TYPINV'   = 3 ;
  323.  rv . 'METHINV' . 'PRECOND'  = 3 ;
  324.  rv . 'METHINV' . 'MATASS'   = matot ;
  325.  rv . 'METHINV' . 'MAPREC'   = matot ;
  326.  deltat = 'KRES' matot 'TYPI' (rv . 'METHINV')
  327.                  'SMBR' ('EXCO' chpres 'RETN' 'RETN')
  328.                  'IMPR' 0 ;
  329.  t1 = t0 '+' ('EXCO' deltat 'RETN' 'SCAL') ;
  330.  gradt1 mchamt = 'PENT'  $mt
  331.                        'FACE' 'DIAMANT' t1
  332.                        'CLIM' tlim ;
  333.  listinco = 'MOTS' 'RN' 'RUXN' 'RUYN' 'RETN' ;
  334. * We check that the residuum is 0 if computed with
  335. * gradt1 and t1
  336.  jacbid chpres1 dt = 'LAPN' 'VF' 'PROPCOST' 'RESI' 'IMPL'
  337.     $mt mu kappa cv rho0 v0 t1 gradv0 gradt1 mchamv mchamt
  338.    'QIMP' qlim 'TIMP' tlim  listinco ;
  339.     mres1 = 'MAXIMUM' ('EXCO' chpres1 'RETN') 'ABS' ;
  340.  'MESSAGE' ('CHAINE' 'Maxi. chpres1 =' mres1) ;
  341.  'SI' ('>' mres1 1.e-5) ;
  342.     'MESSAGE' 'La méthode de Newton na pas converge en un pas.'
  343.     'ERREUR' 5 ;
  344.  'FINSI' ;
  345. *
  346. * Résultats
  347. *
  348. 'SI' graph ;
  349. *
  350. * solutions exactes
  351. *
  352.   tn = solexc ;
  353.   chm_tnex = 'KCHA' $mt 'CHAM' tn ;
  354.   titt = 'CHAINE' 'Température exacte' titglob ;
  355.   'TRACER' chm_tnex $mt nbisov 'TITRE' titt ;
  356. *
  357. * graphe de convergence de la méthode itérative
  358. *
  359.     conver = (rv . 'METHINV' . 'CONVINV') ;
  360.     dimcon = 'DIME' conver ;
  361.     labs = 'PROG' 1.D0 'PAS' 1.D0 dimcon ;
  362.     lord = ('LOG' conver) '/' ('LOG' 10.D0) ;
  363.     evtot = 'EVOL' 'MANU' 'ITER' labs 'RESID' lord ;
  364.     titev = 'CHAINE' 'Historique de convergence' titglob ;
  365.     'DESSIN' evtot 'TITR' titev 'LEGE' ;
  366. *
  367. * solutions calculées
  368. *
  369.    tn = t1 ;
  370.    chm_tn = 'KCHA' $mt 'CHAM' tn ;
  371.    titt = 'CHAINE' 'Température calculée' titglob ;
  372.    'TRACER' chm_tn $mt nbisov 'TITRE' titt ;
  373. *
  374. * erreur
  375. *
  376.    titt = 'CHAINE' 'Abs (Température calculée - Température exacte)'
  377.          titglob ;
  378.    'TRACER' ('ABS' (chm_tnex '-' chm_tn)) $mt nbisov 'TITRE' titt ; 
  379.  'FINSI' ;
  380. *
  381. * Calcul des erreurs par rapport à la solution analytique
  382. *
  383.  vol = 'DOMA' $mt 'VOLUME' ;
  384.  echloc = (('MESURE' mt) '/' ('NBEL' mt)) ** 0.5 ;
  385.  tn = t1 ;
  386.  errlit = CALCERR  tn solexc ;
  387.  errl2t = CALCERR2 tn solexc vol ;
  388.  'MESSAGE' '-------------------------------------------------' ;
  389.  'MESSAGE' ('CHAINE' 'Erreur en norme LINF : ' errlit) ;
  390.  'MESSAGE' ('CHAINE' 'Erreur en norme L2   : ' errl2t) ;
  391.  'MESSAGE' '-------------------------------------------------' ;
  392. *'OPTION' 'DONN' 5 ;
  393.  'FINPROC' echloc errl2t ;
  394. * Fin de la procédure de calcul                             *
  395. *___________________________________________________________*
  396. *-----------------------------------------------------------
  397. * Paramètres du calcul
  398. *
  399. * lraff : nb raffinement du maillage (à chaque fois, on découpe
  400. *         les éléments en quatre).
  401.  'SI' complet ;
  402.    lraff  = 'LECT' 0 PAS 1 3 ;
  403.  'SINON' ;
  404.    lraff  = 'LECT' 0 PAS 1 3 ;
  405.  'FINSI' ;
  406. *
  407. *-----------------------------------------------------------*
  408. * Boucles sur les différents paramètres du calcul           *
  409.  precok = VRAI ;
  410. * ordre théorique en espace de la méthode
  411.  ordtth = 2 ;
  412. * erreur L2 max pour la solution (raffinement 2, complet=FAUX)
  413.  errtmax = 1.D-3 ;
  414. *
  415. *  Boucle sur les raffinements
  416. *
  417.      lh = 'PROG' ;
  418.      lerl2t = 'PROG' ;
  419.      'REPETER' iraff ('DIME' lraff)  ;
  420.         raff = 'EXTRAIRE' lraff &iraff ;
  421.         h errt = CALCUL raff ;
  422.         lh     = 'ET' lh     ('PROG' h ) ;
  423.         lerl2t = 'ET' lerl2t ('PROG' errt) ;
  424.      'FIN' iraff ;
  425.      lh = lh '/' ('EXTRAIRE' lh 1) ;
  426.      lh     = ('LOG' lh)     '/' ('LOG' 10.D0) ;
  427.      lerl2t = ('LOG' lerl2t) '/' ('LOG' 10.D0) ;
  428.      tl2 = 'EVOL' 'MANU' 'Long. carac.' lh
  429.                         'Err. tempér.' lerl2t ;
  430.  
  431. *
  432. * Recherche des ordres de convergence
  433. *
  434.      cpt tlipol = @POMI tl2 1 'IDEM' ;
  435.      ordt = cpt . 1 ;
  436.     'MESSAGE' ('CHAINE' 'ordre température=' ordt) ;
  437. *
  438. * Tracés graphiques
  439. *  
  440.     'SI' graph ;
  441.        tableg = 'TABLE' ;
  442.        tableg . 'TITRE' = 'TABLE' ;
  443.        tableg . 1 = 'MARQ CROI NOLI' ;
  444.        tableg . 'TITRE' . 1 = 'Erreur L2 calculée' ;
  445.        tableg . 2 = 'TIRR' ;                   
  446.        tableg . 'TITRE' . 2 = 'Erreur L2 interpolée' ;
  447.        titdest= 'CHAINE' 'Err L2 Tempér., ordre=' ordt ;
  448.        'DESSIN' (tl2 'ET' tlipol) 'TITRE' titdest tableg ;
  449.     'FINSI' ;
  450. *
  451. * Tests des ordres de convergence
  452. * Tests des erreurs L2 sur le maillage le plus fin dans le
  453. * cas complet=faux
  454. *
  455.      ordok = ordt '>' (ordtth '-' 0.5) ;
  456.       'SI' ('EGA' complet FAUX) ;
  457.        precok = 'ET' precok ('<' errt errtmax) ;
  458.      'FINSI' ;
  459.      'SI' ('NON' ordok) ;
  460.        'MESSAGE' 'On n_obtient pas un ordre de convergence correct' ;
  461.        'ERREUR' 5 ;
  462.      'FINSI' ;
  463.      'SI' ('NON' precok) ;
  464.        'MESSAGE' 'On n_obtient pas une précision correcte' ;
  465.        'ERREUR' 5 ;
  466.      'FINSI' ;
  467.  
  468.  'SI' interact ;
  469.     'OPTION' 'ECHO' 1 ;
  470.     'OPTION' 'DONN' 5 ;
  471.     'SI' logxmgr ;
  472. *     Sortie pour xmgr   
  473.        'OPTION' ECHO 0 ;
  474.        'OPTION' 'IMPR' 'file.txt' ;
  475.        ndim = 'DIME' lh ;
  476.        'REPETER' BL1 ndim ;
  477.          'MESSAGE' ('EXTRAIRE' lh &BL1) '  '  ('EXTRAIRE' lerl2t &BL1) ;
  478.        'FIN' BL1 ;
  479.        lh1 = 'EXTRAIRE' tlipol 'ABSC' ;
  480.        lerr = 'EXTRAIRE' tlipol 'ORDO' ;
  481.        ndim = 'DIME' lh1 ;
  482.        'OPTION' 'IMPR' 'file2.txt' ;
  483.        'REPETER' BL1 ndim ;
  484.           'MESSAGE' ('EXTRAIRE' lh1 &BL1) '  '  ('EXTRAIRE' lerr &BL1) ;
  485.        'FIN' BL1 ;
  486.        'OPTION' 'IMPR' 'poubelle.txt' ;
  487.        'FIN' ; 
  488.     'FINSI' ;
  489.  'FINSI' ;
  490.  
  491.  'MESSAGE' 'Tout s_est bien passé' ;
  492.  'FIN' ;
  493.  
  494.  
  495.  
  496.  
  497.  
  498.  
  499.  
  500.  
  501.  
  502.  
  503.  
  504.  
  505.  
  506.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales