Télécharger la plaquette Cast3M


fr en

Télécharger channeldie5.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : channeldie5.dgibi
  2. *----------------------------------------------------------------------*
  3. *                  C H A N N E L D I E 4 . D G I B I                   *
  4. *----------------------------------------------------------------------*
  5. * Objet :                                                              
  6. * -------
  7. *
  8. *    Cas-test de validation des elements BBAR pour les elements tetra- 
  9. * - edre, pyramide et hexaerdre quadratiques.
  10. *
  11. *    Calcul elastique de la compression d'un lopin de metal place dans
  12. * une matrice l'empechant de se dilater lateralement (lopin coince dans
  13. * un "canal", d'ou "channel die").
  14. *
  15. *    Validation du calcul par comparaison a la solution analytique des
  16. * deplacements et de l'equilibre (F-Bsig). La solution en contrainte
  17. * s'avere peu precise (erreur de quelques pourcents).
  18. *
  19. *    Un 2nd chargement en deplacement impose sur la face superieure,
  20. * non uniforme en espace (varaition quadratique), permet de valider
  21. * l'integration dans les elements en verifiant l'equilibre (F-Bsig).
  22. *
  23. *    Verification du fonctionnement de l'operateur MASSE.
  24. *
  25. *    Verification et validation de l'operateur KSIG en deplacements.
  26. *
  27. * Description :
  28. * -------------
  29. *
  30. * Type de calcul : Mecanique Elastique
  31. * Mode de calcul : 3D
  32. * Type d'element : CU20, TE10, PY13
  33. * Chargement     : Deplacement impose
  34. *
  35. *----------------------------------------------------------------------*
  36. opti dime 3 mode TRID elem TE10 ;
  37.  
  38. * Pour affichages, mettre ig1 a VRAI :
  39. ig1      = faux ;
  40.  
  41. *------------------------------ MAILLAGE ------------------------------*
  42.  
  43. * Points :
  44. p1       = 0. 0. 0. ;
  45. p2       = 100. 0. 0. ;
  46. p3       = 100. 100. 0. ;
  47. p4       = 0. 100. 0. ;
  48. p5       = 0. 0. 100. ;
  49.  
  50. * Contour base :
  51. ne1      = 10 ;
  52. li1      = d ne1 p1 p2 ;
  53. li2      = d ne1 p2 p3 ;
  54. li3      = d ne1 p3 p4 ;
  55. li4      = d ne1 p4 p1 ;
  56.  
  57. * Surface et Volume :
  58. sur1     = dall li1 li2 li3 li4 'PLAN' ;
  59. vol1     = volu tran sur1 p5 ne1 ;
  60. sur2     = vol1 face 2 ;
  61. sx0      = (enve vol1) poin plan p1 P4 p5 1.e-3 ;
  62. sx0      = (enve vol1) elem appu stri sx0 ;
  63. sy0      = (enve vol1) poin plan p1 P2 p5 1.e-3 ;
  64. sy0      = (enve vol1) elem appu stri sy0 ;
  65. sur3     = sx0 et sy0 ;
  66. sur4     = (vol1 face 3) diff sur3 ;
  67. sur3     = sur3 chan tri6 ;
  68. sur0     = sur1 et sur2 et sur3 et sur4 ;
  69. vol1     = volu sur0 ;
  70. list (vol1 elem type) ;
  71.  
  72. si ig1 ;
  73.   trac cach vol1 titr 'Maillage lopin' ;
  74. fins ;
  75.  
  76. *--------------------- MODELE / CARACTERISTIQUES ----------------------*
  77.  
  78. * Valeurs modules d'elasticite :
  79. ym1      = 1.5e11 ;
  80. nu1      = 0.499 ;
  81.  
  82. * Modele et caracteristiques mecaniques :
  83. mod1     = modele vol1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'BBAR' ;
  84. mat1     = mate mod1 'YOUNG' 1.5e11 'NU' nu1 'RHO' 7.6e3 ;
  85.  
  86. * Matrice de raideur :
  87. rig1     = rigi mod1 mat1 ;
  88. mas1     = mass mod1 mat1 ;
  89.  
  90. *----------------------- CONDITIONS AUX LIMITES -----------------------*
  91.  
  92. * Definition des points d'interet :
  93. ptx0     = (vol1 coor 1) poin mini ;
  94. pty0     = (vol1 coor 2) poin mini ;
  95. ptz0     = sur1 ;
  96. ptz1     = sur2 ;
  97. clx0     = bloq ux ptx0 ;
  98. cly0     = bloq uy pty0 ;
  99. clz0     = bloq uz ptz0 ;
  100. clz1     = bloq uz ptz1 ;
  101. cl0      = clx0 et cly0 et clz0 et clz1 ;
  102.  
  103. * Affichages points CL :
  104. si ig1 ;
  105.   trac ((ptx0 coul roug) et (aret vol1)) titr 'Points Ux = 0' ;
  106.   trac ((pty0 coul roug) et (aret vol1)) titr 'Points Uy = 0' ;
  107.   trac ((ptz0 coul roug) et (ptz1 coul rouge) et (aret vol1)) titr 'Points Uz = 0 (surfaces bloquees par matrice)' ;
  108. fins ;
  109.  
  110. *----------------------------- CHARGEMENT -----------------------------*
  111.  
  112. * Deplacement impose essai channel die :
  113. Uy1      = -0.1 ;
  114. pty1     = (vol1 coor 2) poin maxi ;
  115. cly1     = bloq uy pty1 ;
  116. dcl1     = depi cly1 Uy1 ;
  117.  
  118. * Deplacement impose non homogene :
  119. ptx1     = (vol1 coor 1) poin maxi ;
  120. clx1     = bloq ux ptx1 ;
  121. chy1     = ptz1 coor 2 ;
  122. Uz1      = (((-0.01 * (chy1 - 100.)) ** 2) / -100.) nomc uz ;
  123. dcl2     = depi clz1 Uz1 ;
  124.  
  125. si ig1 ;
  126.   trac ((pty1 coul vert) et (aret vol1)) titr 'Points deplacement Uy impose essai channel die' ;
  127.   trac Uz1 ptz1 titr '2nd chargement : deplacement non homogene' ;
  128. fins ;
  129.  
  130. *---------------------------- DEPLACEMENTS ----------------------------*
  131.  
  132. * Solution analytique au point P3:
  133. UxAna1   = -1. * nu1 / (1. - nu1) * Uy1 ;
  134.  
  135. * Solution Castem au point P3: uycas.
  136. deptot   = reso (rig1 et cl0 et cly1) dcl1 ;
  137. dep2     = reso (rig1 et cl0 et cly1 et clx1) dcl2 ;
  138.  
  139. * deplacement Ux au point P3 :
  140. UxSim1   = extr deptot 'UX' p3 ;
  141.  
  142. * Deformee :
  143. def0     = defo deptot (aret vol1) 0. blan ; 
  144. def1     = defo deptot (     vol1) 100 roug ; 
  145. mot1     = chai format '(F7.4)' 'deformee (vue de dessus) : Ux =' UxSim1 ;
  146.  
  147. si ig1 ;
  148.   trac cach (def0 et def1) titr 'deformee (rouge)' ;
  149.   trac (0 0 1.e6) (def0 et def1) titr mot1 ;
  150. fins ;
  151.  
  152. opti oeil (1.e6 -1.e6 0.8e6) ;
  153.  
  154. * Calcul de l'erreur sur le déplacement.
  155. err1     = abs (( UxAna1 - UxSim1 ) / ( UxAna1 )) ;
  156.  
  157. *---------------------------- CONTRAINTES -----------------------------*
  158.  
  159. * Solution analytique: 
  160. syyana1  = ym1 / (1. - (nu1 * nu1)) * uy1 / 100. ;
  161. szzana1  = nu1 * syyana1 ;
  162. prana1   = syyana1 + szzana1 / 3. ;
  163.  
  164. * Solution Castem : pression maximale = maxpres1.
  165. sig1     = sigma mod1 deptot mat1 ;
  166.  
  167. * Validation KSIG avec BBAR :
  168. ksg1     = ksigm mod1 sig1 ;
  169. depto2   = reso (rig1 et ksg1 et cl0 et cly1) dcl1 ;
  170. err6     = maxi abs (deptot - depto2) avec (mots ux uy uz) ;
  171.  
  172. * Affichage :
  173. si ig1 ;
  174.   trac sig1 mod1 titr 'Champ de contrainte' ;
  175. fins ;
  176.  
  177. * Calcul de la pression :
  178. syySim1  = exco 'SMYY' sig1 'P' ;
  179. szzSim1  = exco 'SMZZ' sig1 'P' ;
  180. prSim1   = (syySim1 + szzSim1) / 3. ;
  181. syySim1  = mini syySim1 ;
  182. szzSim1  = mini szzSim1 ;
  183. prSim1   = mini prSim1 ;
  184.  
  185. * Calcul de l'erreur sur les contraintes :
  186. err2     = ((syyana1 - syySim1) / syyana1) + ((szzana1 - szzSim1) / szzana1) + ((prana1 - prSim1) / prana1) ;
  187. err2     = abs err2 / 3. ;
  188.  
  189. * Verification de l'equilibre chargement homogene :
  190. bsg1     = bsig mod1 sig1 ;
  191. rea1     = reac (rig1 et cl0 et cly1) deptot ;
  192. res1     = bsg1 - rea1 ;
  193. err3     = (maxi abs res1) / (maxi abs rea1) ;
  194.  
  195. * Verification equilibre chargement non homogene :
  196. sig2     = sigm mod1 mat1 dep2 ;
  197. bsg2     = bsig mod1 sig2 ;
  198. rea2     = reac (cl0 et cly1 et clx1) dep2 ;
  199. res2     = rea2 - bsg2 ;
  200. err5     = (maxi abs res2) / (maxi abs rea2) ;
  201.  
  202. * Affichages solution chargement non homogene :
  203. si ig1 ;
  204.   trac (defo vol1 dep2 2.e3) cach titr ' Deformee chargement non homogene' ;
  205.   trac sig2 mod1 titr ' Contraintes chargement non homogene' ;
  206. fins ;
  207.  
  208. *----------------------------- VALIDATION -----------------------------*
  209.  
  210. * Affichages :
  211. opti echo 0 ; saut 1 lign ;
  212. mess (chai format '(F6.2)' ' > Erreur relative deplacement au point P3 =' err1) ;
  213. mess (chai format '(F6.2)' ' > Erreur relative contraintes et pression =' err2) ;
  214. opti echo 1 ; saut 1 lign ;
  215.  
  216. * Test de validation:
  217. err0     = maxi abs (prog err1 err3 err5 err5 err6) ;
  218. prec0    = 1.e-4 ;
  219. list err0 ;
  220. list err1 ;
  221. *list err2 ;
  222. list err3 ;
  223. list err5 ;
  224. list err6 ;
  225. list prec0 ;
  226.  
  227. si ( err0 >eg prec0 ) ;
  228.   erreur 5 ;
  229. finsi ;
  230.  
  231. fin;
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales