Télécharger la plaquette Cast3M


fr en

Télécharger deto.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  deto.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *---------------------------------------------------------------------
  6. * Validation de l'opérateur DETO : Comparaison de la pression, de la
  7. * température et de la vitesse de Chapman-Jouguet pour deux mélanges
  8. * H2/O2/N2 entre des données expérimentales, un calcul de référence
  9. * et l'opérateur DETO.
  10. *---------------------------------------------------------------------
  11. * On crée un CHAMPOINT contenant les conditions suivantes
  12. *    Pression et température du mélange 1.atm et 291.K
  13. *    Nombre de moles des différents constituants
  14. *       Point P1  H2=2. O2=1. N2=3. H2O=0.
  15. *       Point P2  H2=2. O2=1. N2=5. H2O=0.
  16. *    Valeurs de référence à 291K ET 1atm
  17. *                                     Vcj(m/s)
  18. *                PCJ(atm) TCJ(K)  Calculée et mesurée
  19. *       Point P1  15.63    3003   2033.       2055.
  20. *       Point P2  14.39    2685   1850.       1822.
  21. *    Référence : Combustion, flames and explosion of gases,
  22. *                B.Lewis and G.von Elbe, page 545, Academic Press ed.
  23. *---------------------------------------------------------------------
  24. * Les différences observées entre le résultat du calcul DETO et le
  25. * résultat du calcul de référence s'expliquent essentiellement par
  26. * le fait que DETO utilise une cinétique chimique à une seule réation.
  27. *---------------------------------------------------------------------
  28. *
  29. *- Initialisations
  30. *
  31. OPTI DIME 2 ELEM QUA4 ECHO 0 ;
  32. P1   = 0. 0. ;
  33. P2   = 2. 0. ;
  34. P1P2 = P1 'DROI' 1 P2 ;
  35. X Y  = 'COOR' P1P2 ;
  36. CHP3 = 'MANU' 'CHPO' P1P2 1 'H2' 2. ;
  37. CHP1 = 'MANU' 'CHPO' P1P2 1 'O2' 1. ;
  38. CHP4 = 'MANU' 'CHPO' P1P2 1 'H2O' 0. ;
  39. CHP2 = 'EXCO' 'SCAL' (x + 3.) 'N2' ;
  40. CHP5 = 'MANU' 'CHPO' P1P2 1 'P' 101325. ;
  41. CHP6 = 'MANU' 'CHPO' P1P2 1 'T' 291. ;
  42. *
  43. *- Calcul
  44. *
  45. CHPTOT = CHP1 + CHP2 + CHP3 + CHP4 + CHP5 + CHP6 ;
  46. CHPR1 CHPR2 CHPR3 = 'DETO' CHPTOT ;
  47. *
  48. *- Récupération des valeurs pour comparaison
  49. *
  50. P01 = ('EXTR' CHPR1 'PCJ' P1) / 101325.;
  51. T1  = 'EXTR' CHPR1 'TCJ' P1 ;
  52. V1  = 'EXTR' CHPR1 'VCJ' P1 ;
  53. *
  54. P02 = ('EXTR' CHPR1 'PCJ' P2) / 101325. ;
  55. T2  = 'EXTR' CHPR1 'TCJ' P2 ;
  56. V2  = 'EXTR' CHPR1 'VCJ' P2 ;
  57. *
  58. *- Affichage
  59. *
  60. P1ref = 15.63 ; T1ref = 3003. ; V1cref = 2033. ; V1mref = 2055. ;
  61. P2ref = 14.39 ; T2ref = 2685. ; V2cref = 1850. ; V2mref = 1822. ;
  62. F1 = '(F6.2)' ; F2 = '(F5.0)' ;
  63. 'MESS' '  ' ;
  64. CH1 = 'CHAI' 'FORMAT' F1 'Ref. Pt1 P=' P1ref
  65.              'FORMAT' F2 ' T=' T1ref ' V=' V1cref ' , ' V1mref ;
  66. 'MESS' CH1 ;
  67. CH1 = 'CHAI' 'FORMAT' F1 'DETO Pt1 P=' P01
  68.              'FORMAT' F2 ' T=' T1 ' V=' V1 ;
  69. 'MESS' CH1 ;
  70. 'MESS' '  ' ;
  71. CH1 = 'CHAI' 'FORMAT' F1 'Ref. Pt2 P=' P2ref
  72.              'FORMAT' F2 ' T=' T2ref ' V=' V2cref ' , ' V2mref ;
  73. 'MESS' CH1 ;
  74. CH1 = 'CHAI' 'FORMAT' F1 'DETO Pt2 P=' P02
  75.              'FORMAT' F2 ' T=' T2 ' V=' V2 ;
  76. 'MESS' CH1 ;
  77. 'MESS' '  ' ;
  78. *
  79. *- Test de bon fonctionnement : Erreur relative sur la Pcj
  80. *
  81. EPS1  = 0.05 ;
  82. TEST1 = ((P01 - P1ref) / P1ref 'ABS') '<' EPS1 ;
  83. TEST2 = ((P02 - P2ref) / P2ref 'ABS') '<' EPS1 ;
  84. 'SI' (TEST1 'ET' TEST2) ;
  85.     'ERRE' 0 ;
  86. 'SINO' ;
  87.     'ERRE' 5 ;
  88. 'FINS' ;
  89. 'FIN' ;
  90.  
  91.  
  92.  
  93.  
  94.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales