Télécharger la plaquette Cast3M


fr en

Télécharger bruipois.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : bruipois.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *---------------------------------------------------------------------*
  5. *            Cas test de l'operateur 'BRUI', option 'POIS'            *
  6. *                                                                     *
  7. *    Ce cas-test verifie la valeur moyenne de variables distribuees   *
  8. * suivant une disribution de Poisson que fournit l'operateur 'BRUI'   *
  9. * avec l'option 'POIS'. Pour tester differentes valeurs moyennes      *
  10. * ainsi que le tirage d'un nombre plus ou moins important de valeurs, *
  11. * ce cas-test realise 4 fois 2 tirages de valeurs moyennes inferieures*
  12. * ou superieures a la valeur 50, l'operateur s'appuyant sur des algo- *
  13. * -rithmes differents dans chaque cas.                                *
  14. *                                                                     *
  15. *---------------------------------------------------------------------*
  16. *                                                                     *
  17. * Mettre IMES1 a VRAI pour avoir les messages :
  18. IMES1    = FAUX ;
  19. *                                                                     *
  20. 'OPTI' 'ECHO' 0 ;
  21. *                                                                     *
  22. * Valeur moyenne de la distrib. de Poisson (THETA1 / THETA2) :
  23. THETA1   = 7 ;
  24. THETA2   = 72 ;
  25. *                                                                     *
  26. * Nombre de valeurs à tirer : NBVAL1 :
  27. NBVAL1   = 100 ;
  28. NBVAL2   = 250 ;
  29. *                                                                     *
  30. *---------------------------------------------------------------------*
  31. *                                                                     *
  32. *                            Debut du test                            *
  33. *                                                                     *
  34. *---------------------------------------------------------------------*
  35. *                                                                     *
  36. * Je fais 4 iterations pour tester differentes moyennes et longueur   *
  37. * de distributions :                                                  *
  38. 'REPE' B0 4 ;
  39. *                                                                     *
  40. *--------------- Test pour une valeur moyenne inf. a 50 --------------*
  41. *                                                                     *
  42. * Tirage :                                                            *
  43.   LVDP1    = 'BRUI' 'BLAN' 'POIS' THETA1 NBVAL1 ;
  44. *                                                                     *
  45. * Verification de la val. moyenne de la distrib. :                    *
  46.   NB1      = 'DIME' LVDP1 ;
  47.   MOY1     = 0 ;
  48.   'REPE' B1 NB1 ;
  49.     MOY1     = MOY1 + ('EXTR' LVDP1 &B1) ;
  50.   'FIN' B1 ;
  51.   MOY1     = ('FLOT' MOY1) / ('FLOT' NB1) ;
  52.   ECA1     = 'ENTI' (('FLOT' THETA1) - MOY1) ;
  53.   'SI' IMES1 ;
  54.     'SAUT' 1 'LIGN' ;
  55.     'MESS' '*** TEST POUR UNE MOYENNE < 50 :' ;
  56.     'MESS' '    ----------------------------' ;
  57.     'MESS' '    Valeur moyenne du tirage / valeur demandee :'  MOY1 '/'
  58.       THETA1 ;
  59.     'MESS' '    Partie entiere de l"ecart a la moyenne i...:' ECA1 ;
  60.     'MESS' '    Nombre de valeurs tirees...................:' NBVAL1 ;
  61.   'FINS' ;
  62. *                                                                     *
  63.   'SI' (ECA1 'NEG' 0) ;
  64.     'ERRE' 5 ;
  65.   'FINS' ;
  66. *                                                                     *
  67. *--------------- Test pour une valeur moyenne sup. a 50 --------------*
  68. *                                                                     *
  69. * Tirage :                                                            *
  70.   LVDP2    = 'BRUI' 'BLAN' 'POIS' THETA2 NBVAL2 ;
  71. *                                                                     *
  72. * Verification de la val. moyenne de la distrib. :                    *
  73.   NB2      = 'DIME' LVDP2 ;
  74.   MOY2     = 0 ;
  75.   'REPE' B2 NB2 ;
  76.     MOY2     = MOY2 + ('EXTR' LVDP2 &B2) ;
  77.   'FIN' B2 ;
  78.   MOY2     = ('FLOT' MOY2) / ('FLOT' NB2) ;
  79.   ECA2     = 'ENTI' (('FLOT' THETA2) - MOY2) ;
  80.   'SI' IMES1 ;
  81.     'SAUT' 1 'LIGN' ;
  82.     'MESS' '*** TEST POUR UNE MOYENNE > 50 :' ;
  83.     'MESS' '    ----------------------------' ;
  84.     'MESS' '    Valeur moyenne du tirage / valeur demandee :'  MOY2 '/'
  85.       THETA2 ;
  86.     'MESS' '    Partie entiere de l"ecart a la moyenne.... :' ECA2 ;
  87.     'MESS' '    Nombre de valeurs tirees...................:' NBVAL2 ;
  88.   'FINS' ;
  89. *                                                                     *
  90.     'SI' (ECA2 'NEG' 0) ;
  91.       'ERRE' 5 ;
  92.     'FINS' ;
  93. *                                                                     *
  94. *--------- Je modifie les moyennes et le nombre de valeurs -----------*
  95. *                                                                     *
  96.   THETA1   = THETA1 + (('EXTR' LVDP1 2) / &B0) ;
  97.   THETA2   = THETA2 + ('EXTR' LVDP2 1) ;
  98.   NBVAL1   = NBVAL1 * 10 ;
  99.   NBVAL2   = NBVAL2 * 10 ;
  100. *                                                                     *
  101. 'FIN' B0 ;
  102. *                                                                     *
  103. *---------------------------------------------------------------------*
  104. *                                                                     *
  105. *                             Fin du test                             *
  106. *                                                                     *
  107. *---------------------------------------------------------------------*
  108. *                                                                     *
  109. * Message de sortie si test reussi :                                  *
  110. *                                                                     *
  111. 'SI' IMES1 ;
  112.   'SAUT' 1 'LIGN' ;
  113.   'MESS'
  114. '***                       TEST REUSSI !                        *** ' ;
  115. 'FINS' ;
  116. *                                                                     *
  117. 'FIN' ;
  118.  
  119.  
  120.  
  121.  
  122.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales