Télécharger la plaquette Cast3M


fr en

Télécharger cl_D_3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  cl_D_3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *C***********************************************************************
  5. *C*                                                                     *
  6. *C* PROJET      : Opérateur CLMI                                        *
  7. *C* NOM         : cl_D_3  .dgibi                                        *
  8. *C* DESCRIPTION : Jeu de données pour le calcul de la couche limite     *
  9. *C*               turbulente en utilisant les relations de fermeture de *
  10. *C*               Cousteix - Cas de la plaque plane sans gradient de    *
  11. *C*               pression                                              *
  12. *C* LANGAGE     : Gibiane                                               *
  13. *C* AUTEUR      : Guillaume VENCO - DRN/DMT/SEMT/LTMF                   *
  14. *C*                                                                     *
  15. *C***********************************************************************
  16. *C*                                                                     *
  17. *C* APPELES     : Opérateur CLMI                                        *
  18. *C*                                                                     *
  19. *C***********************************************************************
  20. *C*                                                                     *
  21. *C*                                                                     *
  22. *C***********************************************************************
  23. *C*                                                                     *
  24. *C* VERSION     : 02/05/2000                                            *
  25. *C* CREATION    : 06/04/2000                                            *
  26. *C*                                                                     *
  27. *C***********************************************************************
  28.  
  29. 'OPTION' dime 2 elem seg2 ;
  30. 'OPTION'  trace x ;
  31. GRAPH=FAUX ;
  32. COMPLET=FAUX ;
  33.  
  34. *                  ****************************
  35. *                  ***  Maillage et Domaine ***
  36. *                  ****************************
  37.  
  38. *Maillage
  39. P1 = 0.3 0.;
  40. p2 =  10. 0. ;
  41. nb1 = 10;
  42. p1p2 = 'DROIT' p1 p2 'DINI' 0.01 'DFIN' 1. ;
  43. *p1p2 = 'DROIT' p1 p2 20;
  44. mt = p1p2 ;
  45. * 'TRACER'  mt ;
  46.  
  47. *Définition du modèle
  48. Mmt = 'CHANGER'  mt 'QUAF' ;
  49. Mail = 'CHANGER' Mmt 'POI1';
  50. Pt0 = Mail 'ELEM' 1;
  51. $mt = 'MODELISER'  Mmt 'NAVIER_STOKES' 'LINE' ;
  52.  
  53. *                  ****************************
  54. *                  * Propriétés phy & Données *
  55. *                  ****************************
  56.  
  57. *Données
  58. Ue0 = 1.;
  59. NU = 1.d-6 ;
  60.  
  61. *Valeurs initiales données par la loi de puissance
  62. D20=8.67d-4;
  63. Q10=6.42*D20;
  64.  
  65. *Pas de temps et nombre de pas
  66. DT = 1.;
  67.  
  68. NBIT =25 ;
  69. Si complet;
  70. NBIT =100;
  71. Finsi ;
  72. *Champ de vitesse à l'extérieur
  73. *vitesse en puissance
  74. K=1.;
  75. m=(0.);
  76. m1= 'DOMA' $mt 'SOMMET';
  77. X = 'COORDONNEE' 1 m1;
  78. X1 = (X**m);
  79. UEX = K*X1;
  80. UE = 'KCHT' $mt scal 'SOMMET' UEX;
  81. X2 = (X**(m-1));
  82. DUEX = K*m*X2 ;
  83. DUE = 'KCHT' $mt scal 'SOMMET' DUEX;
  84.  
  85. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  86. *>>>>>>>>>>>>Création de la table RV et de la table RK>>>>>>
  87. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  88.  
  89. *Dans CLMI le 1er coef correspond au type de fermeture
  90. *le 2ème coef correspond au n°de l'équation à traiter
  91. *1=QDM 2=Energie cinétique
  92.  
  93. rv = 'EQEX'  'OMEGA' 1.  'NITER' 1  'ITMA' 0   'FIDT' 1
  94.      'OPTI' 'EF' 'IMPL' 'CENTREE' 'BDF2'
  95.      'ZONE' $mt
  96.      'OPER' 'DFDT' 1. 'D2NM' 'D2N2' DT  'INCO' 'D2' ;
  97. *     'OPER' 'DFDT' 1. 'D2NM' DT  'INCO' 'D2' ;
  98.  
  99. rv = 'EQEX' rv
  100.      'OPTI' 'EF' 'IMPL' 'SUPG'
  101.       'ZONE'  $mt
  102.      'OPER'  'CLMI' 4 1 UE DUE 'D2NM' 'Q1NM'
  103.      'INCO' 'D2' ;
  104.  
  105. rv = 'EQEX' rv
  106.      'OPTI' 'EF' 'IMPL' 'CENTREE' 'BDF2'
  107.      'ZONE' $mt
  108.      'OPER' 'DFDT' 1. 'Q1NM' 'Q1N2' DT  'INCO' 'Q1' ;
  109. *     'OPER' 'DFDT' 1. 'D1NM' DT  'INCO' 'D1' ;
  110.  
  111. rv = 'EQEX' rv
  112.      'OPTI' 'EF' 'IMPL' 'SUPG'
  113.      'ZONE'  $mt
  114.      'OPER'  'CLMI' 4 3 UE DUE 'Q1NM' 'D2NM'
  115.      'INCO' 'Q1' ;
  116.  
  117. rv = 'EQEX' rv
  118.       'CLIM' 'D2' 'TIMP' pt0 D20
  119.       'CLIM' 'Q1' 'TIMP' pt0 Q10;
  120.  
  121.  
  122. rv.inco = 'TABLE'  inco ;
  123. rv.inco.'D2'=  'KCHT'  $mt scal sommet D20;
  124. rv.inco.'D2NM'=  'KCHT'  $mt scal sommet D20;
  125. rv.inco.'D2N2'=  'KCHT'  $mt scal sommet D20;
  126. rv.inco.'Q1'=  'KCHT'  $mt scal sommet Q10;
  127. rv.inco.'Q1NM'=  'KCHT'  $mt scal sommet Q10;
  128. rv.inco.'Q1N2'=  'KCHT'  $mt scal sommet Q10;
  129.  
  130. ltps = 'PROG' 0. ;
  131. lteta = 'PROG' 0. ;
  132. TPS = 0. ;
  133. nupt = 0 ;
  134. mts1 = 'DOMA'  $mt 'SOMMET' ;
  135. pt1 = 'POIN'  mts1 2 ;
  136. 'LISTE'  pt1 ;
  137.  
  138. *'OPTION'  donn 5 ;
  139.  
  140. 'REPETER'  BCLT nbit ;
  141. nupt=nupt+1;
  142. tps=tps+dt ;
  143. mess ' Pas de temps DT=' dt ' Temps = ' tps ;
  144. ltps=ltps et (prog tps) ;
  145. EXEC  rv ;
  146. teta='EXTRAIRE'  (rv.inco.'D2') 'SCAL' pt1 ;
  147. mess ' Teta=' teta ;
  148. lteta= lteta et ('PROG' teta);
  149.  
  150.  
  151. YNM = rv.'INCO'.'D2NM';
  152. ZNM = rv.'INCO'.'Q1NM';
  153.  
  154. rv.'INCO'.'D2N2' = rv.'INCO'.'D2NM';
  155. rv.'INCO'.'D2NM' = rv.'INCO'.'D2';
  156. rv.'INCO'.'Q1N2' = rv.'INCO'.'Q1NM';
  157. rv.'INCO'.'Q1NM' = rv.'INCO'.'Q1';
  158.  
  159. 'FIN'  bclt ;
  160.  
  161. li4 = 'PROG' 'EXPO' 'A' -1. 'B' 0. ltps;
  162. evt2 = 'EVOL' 'ROUGE' manu ltps li4 ;
  163. evt= evol manu ltps lteta;
  164.  
  165.  
  166.  
  167. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  168. *>>>>>>>>>>>>>>>>>>>>>>> résultats>>>>>>>>>>>>>>>>>>>>>>>>>>
  169. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  170. *évolution de la vitesse extérieure et du gradient
  171. vit = 'EVOL' 'CHPO' UE mt;
  172. gvit = 'EVOL' 'ROUG' 'CHPO' DUE mt;
  173. *quantité de mouvement
  174. D2S = (rv.inco.'D2');
  175. RD2S = UE*D2S/NU;
  176. ev1s = 'EVOL' 'ROUGE' 'CHPO' RD2S mt;
  177. *différence entre (d-d1)
  178. Q1S = (rv.inco.'Q1');
  179. RQ1S = UE*Q1S/NU;
  180. ev2s = 'EVOL' 'ROUGE' 'CHPO' RQ1S mt;
  181. *Epaisseur de déplacement
  182. D1S = (rv.'INCO'.'D1');
  183. RD1S = UE*D1S/NU;
  184. ev3s = 'EVOL' 'ROUGE' 'CHPO' RD1S mt;
  185. *évolution du frottement à la paroi
  186. CfS = rv.'INCO'.'CF';
  187. ev4s = 'EVOL' 'ROUGE' 'CHPO' CfS mt;
  188. *évolution du facteur de forme H final
  189. HS = rv.'INCO'.'H';
  190. ev5s = 'EVOL' 'ROUGE' 'CHPO' HS mt;
  191. *évolution du facteur H*
  192. HHS = Q1S*(D2S**(-1));
  193. ev6s = 'EVOL' 'ROUGE' 'CHPO' HHS mt;
  194.  
  195.  
  196. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  197. *solution théorique cf:SCHLICHTING >>>>>>>>>>>>>>>>>>>>>>>>
  198. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  199. RX = X*UE*(1./NU);
  200. *Quantité de mvt
  201. *----Rteta donné par Nikuradze
  202. RD2N = (0.01738/1.304)*(RX**(0.861)); 
  203. ev1n =  'EVOL' 'BLEU' 'CHPO' RD2N mt;
  204. *----Rteta par la loi de puissance
  205. RD2P = (1./1.e-6)*(0.036*X*(RX**(-1./5)))*UE;
  206. ev1p = 'EVOL' 'VERT' 'CHPO' RD2P mt;
  207. *différence (d-d1) théorique
  208. Q1P=(0.37-(1.2857*0.036))*(X*(RX**(-1./5)));
  209. RQ1P=UE*Q1P/NU;
  210. ev2p='EVOL' 'VERT' 'CHPO' RQ1P mt;
  211. *Epaisseur de déplacement
  212. *----Rdelta1 par la Nikuradze
  213. RD1N = 1.304*RD2N;
  214. ev3n = 'EVOL' 'BLEU' 'CHPO' RD1N mt;
  215. *----Rdelta1 par la loi de puissance
  216. RD1P = (9./7.)*RD2P;
  217. ev3p = 'EVOL' 'VERT' 'CHPO' RD1P mt;
  218. *Coefficient de frottement
  219. *----Formule par Nikuradze
  220. CfN = 0.02296*(RX**(-0.139));
  221. ev4n = 'EVOL' 'BLEU' 'CHPO' CfN mt;
  222. *----Formule par loi de puissance
  223. CfP = 0.0576*(RX**(-1./5.));
  224. ev4p = 'EVOL' 'VERT' 'CHPO' CfP mt;
  225. *facteur de forme
  226. *----H par Nikuradze
  227. HN = 'KCHT' $mt scal sommet 1.304;
  228. ev5n = 'EVOL' 'BLEU' 'CHPO' HN mt;
  229. *----H par loi de puissance
  230. HP = 'KCHT' $mt scal sommet 1.2857;
  231. ev5p = 'EVOL' 'VERT' 'CHPO' HP mt;
  232. *coef H* théorique
  233. HHP='KCHT' $mt scal sommet 7.89;
  234. ev6p= 'EVOL' 'BLEU' 'CHPO' HHP mt;
  235.  
  236. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  237. *Courbes>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  238. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  239. 'OPTION' trace psc;
  240.  
  241. Si Graph ;
  242. 'DESSIN'  (evt) 'TITR' 'Convergence de la valeur au dernier noeud'
  243.            'TITY' 'Valeurs de Y' 'TITX' 'Temps';
  244.  
  245. 'DESSIN' (vit 'ET' gvit)
  246.      'TITRE' 'Vitesse et gradient de vitesse extérieure';
  247.  
  248. TAB1 = 'TABLE' ;
  249. TAB1.'TITRE' = 'TABLE' ;
  250. TAB1.'TITRE' . 1 = MOT ' Simulation';
  251. TAB1.'TITRE' . 2 = MOT ' Nikuradze';
  252. TAB1.'TITRE' . 3 = MOT ' Loi de puissance';
  253.  
  254. TAB2 = 'TABLE' ;
  255. TAB2.'TITRE' = 'TABLE' ;
  256. TAB2.'TITRE' . 1 = MOT ' Simulation';
  257. TAB2.'TITRE' . 2 = MOT ' Loi de puissance';
  258.  
  259. 'DESSIN' (ev1s 'ET' ev1n 'ET' ev1p)
  260.        'TITRE' 'Epaisseur de quantité de mouvement'
  261.        'TITY' 'Rteta'
  262.        'TITX' 'Abscisses'
  263.        'GRIL'
  264.        'LEGE' TAB1;       
  265.  
  266. 'DESSIN' (ev2s 'ET' ev2p) 'TITRE' 'différence entre delta et delta1' 
  267.        'TITY' 'Rdelta-Rdelta1'
  268.        'TITX' 'Abscisses'
  269.        'GRIL'
  270.        'LEGE' TAB2;              
  271.  
  272. 'DESSIN' (ev3s 'ET' ev3n 'ET' ev3p)
  273.        'TITRE' 'Epaisseur de déplacement'
  274.        'TITY' 'Rdelta1'
  275.        'TITX' 'Abscisses'
  276.        'GRIL'
  277.        'LEGE' TAB1;
  278.  
  279. 'DESSIN' (ev4s 'ET' ev4n 'ET' ev4p)
  280.            'TITRE' 'Coefficient de frottement à la paroi'
  281.            'TITX' 'Abscisses'
  282.            'TITY' 'Cf'
  283.            'GRIL'
  284.            'LEGE' TAB1;
  285.  
  286. 'DESSIN' (ev5s 'ET' ev5n 'ET' ev5p)
  287.         'TITRE' 'Evolution du facteur de forme'
  288.         'TITX' 'Abscisses'
  289.         'TITY' 'H=delta1/theta'
  290.         'LEGE' TAB1;
  291.  
  292. 'DESSIN' (ev6s 'ET' ev6p) 'TITRE' 'Evolution du facteur H*'
  293.         'TITX' 'Abscisses'
  294.         'TITY' 'H'
  295.         'LEGE' TAB1;
  296.  
  297. Finsi ;
  298.  
  299. *calcul de l'erreur au sens de la norme L2
  300. diag = 'DOMA' $mt 'XXDIAGSI';
  301. r = (RD2S-RD2N)**2;
  302. r2= (RD2S-RD2P)**2;
  303. EL2N = 'SOMT'(diag*r);
  304. EL2P = 'SOMT'(diag*r2);
  305. 'MESSAGE' 'Erreur sur teta au sens de la norme L2=';
  306. 'LISTE'  EL2N;
  307. 'LISTE'  EL2P;
  308. r3=(RQ1S-RQ1P)**2;
  309. EL3P= 'SOMT'(diag*r3);
  310. 'MESSAGE' 'Erreur sur (delta-delta1) au sens de la norme L2=';
  311. 'LISTE'  EL3P;
  312.  
  313. Si graph ;
  314. *autre dessin
  315. a = 'EXTRAIRE' ev1s 'SCAL';
  316. log = 'LOG' a;
  317. l10= 'LOG' 10;
  318. loga = (1./l10)*log;
  319. b = 'EXTRAIRE' ev5s 'SCAL';
  320. evH = 'EVOL' 'MANU' 'Rtheta' a 'H' b;
  321. 'DESSIN' evH
  322.          'LOGX'
  323.          'TITRE' 'facteur de forme en couche limite turbulente'
  324.          'TITX' 'Log(Rtheta)'
  325.          'TITY' 'H'
  326.          'GRIL';
  327. Finsi ;
  328.  
  329.  'FIN';
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  
  342.  
  343.  
  344.  
  345.  
  346.  
  347.  
  348.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales