Exemples de jeux de données Cast3M

* fichier : conv2d.dgibi
************************************************************************
************************************************************************
* NOM         : CONV2D
* DESCRIPTION : 2D pure convection equation
*
*               See:
*               ENSTA Lecture Notes 2021
*               Introduction to the finite element method applied to 
*               incompressible fluid mechanics (in english)
*               Introduction a la methode des elements finis en
*               mecanique des fluides incompressibles (en francais)
*               Stephane GOUNAND and Sergey KUDRIAKOV
*               http://www-cast3m.cea.fr/index.php?xml=supportcours
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
*               mél : gounand@semt2.smts.cea.fr
**********************************************************************
* VERSION    : v1, 31/10/2008, version initiale
* HISTORIQUE : v1, 31/10/2008, création
************************************************************************
*
'OPTION' 'DIME' 2 'ELEM' 'QUA8' ;
graph = faux ;
*
* Scaled hyperbolic tangent function
*
'DEBPROC' STANH ;
'ARGUMENT' xmoy*'FLOTTANT' ;
'ARGUMENT' xtan*'FLOTTANT' ;
'ARGUMENT' ymin*'FLOTTANT' ;
'ARGUMENT' ymax*'FLOTTANT' ;
'ARGUMENT' xi*'CHPOINT' ;
*
xnew = '/' ('-' xi xmoy) xtan ; 
ynew = 'TANH' xnew ;
ytan = '/' ('-' ymax ymin) 2.D0 ;
ymoy = '/' ('+' ymax ymin) 2.D0 ;
y = '+' ('*' ynew ytan) ymoy ;
*
'RESPRO' y ;
'FINPROC' ;
*
* iini = 1 : smooth boundary condition (tanh function)
* iini = 2 : shock-like boundary condition
* ang      : angle in degrees between y-axis and convective speed
* nmail    : number of mesh elements in each direction
* idecent = 1 : centered discretization for the convective term
* idecent = 2 : artificial numerical diffusion
* idecent = 3 : SUPG numerical diffusion
* idecent = 4 : SUPGDC numerical diffusion
* cmd      : multiplicative coefficient for the SUPG numerical diffusion
*            term 
* itrac = 1 : 3D post-treatment + isovalues
* itrac = 2 : 3D post-treatment
* itrac = 3 : 2D post-treatment
*
iini    = 1 ;
ang     = 10. ;
nmail   = 15 ;
idecent = 3 ;
cmd     = 0.5 ;
itrac   = 2 ;
*
lmesh = 1.5 ;
'SI' ('EGA' idecent 1) ;
   typdec = 'CENTREE' ;
* very small diffusion
   difart = '/' ('/' lmesh ('FLOTTANT' nmail)) 2.D45 ;
*   difart = 0. ;
   niter  = 1 ;
   omeg   = 1. ;
'FINSI' ;   
'SI' ('EGA' idecent 2) ;
   typdec = 'CENTREE' ;
* alfa = U dx / 2 Pem with critical mesh Peclet number = 1
   difart = '/' ('/' lmesh ('FLOTTANT' nmail)) 2. ;
   difart = '*' difart cmd ;
   niter  = 1 ;
   omeg   = 1. ;
'FINSI' ;   
'SI' ('EGA' idecent 3) ;
   typdec = 'SUPG' ;
   difart = 0. ;
   niter  = 1 ;
   omeg   = 1. ;
'FINSI' ;   
'SI' ('EGA' idecent 4) ;
   typdec = 'SUPGDC' ;
   difart = 0. ;
   niter = 15 ;
   omeg  = 0.7 ;
'FINSI' ;   
*
* Mesh
*
p0 = 0. 0. ; p1 = lmesh 0. ;
lt = 'DROIT' nmail p0 p1 ;
mt  = 'TRANSLATION' lt nmail (0. lmesh) ;
cmt = 'CONTOUR' mt ;
bas dro hau gau = 'COTE' mt ;
hau = 'INVERSE' hau ;
_bas = 'CHANGER' bas 'QUAF' ; _dro = 'CHANGER' dro 'QUAF' ;
_hau = 'CHANGER' hau 'QUAF' ; _gau = 'CHANGER' gau 'QUAF' ;
_mt  = 'CHANGER' mt 'QUAF' ;
'ELIMINATION' (_mt 'ET' _bas 'ET' _gau 'ET' _dro 'ET' _hau) 1.D-6 ;
$mt = 'MODE' _mt 'NAVIER_STOKES' 'LINE' ;
$gau = 'MODE' _gau 'NAVIER_STOKES' 'LINE' ;
$dro = 'MODE' _dro 'NAVIER_STOKES' 'LINE' ;
$hau = 'MODE' _hau 'NAVIER_STOKES' 'LINE' ;
$bas = 'MODE' _bas 'NAVIER_STOKES' 'LINE' ;
mt = 'DOMA' $mt 'MAILLAGE' ; gau = 'DOMA' $gau 'MAILLAGE' ;
dro = 'DOMA' $dro 'MAILLAGE' ; hau = 'DOMA' $hau 'MAILLAGE' ;
bas = 'DOMA' $bas 'MAILLAGE' ;
*
* Boundary condition
*
'SI' ('EGA' iini 1) ;
   solex = STANH ('COORDONNEE' 1 mt) 0.5 -0.15 0. 1. ;
'SINON' ;   
   solex = 'MASQUE' ('COORDONNEE' 1 mt) 'INFERIEUR' 0.5 ;
'FINSI' ;   
mclim = 'ET' bas gau ;
cclim = 'REDU' solex mclim ;
*
* Problem description
*
rv = 'EQEX' 'NITER' niter 'OMEGA' omeg
     'OPTI' 'EF' 'IMPL' typdec 'CMD' cmd
     'ZONE' $mt 'OPER' 'KONV' 1. 'UN' 'ALF' 'INCO' 'TN'
     'OPTI' 'EF' 'IMPL' 'CENTREE'
     'ZONE' $mt 'OPER' 'LAPN' 'ALF' 'INCO' 'TN'
     'CLIM' mclim 'TN' 'TIMP' cclim
      ;
rv . 'INCO' = 'TABLE' 'INCO' ;
rv . 'INCO' . 'UN'  = 'KCHT' $mt 'VECT' 'SOMMET' (('SIN' ang)
                                                  ('COS' ang)) ;
rv . 'INCO' . 'ALF' = 'KCHT' $mt 'SCAL' 'CENTRE' difart ;
rv . 'INCO' . 'TN'  = 'KCHT' $mt 'SCAL' 'SOMMET' 0. ;
*
EXEC rv ;
*
tn = rv . 'INCO' . 'TN' ;
*
* Post-treatment
*
'SI' graph ;
   'SI' ('EGA' itrac 1) ;
      'OPTI' 'DIME' 3 ;
      tnp mtp = 'PLUS' tn mt ('*' ('NOMC' 'UZ' tn) 0.5D0) ;
      oeil = '*' (1.2 -2.4 1.3) 2. ;
      'TRACER' oeil 'CACH' tnp mtp ; 
      'OPTI' 'DIME' 2 ;
   'FINSI' ;
   'SI' ('EGA' itrac 2) ;
      'OPTI' 'DIME' 3 ;
      mtp = 'PLUS' mt ('*' ('NOMC' 'UZ' tn) 0.5D0) ;
      oeil = '*' (1.2 -2.4 1.3) 2. ;
      'TRACER' oeil 'CACH' mtp ;
      'OPTI' 'DIME' 2 ;
   'FINSI' ;
   'SI' ('EGA' itrac 3) ;
      evb = 'EVOL' 'CHPO' tn 'SCAL' bas ;
      evh = 'EVOL' 'CHPO' tn 'SCAL' hau ;
*   evtot = ('COULEUR' evh 'JAUN') 'ET' ('COULEUR' evb 'TURQ') ;
      evtot = evh 'ET' evb ;
      tabt = 'TABLE' ; tabt . 'TITRE' = 'TABLE' ;
      tabt . 1 = 'CHAINE' 'TIRC MARQ CROI' ;
      tabt . 'TITRE' . 1 = 'CHAINE' 'y=1' ;
      tabt . 'TITRE' . 2 = 'CHAINE' 'y=0' ;
      'DESSIN' evtot 'TITX' 'X' 'TITY' 'T' 'LEGE' tabt ;
   'FINSI' ;
   'OPTION' 'DONN' 5 ;
'FINSI' ;   
*
* End of dgibi file CONV2D
*
'FIN' ;