Télécharger la plaquette Cast3M


fr en

Télécharger elas1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test elas1.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI ECHO 1   ;
  19.   OPTI TRAC PSC ;
  20. SINO ;
  21.   OPTI ECHO 1   ;
  22. FINSI ;
  23.  
  24. *______________________________________________________
  25. * TEST ELAS1
  26. *
  27. * Une calotte sph}rique est soumise :
  28. *                 - @ une pression interne
  29. *                 - @ son poids propre
  30. *                 - @ une force radiale en tete
  31. *
  32. * En élasticité et en supposant le probleme
  33. * axisymétrique, on se propose de calculer le
  34. * déplacement radial en tete de la calotte.
  35. *
  36. * Pour résoudre ce probleme on utilise le principe
  37. * de superposition. Les forces équivalentes pour chaque
  38. * chargement sont calculées puis ajoutées avant de
  39. * résoudre le systeme.
  40. *
  41. * Le déplacement radial en tete calculé est comparé à
  42. * la valeur théorique égale à 4.677 microns.
  43. *
  44. *______________________________________________________
  45. TITRE 'CALOTTE SPHERIQUE SOUS PLUSIEURS TYPES DE CHARGEMENT';
  46. OPTION DIME 2 ELEM SEG2 MODE AXIS ;
  47.  
  48. *______________________________________________________
  49. *------------------ DEFINITION DE LA GEOMETRIE --------
  50. *______________________________________________________
  51. *
  52. A = 0 0 ;
  53. B = 1 1 ;
  54. O = 0 1 ;
  55. *
  56. L1 = CERC 100 A O B ;
  57. *
  58. SI (NEG GRAPH 'N');
  59.   TRAC (L1 ET O) 'QUAL' ;
  60. FINSI;
  61.  
  62. *______________________________________________________
  63. *----- DEFINITION DES CONDITIONS AUX LIMITES ---------
  64. *______________________________________________________
  65.  
  66. CL1 = BLOQ B UZ ;
  67. CL2 = BLOQ A UR ;
  68. CL = CL1 ET CL2 ;
  69.  
  70. *______________________________________________________
  71. * DEFINITION DU MODELE, DU MATERIAU
  72. *   ET DES CARACTERISTIQUES
  73. *______________________________________________________
  74. MO = MODE L1 MECANIQUE ELASTIQUE COQ2 ;
  75.  
  76. MA = MATE MO YOUN 2.1E11 NU 0.3 RHO 7.85E4 ;
  77. CA = CARA MO EPAI 0.02 ;
  78. MA=MA ET CA;
  79. *______________________________________________________
  80. *------- CALCUL DE LA MATRICE DE RIGIDITE -------------
  81. *______________________________________________________
  82. RI1 = RIGI MO MA ;
  83. RI2 = RI1 ET CL ;
  84. *______________________________________________________
  85. *-------------- DEFINITION DES CHARGES ----------------
  86. *______________________________________________________
  87. *
  88. *
  89. *------------ PRESSION INTERNE UNIFORME ---------------
  90. *
  91. MOP = 'MODE' L1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  92. MAP = 'MATE' MOP 'EPAI' 0.02 ;
  93. CHP = 'PRES' MOP 'PRES' -10000 ;
  94. FO1 = 'BSIG' MOP CHP ;
  95. *
  96. * -- POIDS PROPRE (IL FAUT CALCULER LA MATRICE MASSE) -
  97. *
  98. MAS = MASSE MO MA;
  99. EL1 = CHANGE L1 POI1 ;
  100. POP = MANU CHPO EL1 1 UZ -1 ;
  101. FO2 = MAS*POP ;
  102. *
  103. *------------- FORCE RADIALE EN TETE ------------------
  104. *
  105. F=1000*2*PI;
  106. FO3 = FORC FR F B ;
  107. *
  108. FO = FO1 + FO2 + FO3 ;
  109. *______________________________________________________
  110. *--CALCUL PAR RESO DES DEPLACEMENTS ET POST-TRAITEMENT-
  111. *______________________________________________________
  112. RE = RESO RI2 FO ;
  113. DR = EXTR RE UR B ;
  114. DR = 1000000*DR ;
  115. SAUT PAGE ;
  117. MESS ' DEPLACEMENT RADIAL EN TETE   THEORIQUE CALCULE ' ;
  118. MESS '                            UR=4.677 MICRON UR =' DR 'MICRON';
  119. TEMPS ;
  120. *______________________________________________________
  121. *--------- CODE DE BON FONCTIONNEMENT -----------------
  122. *______________________________________________________
  123.  
  124. ERR=100*(ABS(4.677 -DR)/4.677);
  125. SI (ERR < 5);
  126.   ERRE 0;
  127. SINON;
  128.   ERRE 5;
  129. FINSI;
  130.  
  131. FIN;
  132.  
  133.  
  134.  
  135.  
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  
  142.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales