Télécharger la plaquette Cast3M


fr en

Télécharger elas12.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas12.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas12.dgibi: Jeux de données        *
  7. *           ---------------------------------         *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13     PROVENANCE : TEST
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19.   OPTI ECHO 1   ;
  20.   OPTI TRAC PSC ;
  21. SINO ;
  22.   OPTI ECHO 0   ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *_________________________________________________________
  27. *   TEST ELAS12                                          *
  28. *                                                        *
  29. *   ARC MINCE BI-ARTICULE EN FLEXION PLANE               *
  30. *                                                        *
  31. *   Test V.P.C.S. numero SSLL08/90                       *
  32. *                                                        *
  33. *   Reference : P. Dellus, Resistance des materiaux,     *
  34. *               Paris, Technique et Vulgarisation, 1958  *
  35. *                                                        *
  36. *     La structure est composee d'un arc de cercle d'un  *
  37. *   metre de rayon moyen, et de section circulaire creuse*
  38. *   Le diametre interieur est de 0.016 m, le diametre    *
  39. *   exterieur est de 0.02 m.                             *
  40. *                                                        *
  41. *     Une extremite (point A) est articule (UA = VA =0.) *
  42. *   l'autre extremite (point B) est bloque suivant y     *
  43. *   (VB = 0.). La structure est chargee par une force    *
  44. *   ponctuelle verticale au point C (centre de l'arc).   *
  45. *                                                        *
  46. *     On se propose de calculer les rotations en A et B, *
  47. *   ainsi que les deplacements horizontal du point B et  *
  48. *   vertical du point C.                                 *
  49. *                                                        *
  50. *     Les valeurs trouvees sont ensuites comparees aux   *
  51. *   valeurs de reference obtenues par solution           *
  52. *   analytique.                                          *
  53. *                                                        *
  54. *_________________________________________________________
  56. OPTI ELEM SEG2;
  57. *
  58. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  59. *                  maillage - geometrie                  *
  60. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  61. *
  62. PO =  0. 0. 0.;
  63. PA = -1. 0. 0.;
  64. PC =  0. 1. 0.;
  65. PB =  1. 0. 0.;
  66. *
  67. C1 = PA CERC 6 PO PC;
  68. C2 = PC CERC 6 PO PB;
  69. *
  70. SUR1 = C1 ET C2;
  71. *
  72. SI (NEG GRAPH 'N');
  73.    TITR 'ELAS12 : MAILLAGE';
  74.    TRAC (0. 0. 1000.) QUAL SUR1;
  75. FINSI;
  76. *
  77. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  78. *             calcul de la rigidite                      *
  79. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  80. *
  81. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE POUT;
  82. MATR1 = MATE MODL1 YOUN 2.E11 NU 0.3 TORS 1000.
  83.              SECT 1.131E-4 INRY 4.637E-9 INRZ 4.637E-9;
  84. RIGI1 = RIGI MODL1 MATR1;
  85. *
  86. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  87. *              conditions aux limites                    *
  88. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  89. *
  90. CL1 = BLOQ UX PA;
  91. CL2 = BLOQ UY PA;
  92. CL3 = BLOQ UY PB;
  93. *
  94. CL4 = BLOQ UZ SUR1;
  95. CL5 = BLOQ RX SUR1;
  96. *
  97. RIGI1 = RIGI1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5;
  98. *
  99. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  100. *                     chargement                         *
  101. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  102. *
  103. CHAR1 = FORC (0. -100 0.) PC;
  104. *
  105. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  106. *        resolution : champs de deplacements             *
  107. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  108. *
  109. DEPL1 = RESO RIGI1 CHAR1;
  110. *
  111. SI (NEG GRAPH 'N');
  112.   TITR' ELAS12 : DEFORMEE? CHARGEMENT, REACTIONS';
  113.   VECT1 = VECT CHAR1 FX FY FZ 4.E-3 ROUGE;
  114.   REAC1 = REAC RIGI1 DEPL1;
  115.   VECT2 = VECT REAC1 FX FY FZ 4.E-3 BLEU;
  116.   DEF0 = DEFO SUR1 DEPL1 0.;
  117.   DEF1 = DEFO SUR1 DEPL1 2. (VECT1 ET VECT2) VERT;
  118.   TRAC (0. 0. 1000.) SUR1 (DEF0 ET DEF1);
  119. FINSI;
  120. *
  121. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  122. *               extraction des resultats                 *
  123. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  124. *
  125. * Rotation au noeud A :
  126. RZA1 = -3.0774E-2;
  127. RZA2 = EXTR DEPL1 RZ PA;
  128. ERG1 = 100 * (ABS ((RZA1 - RZA2) / RZA1));
  129. *
  130. * Rotation au noeud B :
  131. RZB1 = 3.0774E-2;
  132. RZB2 = EXTR DEPL1 RZ PB;
  133. ERG2 = 100 * (ABS ((RZB1 - RZB2) / RZB1));
  134. *
  135. * Deplacement vertical du noeud C :
  136. UYC1 = -1.9206E-2;
  137. UYC2 = EXTR DEPL1 UY PC;
  138. ERG3 = 100 * (ABS ((UYC1 - UYC2) / UYC1));
  139. *
  140. * Deplacement horizontal au noeud B :
  141. UXB1 = 5.3912E-2;
  142. UXB2 = EXTR DEPL1 UX PB;
  143. ERG4 = 100 * (ABS ((UXB1 - UXB2) / UXB1));
  144. *
  145. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  146. *             affichage des resultats                    *
  147. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  148. *
  149. MESS 'RESULTATS : TEST ELAS12';
  150. MESS '-----------------------';
  152. *
  153. MESS '  Rotation au noeud A';
  154. MESS '  -------------------';
  155. MESS '     Valeur theorique :' RZA1 'rad';
  156. MESS '     Valeur calculee  :' RZA2 'rad';
  157. MESS '               Ecart  :' ERG1 '%';
  159. *
  160. MESS '  Rotation au noeud B';
  161. MESS '  -------------------';
  162. MESS '     Valeur theorique :' RZB1 'rad';
  163. MESS '     Valeur calculee  :' RZB2 'rad';
  164. MESS '               Ecart  :' ERG2 '%';
  166. *
  167. MESS '  Deplacement vertical du noeud C';
  168. MESS '  -------------------------------';
  169. MESS '     Valeur theorique :' UYC1 'm';
  170. MESS '     Valeur calculee  :' UYC2 'm';
  171. MESS '               Ecart  :' ERG3 '%';
  173. *
  174. MESS '  Deplacement horizontal au noeud B';
  175. MESS '  ---------------------------------';
  176. MESS '     Valeur theorique :' UXB1 'm';
  177. MESS '     Valeur calculee  :' UXB2 'm';
  178. MESS '               Ecart  :' ERG4 '%';
  180. *
  181. *
  182. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  183. *                    code fonctionnement                 *
  184. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  185. *
  186. ERGMAX = MAXI (PROG ERG1 ERG2 ERG3 ERG4);
  187. SI (ERGMAX <EG 5.);
  188.   ERRE 0;
  189. SINON;
  190.   ERRE 5;
  191. FINSI;
  193.  
  194. TEMPS;
  195.  
  196. FIN;
  197.  
  198.  
  199.  
  200.  
  201.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales