Télécharger la plaquette Cast3M


fr en

Télécharger convdif1d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : convdif1d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * NOM         : CONVDIF1D
  5. * DESCRIPTION : 1D convection-diffusion equation
  6. *               
  7. *               See:
  8. *               ENSTA Lecture Notes 2021
  9. *               Introduction to the finite element method applied to 
  10. *               incompressible fluid mechanics (in english)
  11. *               Introduction a la methode des elements finis en
  12. *               mecanique des fluides incompressibles (en francais)
  13. *               Stephane GOUNAND and Sergey KUDRIAKOV
  14. *               http://www-cast3m.cea.fr/index.php?xml=supportcours
  15. *
  16. * LANGAGE     : GIBIANE-CAST3M
  17. * AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
  18. *               mél : gounand@semt2.smts.cea.fr
  19. **********************************************************************
  20. * VERSION    : v1, 03/10/2008, version initiale
  21. * HISTORIQUE : v1, 03/10/2008, création
  22. ************************************************************************
  23. *
  24. 'OPTION' 'DIME' 2 'ELEM' 'QUA8' ;
  25. graph = FAUX ;
  26. *
  27. * Exact Solution : (1 - exp (2 Pe x)) / (1 - exp (2 Pe))
  28. * 
  29. 'DEBPROC' solex ;
  30. 'ARGUMENT' pe*'FLOTTANT' ;
  31. pe2 = '*' pe 2 ;
  32. lx = 'PROG' 0. 'PAS' 1.D-3 1. ;
  33. l1 = 'PROG' ('DIME' lx) * 1. ;
  34. num = '-' l1 ('EXP' ('*' lx pe2)) ;
  35. den = '-' 1. ('EXP' pe2) ;
  36. ly  = '/' num den ;
  37. evex = 'EVOL' 'MANU' lx ly ;
  38. 'RESPRO' evex ;
  39. 'FINPROC' ;
  40. *
  41. Peclet  = 10. ;
  42. *
  43. *
  44. * nmail    : number of mesh elements
  45. * dmail    : refinement factor at the right boundary (>= 1)
  46. * idecent = 1 : centered discretization for the convective term
  47. * idecent = 2 : SUPG numerical diffusion
  48. * cmd      : multiplicative coefficient for the SUPG numerical diffusion
  49. *            term 
  50.  
  51.  
  52. nmail = 6  ;
  53. dmail = 1. ;
  54. idecent = 1 ;
  55. cmd = 0.5 ; 
  56. * Densities
  57. dmoy = '/' 1. ('FLOTTANT' nmail) ;
  58. dini = '*' dmoy dmail ;
  59. dfin = '/' dmoy dmail ;
  60. * Upwinding
  61. 'SI' ('EGA' idecent 1) ;
  62.    typdec = 'CENTREE' ;
  63.    niter  = 1 ;
  64. 'FINSI' ;   
  65. 'SI' ('EGA' idecent 2) ;
  66.    typdec = 'SUPG' ;
  67.    niter  = 1 ;
  68. 'FINSI' ;
  69. *
  70. * Mesh
  71. *
  72. p0 = 0. 0. ; p1 = 1. 0. ;
  73. lt = 'DROIT' ('*' nmail -1) p0 p1 'DINI' dini 'DFIN' dfin ;
  74. bas = lt ;
  75. mt  = 'TRANSLATION' lt 1 (0. 1.) ;
  76. gau = 'COTE' 4 mt ;
  77. dro = 'COTE' 2 mt ;
  78. _bas = 'CHANGER' bas 'QUAF' ;
  79. _gau = 'CHANGER' gau 'QUAF' ;
  80. _dro = 'CHANGER' dro 'QUAF' ;
  81. _mt  = 'CHANGER' mt 'QUAF' ;
  82. 'ELIMINATION' (_mt 'ET' _bas 'ET' _gau 'ET' _dro) 1.D-6 ;
  83. $mt = 'MODE' _mt 'NAVIER_STOKES' 'LINE' ;
  84. $bas = 'MODE' _bas 'NAVIER_STOKES' 'LINE' ;
  85. $gau = 'MODE' _gau 'NAVIER_STOKES' 'LINE' ;
  86. $dro = 'MODE' _dro 'NAVIER_STOKES' 'LINE' ;
  87. mt = 'DOMA' $mt 'MAILLAGE' ;
  88. bas = 'DOMA' $bas 'MAILLAGE' ;
  89. gau = 'DOMA' $gau 'MAILLAGE' ;
  90. dro = 'DOMA' $dro 'MAILLAGE' ;
  91. *
  92. * Problem description 
  93. *
  94. rv = 'EQEX' 'NITER' niter 
  95.      'OPTI' 'EF' 'IMPL' typdec 'CMD' cmd 
  96.      'ZONE' $mt 'OPER' 'KONV' 1. 'UN' 'ALF' 'INCO' 'TN'
  97.      'OPTI' 'EF' 'IMPL' 'CENTREE'
  98.      'ZONE' $mt 'OPER' 'LAPN' 'ALF' 'INCO' 'TN'
  99.      'CLIM' gau 'TN' 'TIMP' 0.
  100.      'CLIM' dro 'TN' 'TIMP' 1.
  101.       ;
  102. rv . 'INCO' = 'TABLE' 'INCO' ;
  103. rv . 'INCO' . 'UN'  = 'KCHT' $mt 'VECT' 'SOMMET' (1. 0.) ;
  104. rv . 'INCO' . 'ALF' = 'KCHT' $mt 'SCAL' 'CENTRE' ('/' 0.5 Peclet) ;
  105. rv . 'INCO' . 'TN'  = 'KCHT' $mt 'SCAL' 'SOMMET' 0. ;
  106. *
  107. EXEC rv ;
  108. *
  109. * Post treatment
  110. *
  111. tn = rv . 'INCO' . 'TN' ;
  112. evt = 'EVOL' 'CHPO' tn 'SCAL' bas ;
  113. evx = SOLEX Peclet ;
  114. evtot = evt 'ET' evx ;
  115. *
  116. tabt = 'TABLE' ; tabt . 'TITRE' = 'TABLE' ;
  117. tabt . 1 = 'CHAINE' 'TIRC MARQ CROI' ;
  118. tabt . 'TITRE' . 1 = 'CHAINE' 'Sol. App.' ;
  119. tabt . 'TITRE' . 2 = 'CHAINE' 'Sol. Exa.' ;
  120. 'SI' graph ;
  121.    'DESSIN' evtot 'TITX' 'X' 'TITY' 'T'
  122.           'TITR' ('CHAINE' 'Peclet=' Peclet)
  123.           'LEGE' tabt ;
  124.    'OPTION' 'DONN' 5 ;
  125. 'FINSI' ;
  126. *
  127. * End of dgibi file CONVDIF1D
  128. *
  129. 'FIN' ;
  130.  
  131.  
  132.  
  133.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales