Télécharger la plaquette Cast3M


fr en

Télécharger elas9.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas9.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas9.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  10.  
  11. *  POUR CALCUL COMPLET METTRE COMPLET = VRAI;
  12. complet = VRAI;
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22.   OPTI ECHO 1   ;
  23.   OPTI TRAC PSC ;
  24. SINO ;
  25.   OPTI ECHO 1   ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *___________________________________________________________________
  30. *   TEST ELAS9                                                     *
  31. *                                                                  *
  32. *   MEMBRANE EPAISSE ELLIPTIQUE CHARGEE EN PRESSION                *
  33. *                                                                  *
  34. *   Test NAFEMS numero le10                                        *
  35. *   Nom : THICK PLATE PRESSURE                                     *
  36. *                                                                  *
  37. *       La plaque epaisse est maillee a l'aide d'elements CU20.    *
  38. *   Elle est chargee normalement par une pression de 1 MPa.        *
  39. *   On s'interesse a la contrainte smyy au point D                 *
  40. *                                                                  *
  41. *       La valeur calculee de la contrainte est ensuite comparee   *
  42. *   avec une valeur theorique obtenue avec un maillage plus fin.   *
  43. *                                                                  *
  44. *___________________________________________________________________
  45. *
  47. OPTI ELEM CU20;
  48. *
  49. *==================================================================*
  50. *             geometrie : maillage                                 *
  51. *==================================================================*
  52. *
  53. * Dimensions en metres.
  54. *
  55. *     Pour obtenir des arcs d'ellipse on projete des arcs de cercle
  56. *  sur le plan xOy.
  57. *
  58. * Corfficient de finesse du maillage.
  59. *
  60. si complet;
  61. K = 2;
  62. sinon;
  63.  k= 1;
  64. finsi;
  65. *
  66. PB = 0. 2.75 0.;
  67. PB1 = 0. 2.75 (((3.25 ** 2) - (2.75 ** 2)) ** 0.5);
  68. PC = 3.25 0. 0.;
  69. *
  70. C1 = PC CERC (6 * K) (0. 0. 0.) PB1;
  71. C2 = C1 PROJ DIRE (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  72. *
  73. PA = 0. 1. 0.;
  74. PA1 = 0. 1. (((2. ** 2) - (1. ** 2)) ** 0.5);
  75. PD = 2. 0. 0.;
  76. *
  77. C3 = Pd CERC (6 * K) (0. 0. 0.) PA1;
  78. C4 = C3 PROJ DIRE (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  79. *
  80. D1 = PA DROI (2 * K) (0. 1.583 0.) DROI (2 * K) PB;
  81. D3 = PC DROI (2 * K) (2.417 0. 0.) DROI (2 * K) PD;
  82. *
  83. ELIM (D1 ET C2 ET D3 ET C4) 0.0001;
  84. SUR1 = DALL D1 C2 D3 C4 PLAN;
  85. *
  86. VOL1 = SUR1 VOLU (2 * K) TRAN (0. 0. -0.6);
  87. *
  88. * Surfaces et arc d'ellipse pour conditions aux limites
  89. *
  90. FACE1 = D1 TRAN (2 * K) (0. 0. -0.6);
  91. FACE2 = C2 TRAN (2 * K) (0. 0. -0.6);
  92. FACE3 = D3 TRAN (2 * K) (0. 0. -0.6);
  93. C2CL  = C2 PLUS (0. 0. -0.3);
  94. *
  95. ELIM (VOL1 ET FACE1 ET FACE2 ET FACE3 ET C2CL) 0.0001;
  96. *
  97. SI (NEG GRAPH 'N');
  98.   TITR 'ELAS9 : MAILLAGE';
  99.   TRAC (-1000 -1000 1000) FACE QUAL (COUL VOL1 BLAN);
  100. FINSI;
  101. *
  102. *==================================================================*
  103. *          modele - materiau - caracteristique                     *
  104. *           rigidite - conditions aux limites                      *
  105. *==================================================================*
  106. *
  107. MODL1 = MODE VOL1 MECANIQUE ELASTIQUE ISOTROPE CU20;
  108. MATR1 = MATE MODL1 YOUN 2.1E11 NU 0.3;
  109. *
  110. MOP  = 'MODE' SUR1 'CHARGEMENT' 'PRESSION' ;
  111. MAP  = 'PRES' MOP 'PRES' 1.E6 ;
  112. MODLT = MODL1 ;
  113. *
  114. RIG1 = RIGI MODLT MATR1 ;
  115. *
  116. *==================================================================*
  117. *                  conditions aux limites                          *
  118. *==================================================================*
  119. *
  120. *   - face dans le plan xOz : ux = 0.,
  121. *   - face dans le plan yOz : uy = 0.;
  122. *   - face elliptique exterieure : ux = uy = 0. et
  123. *      uz = 0. le long de la surface moyenne.
  124. *
  125. CL1 = BLOQ UX FACE1;
  126. CL2 = BLOQ UY FACE3;
  127. CL3 = BLOQ UX FACE2;
  128. CL4 = BLOQ UY FACE2;
  129. CL5 = BLOQ UZ C2CL;
  130. *
  131. RIG1 = RIG1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5;
  132. *
  133. *==================================================================*
  134. *                     chargement mecanique                         *
  135. *==================================================================*
  136. *
  137. *    La plaque est soumis a une pression uniforme normal de 1 MPa
  138. * sur la face superieure.
  139. *
  140. CHA1 = 'BSIG' MOP MAP ;
  141. *
  142. *==================================================================*
  143. *                 calcul du champ de deplacement                   *
  144. *==================================================================*
  145. *
  146. optio reso iter;
  147. DEP1 = RESO RIG1 CHA1;
  148. mena 'OBLI';
  149. *
  150. * Trace facultatif de la deformee.
  151. *
  152. SI (NEG GRAPH 'N');
  153.    DEF0 = DEFO 0. DEP1 VOL1;
  154.    DEF1 = DEFO 5.E2 DEP1 VOL1 VERT;
  155.    TITR 'ELAS9 : DEFORMEE';
  156.    TRAC (-1000 -1000 1000) CACH VOL1 (DEF0 ET DEF1);
  157. FINSI;
  158. *
  159. *==================================================================*
  160. *                  extraction d'une contrainte                     *
  161. *            et comparaison avec solution analytique               *
  162. *==================================================================*
  163. *
  164. *   On cherche la contrainte smyy au point D (2. 0. 0.).
  165. *
  166. *  Calcul du champs de contraintes.
  167. *
  168. CHAM1 = SIGM MODL1 MATR1 DEP1;
  169. *
  170. * Interpolation aux noeuds du maillage.
  171. *
  172. CHAM2 = CHAN NOEUD MODL1 CHAM1;
  173. CHPO2 = CHAN CHPO  MODL1 CHAM2;
  174.  
  175. *
  176. * Trace facultatif des contraintes aux noeuds.
  177. *
  178. SI (NEG GRAPH 'N');
  179.    TITR 'ELAS9 : Contraintes Nodales';
  180.    TRAC (-1000 -1000 1000) CACH VOL1 ((EXCO CHPO2 SMYY)*1e-6);
  181. FINSI;
  182. *
  183. * Extraction de la contriante smyy au point D.
  184. *
  185. SMYYD = EXTR CHPO2 SMYY  PD;
  186. SMYYD = SMYYD / 1.E6;
  187. *
  188. SMYYD1 = -5.38;
  189. *
  190. * Calcul de l'ecart avec la solution de reference.
  191. *
  192. ERG = 100 * (ABS ((SMYYD1 - SMYYD) / SMYYD1));
  193. *
  194. *==================================================================*
  195. *                   affichage des resultats                        *
  196. *==================================================================*
  197. *
  198. MESS ' RESULTATS ';
  199. MESS ' --------- ';
  201. *
  202. MESS '   Contrainte theorique SMYYD :' SMYYD1 'MPa';
  204. MESS '   Contrainte calculee SMYYD  :' SMYYD 'MPa';
  206. MESS '             Soit un ecart de :' ERG '%';
  208. *
  209. *==================================================================*
  210. *                      code fonctionnement                         *
  211. *==================================================================*
  212. *
  213. si complet; ertes=3.; sinon; ertes=7. ; finsi;
  214. SI (ERG <EG ertes);
  215.    ERRE 0;
  216. SINON;
  217.    ERRE 5;
  218. FINSI;
  219. *
  221.   TEMPS;
  223. *
  224. FIN;
  225.  
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales