Télécharger la plaquette Cast3M


fr en

Télécharger elas6.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas6.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  10.  
  11. * SI GRAPH, LES GRAPHIQUES SONT AFFICHES
  12. GRAPH = FAUX ;
  13.  
  14. SAUT PAGE;
  15. SI GRAPH ;
  16.   OPTI ECHO 1   ;
  17.   OPTI TRAC PSC EPTR 5;
  18. SINO ;
  19.   OPTI ECHO 1   ;
  20. FINSI ;
  21.  
  22. SAUT PAGE;
  23. *___________________________________________________________________
  24. *   TEST ELAS6                                                     *
  25. *                                                                  *
  26. *   COQUE AXISYMETRIQUE                                            *
  27. *                                                                  *
  28. *   cas-test NAFEMS : test numero LE8                              *
  29. *                                                                  *
  30. *     La structure est constituee d'un cylindre surmonte d'une     *
  31. *   partie de tore et d'une partie de sphere. Elle est soumise a   *
  32. *   un pression interne de 1MPa.                                   *
  33. *                                                                  *
  34. *     Le probleme presentant une symetrie axiale (geometrie et     *
  35. *   chargement), on se place en mode axisymetrique.                *
  36. *                                                                  *
  37. *     On se propose de calculer la contrainte tangentielle au      *
  38. *   point D sur la surface exterieure. La valeur trouvee est       *
  39. *   ensuite comparee a une valeur theorique trouvee analytiquement.*
  40. *___________________________________________________________________
  41.  
  43. OPTI MODE AXIS;
  44. OPTI ELEM SEG2;
  45.  
  46. *==================================================================*
  47. *             geometrie : maillage                                 *
  48. *==================================================================*
  49. * Dimension en metres
  50. *
  51. * Points
  52. *
  53. RO2 = 0.;    ZO2 = 0.75;                   PO2 = RO2 ZO2;
  54. RO1 = 0.25 - 0.0625; ZO1 = 0.5;            PO1 = RO1 ZO1;
  55. *
  56. RA = 0.25;           ZA = 0.;              PA = RA ZA;
  57. RB = 0.25;           ZB = 0.5;             PB = RB ZB;
  58. RC = 0.25 - 0.0625;  ZC = 0.5 + 0.0625;    PC = RC ZC;
  59. RD = 0.25 - (0.0625 * (1 + (SIN 36))); ZD = 0.5 + (0.0625 * (COS 36));
  60.                                            PD = RD ZD;
  61. RE = 0.;             ZE = 0.5;             PE = RE ZE;
  62.  
  63. * Droites, cercles et lignes
  64.  
  65. * coefficient de finesse du maillage
  66. K = 1;
  67. * K = 2;
  68.  
  69. SI (K EGA 1);
  70.   TITR ' LE8 : MAILLAGE GROSSIER';
  71. SINON;
  72.   TITR ' LE8 : MAILLAGE FIN';
  73. FINSI;
  74.  
  75. *N1 = 6 * K;
  76. N1 = 4 * K;
  77. AB = PA DROI N1 PB;
  78. *
  79. N2 = 5 * K;
  80. BC = PB CERC N2 PO1 PC;
  81. *
  82. CD = PC CERC N1 PO1 PD;
  83. *
  84. N3 = 8 * K;
  85. DE = PD CERC N3 PO2 PE;
  86. *
  87. * Maillage
  88. *
  89. SUR1 = AB ET BC ET CD ET DE;
  90.  
  91. SI (GRAPH);
  92.    TITR ' TEST ELAS6 : MAILLAGE';
  93.    TRAC QUAL SUR1;
  94. FINSI;
  95. *
  96. ELSUR1 = NBEL SUR1;
  97. NOSUR1 = NBNO SUR1;
  98.  
  99. *==================================================================*
  100. *      modele - affecte - materiau - caracteristique               *
  101. *           rigidite - conditions aux limites                      *
  102. *==================================================================*
  103.  
  104. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE COQ2;
  105. MATR1 = MATE MODL1 YOUN 210E9 NU 0.3 EPAI 0.01;
  106. RI1 = RIGI MODL1 MATR1;
  107.  
  108. * Conditions aux limites
  109. *    - point pe : pas de deplacement radial et pas de rotation,
  110. *    - point pa : pas de deplacement vertical.
  111.  
  112. CL1 = BLOQ ROTA PE;
  113. CL2 = BLOQ UR PE;
  114. CL3 = BLOQ UZ PA;
  115. *
  116. CLI1 = CL1 ET CL2 ET CL3;
  117. RIG1 = RI1 ET CLI1;
  118. *==================================================================*
  119. *                      Chargement                                  *
  120. *==================================================================*
  121. *   Pression interne uniforme de 1e6Pa.
  122. *
  123. MOP  = 'MODE' SUR1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  124. MAP  = 'PRES' MOP 'PRES' -1.E6 ;
  125. cha1 = bsig mop map ;
  126.  
  127. *==================================================================*
  128. *            resolution : champs de deplacements                   *
  129. *==================================================================*
  130.  
  131. DEP1 = RESO RIG1 CHA1;
  132. *
  133. * Trace facultatif de la deformee et des reactions
  134. *
  135. SI (GRAPH );
  136.   AMPVEC = .4E-6;
  137.   REA1 = REAC DEP1 RIG1;
  138.   VECT1 = VECT CHA1 (AMPVEC * 5) FR FZ ROUGE ;
  139.   VECT2 = VECT REA1 (AMPVEC * 5) FR FZ BLEU  ;
  140.   DEF0 = DEFO 0.  DEP1 SUR1;
  141.   DEF1 = DEFO 20. DEP1 SUR1 (VECT1 ET VECT2) VERT;
  142.   TITR 'ELAS6 : DEFORMEE, CHARGEMENT, REACTIONS';
  143.   TRAC SUR1 (DEF0 ET DEF1);
  144. FINSI;
  145.  
  146. *==================================================================*
  147. *                  extraction d'une contrainte                     *
  148. *            et comparaison avec solution analytique               *
  149. *==================================================================*
  150. *      On cherche la contrainte tangentielle sigtt au noeud pd et
  151. * sur la surface exterieure.
  152. *
  153. * Calcul du champs de contraintes generalisees.
  154. *
  155. CHAM1 = SIGM 'LINE' MODL1 MATR1 DEP1;
  156. *
  157. * Calcul du champs de contraintes au sens des milieux continus :
  158. *  Utilisation l'operateur CALP.
  159. *
  160. CHAM2 = CALP CHAM1 MATR1 MODL1 'INFE';
  161. *
  162. * Interpolation aux noeuds du maillage
  163. *
  164. CHAM3 = CHAN NOEUD MODL1 CHAM2;
  165. CHPO3 = CHAN CHPO MODL1 CHAM3;
  166. *
  167. * Extraction de la contrainte
  168. *
  169. SMTTD = EXTR CHPO3 SMYY PD;
  170. SMTTD = SMTTD / 1.E6;
  171. *
  172. SMTTD1 = 94.55;
  173. *
  174. * Calcul de l'ecart avec la solution de reference.
  175. *
  176. ERGTTD = 100 * (ABS ((SMTTD - SMTTD1) / SMTTD1));
  177.  
  178. *==================================================================*
  179. *                   affichage des resultats                        *
  180. *==================================================================*
  181. MESS ' Resultats du test ELAS6_2 ';
  182. MESS ' ------------------------- ';
  184. *
  185. MESS ' La valeur cherchee est la contrainte tangentielle au point D,';
  187.   ' elle est comparee a une valeur theorique obtenue analytiquement.';
  189. MESS ' Contrainte tangentielle theorique en D :' SMTTD1 'MPa';
  191. MESS ' Contrainte tangentielle calculee en D  :' SMTTD 'MPa';
  193. MESS '          Soit un ecart de :' ERGTTD '%';
  195. *
  196. SI (K EGA 1);
  197.   MESS ' Maillage grossier';
  198. SINON;
  199.   MESS ' Maillage fin';
  200. FINSI;
  201. *
  202. MESS '    Nombre d elements :' ELSUR1;
  203. MESS '    Nombre de noeuds  :' NOSUR1;
  204. MESS '       soit ' (NOSUR1 * 3) 'd.d.l.';
  205.  
  206. *==================================================================*
  207. *                  code fonctionnement                             *
  208. *==================================================================*
  209. * ecart maximum entre valeur theorique et calculee doit etre
  210. * inferieure a 1,5% 
  211. * bp, 2020-12-18 : on remarque que l'on ne converge pas vers la solution NAFEMS ???
  212. * --> on change la tolerance pour 2,5% 
  213. SAUT 2 LIGNE;
  214. SI (ERGTTD <EG 2.5);
  215.     ERRE 0;
  216. SINON;
  217.     ERRE 5;
  218. FINSI;
  219.  
  220. *==================================================================*
  221. *                 Temps de calcul et fin                           *
  222. *==================================================================*
  224. TEMPS;
  226.  
  227. FIN;
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales