Télécharger la plaquette Cast3M


fr en

Télécharger elas3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas3.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI ECHO 1   ;
  19.   OPTI TRAC PSC ;
  20. SINO ;
  21.   OPTI ECHO 0   ;
  22. FINSI ;
  23.  
  24. *______________________________________________________
  25. * TEST ELAS3
  26. *
  27. * Meme probleme que DFICH10 mais avec une extrémité
  28. * libre au lieu d'etre encastrée (la géométrie est
  29. * différente).
  30. *
  31. * Un cylindre est pincé à une extrémité, l'autre reste
  32. * libre.
  33. *
  34. * Pour des raisons de symétrie seul 1/4 de la structure
  35. * est discrétisé.
  36. * Les conditions aux limites respectent cette symétrie.
  37. *
  38. * Une force ponctuelle est appliquée diamétralement.
  39. *
  40. * La déflexion suivant Z au point d'application de la
  41. * force est comparée à la déflexion théorique (-0.452).
  42. *______________________________________________________
  43.  
  44. OPTION DIME 3 ELEM TRI3 ;DENS 0.75 ;
  45. TITR 'CYLINDRE PINCE A BORDS LIBRES' ;
  46. TEMPS ;
  47.  
  48. *----------------------------------------------------
  49. * DEFINITION DE LA GEOMETRIE
  50. *----------------------------------------------------
  51. P1=4.953 0 0 ;P2=0 0 4.953 ;C1=0 0 0 ;VECT=0 5.175 0 ;
  52. LIG1=C   P1 C1 P2 ;SURF=LIG1 TRAN    VECT ;
  53. LIG1 LIG2 LIG3 LIG4=COTE SURF ;P3=LIG2 POIN FINA ;
  54. LIST P3;
  55.  
  56. *----------------------------------------------------
  57. * TRACE
  58. *----------------------------------------------------
  59. OEIL1 = 100 100 100;
  60. SI(NEG GRAPH 'N');
  61.    TRAC OEIL1 SURF 'QUAL';
  62. FINSI;
  63.  
  64. *----------------------------------------------------
  65. * DEFINITION DU MODELE ET DES CARACTERISTIQUES
  66. *----------------------------------------------------
  67.  
  68. MOD1=MODE SURF MECANIQUE ELASTIQUE DKT;
  69. MAT1=MATE MOD1 YOUN 10.5E6 NU 0.3125 RHO 1. EPAI 0.094 ;
  70.  
  71. *----------------------------------------------------
  72. * CALCUL RIGIDITE ET MASSE ;
  73. *----------------------------------------------------
  74. *
  75. RIG1=RIGI MOD1 MAT1;
  76.  
  77. *----------------------------------------------------
  78. * CONDITIONS AUX LIMITES
  79. *----------------------------------------------------
  80. ENC1=BLOQ LIG4 UZ ;ENC2=BLOQ LIG4 RX ;ENC3=BLOQ LIG4 RY ;
  81. ENC4=BLOQ LIG2 UX ;ENC5=BLOQ LIG2 RY ;ENC6=BLOQ LIG2 RZ ;
  82. ENC7=BLOQ LIG3 UY ;ENC8=BLOQ LIG3 RX ;ENC9=BLOQ LIG3 RZ ;
  83. ENC10=ENC1 ET ENC2 ET ENC3 ET ENC4 ET ENC5 ET ENC6 ET ENC7 ET ENC8
  84. ET ENC9 ;
  85.  
  86. *----------------------------------------------------
  87. * FORCE
  88. *----------------------------------------------------
  89. F1=0 0 -100 ;
  90. EFOR=FORC F1 P3 ;
  91. RIG2=RIG1 ET ENC10;
  92.  
  93. *----------------------------------------------------
  94. * RESOLUTION
  95. *----------------------------------------------------
  96. DE1 = RESO RIG2 EFOR;
  97. D3Z = EXTR DE1 UZ P3;
  98.  
  99. *----------------------------------------------------
  100. * RESULTATS (isovaleurs de deplacement en Z)
  101. *----------------------------------------------------
  102. SAUT PAGE ;
  103.  
  104. SURF1= DEFO SURF DE1;
  105. DZ   = EXCO DE1  UZ;
  106. SI(NEG GRAPH 'N');
  107.     TRAC OEIL1 'CACH' SURF1 DZ ;
  108. FINSI;
  109.  
  110. MESS ' DEPLACEMENT EN Z THEORIQUE :   -0.452 ';
  111. MESS ' DEPLACEMENT EN Z CALCULE   :   ' D3Z ;
  112. TEMPS ;
  113. *            CODE FONCTIONNEMENT
  114. DZREF=-0.452;
  115. RESI=ABS((D3Z-DZREF)/DZREF);
  116. SI(RESI <EG 4E-4);
  117.      ERRE  0;
  118. SINO;
  119.      ERRE  5;
  120. FINSI;
  121. FIN;
  122.  
  123.  
  124.  
  125.  
  126.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales