Télécharger la plaquette Cast3M


fr en

Télécharger elas13.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas13.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas13.dgibi: Jeux de données        *
  7. *           ---------------------------------         *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19.   OPTI ECHO 1   ;
  20.   OPTI TRAC PSC   ;
  21. SINO ;
  22.   OPTI ECHO 0   ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *______________________________________________________
  27. *   TEST ELAS13                                       *
  28. *                                                     *
  29. *   POUTRE SUR SOL ELASTIQUE, EXTREMITES ARTICULEES   *
  30. *                                                     *
  31. *   Test V.P.C.S. numero SSLL16/89                    *
  32. *                                                     *
  33. *   Reference : M. Courtand et P. Lebelle, Formulaire *
  34. *         du beton arme, T. 2, Paris, Eyrolles, 1976  *
  35. *                                                     *
  36. *   La structure est constituee d'une poutre articulee*
  37. *   aux extremites et reposant sur un sol elastique.  *
  38. *                                                     *
  39. *      On se propose de calculer la rotation et la    *
  40. *   reaction a une extremite, ainsi que la fleche et  *
  41. *   le moment de flexion au centre de la poutre.      *
  42. *                                                     *
  43. *     Les valeurs trouvees sont ensuites comparees    *
  44. *   aux valeurs de reference obtenues par solution    *
  45. *   analytique.                                       *
  46. *                                                     *
  47. *______________________________________________________
  48. *
  50. OPTI ELEM SEG2;
  51. *
  52. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  53. *                  maillage - geometrie               *
  54. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  55. *
  56. L = PI * (10 ** .5) / 2.;
  57. *
  58. PA = (-.5 * L) 0. 0.;
  59. PB = (0.5 * L) 0. 0.;
  60. *
  61. SUR1 = PA DROI 8 PB;
  62. PD = SUR1 POIN PROC (0. 0. 0.);
  63. *
  64. SI (NEG GRAPH 'N');
  65.    TITR 'ELAS13 : MAILLAGE';
  66.    TRAC (0. 0. 1000.) QUAL SUR1;
  67. FINSI;
  68. *
  69. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  70. *               calcul de la rigidite                 *
  71. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  72. *
  73. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE POUT;
  74. MATR1 = MATE MODL1 YOUN 2.E11 NU 0.3 TORS 1000.
  75.                    SECT 1000 INRY 1.E-4 INRZ 1.E-4;
  76. RIGI1 = RIGI MODL1 MATR1;
  77. *
  78. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  79. *              conditions aux limites                 *
  80. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  81. *
  82. *  - Rotule en A et B,
  83. *  - Appui continu elastique : sol de raideur lineique
  84. *     constante : K = 840 000 N/m2 ,
  85. *  - Conditions d'un probleme plan.
  86. *
  87. CL1 = BLOQ UX (PA ET PB);
  88. CL2 = BLOQ UY (PA ET PB);
  89. *
  90. CL3 = BLOQ UZ SUR1;
  91. CL4 = BLOQ RX SUR1;
  92. *
  93. NEL1 = NBEL SUR1;
  94. K = 840000;
  95. KNOEUD = K * L / (2. * NEL1);
  96. I = 0;
  97. CL5 = APPUI DEPL 0. SUR1;
  98. REPETER BLOC2 NEL1;
  99.   I = I + 1;
  100.   POI1 = SUR1 POIN I;
  101.   POI2 = SUR1 POIN (I + 1);
  102.   APP1 = APPUI DEPL KNOEUD POI1;
  103.   APP2 = APPUI DEPL KNOEUD POI2;
  104.   CL5 = CL5 ET APP1 ET APP2;
  105. FIN BLOC2;
  106. *
  107. RIGI1 = RIGI1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5;
  108. *
  109. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  110. *                      chargement                     *
  111. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  112. *
  113. *  - Force ponctuelle verticale de -10000 N au point D,
  114. *  - Force lineique repartie verticale de -5000 N/m,
  115. *  - Moments opposes aux extremites de 15000 N.m .
  116. *
  117. CHA1 = FORC (0. -10000. 0.) PD;
  118. *
  119. FTOTAL = -5000. * L;
  120. FPOINT = FTOTAL / (2. * NEL1);
  121. CHA2 = FORC FY 0. PA;
  122. I = 0;
  123. REPETER BLOC1 NEL1;
  124.   I = I + 1;
  125.   POI1 = SUR1 POIN I;
  126.   POI2 = SUR1 POIN (I + 1);
  127.   FOR1 = FORC FY FPOINT POI1;
  128.   FOR2 = FORC FY FPOINT POI2;
  129.   CHA2 = CHA2 ET FOR1 ET FOR2;
  130. FIN BLOC1;
  131. *
  132. CHA3 = (MOMENT MZ -15000 PA) ET (MOMENT MZ 15000 PB);
  133. *
  134. CHAR1 = CHA1 ET CHA2 ET CHA3;
  135. *
  136. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  137. *           resolution : champs de deplacements       *
  138. *                        champ de contraintes         *
  139. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  140. *
  141. DEPL1 = RESO RIGI1 CHAR1;
  142. *
  143. * Trace facultatif de la deformee
  144. *
  145. REAC1 = REAC RIGI1 DEPL1;
  146. SI (NEG GRAPH 'N');
  147.    TITR 'ELAS13 : DEFORMEE, CHARGEMENT, REACTIONS';
  148.    VECT1 = VECT CHAR1 1.E-4 FX FY FZ ROUGE;
  149.    VECT2 = VECT REAC1 1.E-4 FX FY FZ BLEU;
  150.    DEF0 = DEFO SUR1 DEPL1 0.;
  151.    DEF1 = DEFO SUR1 DEPL1 20. (VECT1 ET VECT2) VERT;
  152.    TRAC (0. 0. 1000.) SUR1 (DEF0 ET DEF1);
  153. FINSI;
  154. *
  155. SIGM1 = SIGM MODL1 MATR1 DEPL1;
  156. SIGM2 = CHAN NOEUD MODL1 SIGM1;
  157. SIGM3 = CHAN CHPO MODL1 SIGM2;
  158. *
  159. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  160. *              extraction des resultats               *
  161. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  162. *
  163. * Rotation du point A :
  164. RZA1 = EXTR DEPL1 RZ PA;
  165. RZA2 = -3.045E-3;
  166. ERG1 = 100 * (ABS ((RZA2 - RZA1) / RZA2));
  167. *
  168. * Reaction au point A :
  169. VA1  = EXTR REAC1 FY PA;
  170. VA2  = 1.1674E4;
  171. ERG2 = 100 * (ABS ((VA2 - VA1) / VA2));
  172. *
  173. * Fleche au point D :
  174. UYD1 = EXTR DEPL1 UY PD;
  175. UYD2 = -4.23326E-3;
  176. ERG3 = 100 * (ABS ((UYD2 - UYD1) / UYD2));
  177. *
  178. * Moment de flexion au point D :
  179. MD1  = EXTR SIGM3 MOMZ PD;
  180. MD2  = 3.3840E4;
  181. ERG4 = 100 * (ABS ((MD1 - MD2) / MD2));
  182. *
  183. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  184. *               affichage des resultats               *
  185. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  186. *
  187. MESS 'RESULTATS : TEST ELAS13';
  188. MESS '-----------------------';
  190. *
  191. MESS ' Rotation du point A ';
  192. MESS ' ------------------- ';
  193. MESS '      Valeur theorique :' RZA2 'rad';
  194. MESS '      Valeur calculee  :' RZA1 'rad';
  195. MESS '                 Ecart :' ERG1 '%';
  197. *
  198. MESS ' Reaction au point A ';
  199. MESS ' ------------------- ';
  200. MESS '      Valeur theorique :' VA2 'N';
  201. MESS '      Valeur calculee  :' VA1 'N';
  202. MESS '                 Ecart :' ERG2 '%';
  204. *
  205. MESS ' Fleche au point D ';
  206. MESS ' ----------------- ';
  207. MESS '      Valeur theorique :' UYD2 'm';
  208. MESS '      Valeur calculee  :' UYD1 'm';
  209. MESS '                 Ecart :' ERG3 '%';
  211. *
  212. MESS ' Moment de flexion au point D ';
  213. MESS ' ---------------------------- ';
  214. MESS '      Valeur theorique :' MD2 'N.m';
  215. MESS '      Valeur calculee  :' MD1 'N.m';
  216. MESS '                 Ecart :' ERG4 '%';
  218. *
  219. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  220. *                code fonctionnement                  *
  221. *+++++++++++++++++++++++++++++++++++++++++++++++++++++*
  222. ERGMAX = MAXI (PROG ERG1 ERG2 ERG3 ERG4);
  223. SI (ERGMAX <EG 5.);
  224.   ERRE 0;
  225. SINON;
  226.   ERRE 5;
  227. FINSI;
  228.  
  230. TEMPS;
  231.  
  232. FIN;
  233.  
  234.  
  235.  
  236.  
  237.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales