Télécharger la plaquette Cast3M


fr en

Télécharger bobiproc.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  bobiproc.dgibi
  2. DEBPROC INDUCTAN BOBINE*'MAILLAGE' TBIOT*'TABLE';
  3. *********************************************************
  4. * CALCUL DE LA MUTUELLE INDUCTANCE ENTRE UN INDUCTEUR
  5. * DECRIT ANALYTIQUEMENT PAR LA TABLE TBIOT ET UN 
  6. * INDUIT DE TYPE MAILLAGE. 
  7. *    TBIOT.'SOUSTYPE' = INDUCTEUR
  8. *    TBIOT.1 = TABLE DECRIVANT L'INDUCTEUR 1
  9. *     ...
  10. *    TBIOT.N = TABLE DECRIVANT L'INDUCTEUR N
  11. *    POUR L'INDUCTEUR 1 PAR EXEMPLE :
  12. *    TBIOT.1.'SOUSTYPE' = INDUCTEUR1
  13. *    TBIOT.1.'GEOTYPE' = 'BARR' OU 'ARC' OU 'CIRC'  
  14. *    CAS 'ARC' OU 'CIRC':
  15. *      TBIOT.1.'POINT1' = CENTRE DE LA SPIRE
  16. *      TBIOT.1.'POINT2' = PREMIER POINT DEFINISSANT LA SPIRE
  17. *      TBIOT.1.'POINT3' = DEUXIEME POINT DEFINISSANT LA SPIRE
  18. *      TBIOT.1.'FLOT1' = RAYON INTERIEUR DE LA BOBINE
  19. *      TBIOT.1.'FLOT2' = RAYON EXTERIEUR DE LA BOBINE
  20. *      TBIOT.1.'FLOT3' = HAUTEUR DE LA BOBINE
  21. *    CAS 'BARR':
  22. *      TBIOT.1.'POINT1' = EXTREMITE 1 DE LA BARRE
  23. *      TBIOT.1.'POINT2' = EXTREMITE 2 DE LA BARRE
  24. *      POINT1 ET POINT2 DEFINISSENT L'AXE X LOCAL
  25. *      TBIOT.1.'POINT3' = POINT DEFINISSANT L'AXE Y LOCAL
  26. *      TBIOT.1.'FLOT1' = DY DE LA BOBINE
  27. *      TBIOT.1.'FLOT2' = DZ DE LA BOBINE
  28. *    TBIOT.1.'SECTION' = 'RECTANGLE' OU 'TRAPEZE'
  29. *    DANS LE CAS 'TRAPEZE', ON A DE PLUS :
  30. *    TBIOT.1.'PENTEBASSE' = PENTE BASSE
  31. *    TBIOT.1.'PENTEHAUTE' = PENTEHAUTE
  32. * 
  33. *    SYNTAXE : MUTU = INDUCTAN BOBINE TBIOT;
  34. *
  35. ********************************************************
  36. *
  37. * MAILLAGE DE POINTS CONSTITUE DES
  38. * BARYCENTRES DES ELEMENTS DE 'BOBINE'
  39. * 
  40.   NE = NBEL BOBINE;
  41.   IEL = 1;
  42.   GEO1 = BOBINE ELEM IEL;
  43.   P0 = BARY GEO1;
  44.   GEO2 = P0 ET P0;
  45.   GEO2 = GEO2 ELEM POI1 1;
  46.   NEM1=NE-1;
  47.   REPETER BOUC NEM1;
  48.     IEL = IEL + 1;
  49.     GEO1 = BOBINE ELEM IEL;
  50.     PC = BARY GEO1;
  51.     GEO3 = PC ET PC;
  52.     GEO3 = GEO3 ELEM POI1 1;
  53.     GEO2 = GEO2 ET GEO3;
  54.   FIN BOUC;
  55.   ELIM 0.01 GEO2;
  56. *
  57. * CALCUL DU POTENTIEL VECTEUR DU A CHAQUE
  58. * INDUCTEUR ET DU POTENTIEL VECTEUR TOTAL
  59. *
  60.   PI = 3.14159265;
  61.   MU0 = 4.*PI*1.E-7;
  62. *
  63. * INITIALISATION DU POTENTIEL VECTEUR TOTAL
  64.   ATOT = MANU 'CHPO' GEO2 3 AX 0. AY 0. AZ 0.;  
  65. *
  66. * BOUCLE SUR LES INDUCTEURS
  67.   IND = 0;
  68.   NIND = DIME TBIOT;
  69.   NIND = NIND-1;
  70.   REPETER BOUC NIND;
  71.     IND = IND+1;
  72.     TYPI = TBIOT.IND.'GEOTYPE'; 
  73.     Q1 = TBIOT.IND.'POINT1';
  74.     Q2 = TBIOT.IND.'POINT2';
  75.     Q3 = TBIOT.IND.'POINT3';
  76. *
  77. *   CAS DES CERCLES ET DES ARCS
  78.     SI ((EGA TYPI 'CIRC') OU (EGA TYPI 'ARC'));
  79.       RI = TBIOT.IND.'FLOT1';
  80.       RE = TBIOT.IND.'FLOT2';
  81.       H  = TBIOT.IND.'FLOT3';
  82.       S = (RE-RI)*H;
  83.       DNS = 1./S;
  84.       SECT = TBIOT.IND.'SECTION';
  85. *
  86. *     SECTION RECTANGULAIRE
  87.       SI (EGA SECT 'RECTANGLE');
  88.         SI (EGA TYPI 'CIRC'); 
  89.           AIND = BIOT 'POTE' GEO2 'CERC' Q1 Q2 Q3
  90.                  RI RE H DNS MU0;
  91.         FINSI;
  92.         SI (EGA TYPI 'ARC');
  93.           AIND = BIOT 'POTE' GEO2 'ARC' Q1 Q2 Q3
  94.                  RI RE H DNS MU0;
  95.         FINSI;  
  96.       FINSI;
  97. *
  98. *     SECTION TRAPEZOIDALE
  99.       SI (EGA SECT 'TRAPEZE');
  100.         PENT1 = TBIOT.IND.'PENTEBASSE';
  101.         PENT2 = TBIOT.IND.'PENTEHAUTE';
  102.         SI (EGA TYPI 'CIRC');
  103.           AIND = BIOT 'POTE' GEO2 'CERC' Q1 Q2 Q3
  104.                  RI RE H 'TRAP' PENT1 PENT2 DNS MU0;
  105.         FINSI;
  106.         SI (EGA TYPI 'ARC');
  107.           AIND = BIOT 'POTE' GEO2 'ARC' Q1 Q2 Q3
  108.                  RI RE H 'TRAP' PENT1 PENT2 DNS MU0;
  109.         FINSI;
  110.       FINSI;
  111. *
  112. *   CAS DES BARRES
  113.     SINON;
  114.       DY = TBIOT.IND.'FLOT1';
  115.       DZ = TBIOT.IND.'FLOT2';
  116.       S = DY*DZ;
  117.       DNS = 1./S;
  118.       SECT = TBIOT.IND.'SECTION';
  119. *
  120. *     SECTION RECTANGULAIRE;
  121.       SI (EGA SECT 'RECTANGLE');
  122.         AIND = BIOT 'POTE' GEO2 'BARR' Q1 Q2 Q3 DY DZ
  123.                DNS MU0;
  124.       FINSI;
  125. *
  126. *     SECTION TRAPEZOIDALE
  127.       SI (EGA SECT 'TRAPEZE');
  128.         PENT1 = TBIOT.IND.'PENTEBASSE';
  129.         PENT2 = TBIOT.IND.'PENTEHAUTE';
  130.         AIND = BIOT 'POTE' GEO2 'BARR' Q1 Q2 Q3
  131.                DY DZ 'TRAP' PENT1 PENT2 DNS MU0;
  132.       FINSI;
  133.     FINSI;
  134.     ATOT = ATOT + AIND; 
  135.   FIN BOUC;
  136. *
  137. * CALCUL DES VOLUMES ELEMENTAIRES
  138. *
  139.   LVOL = PROG 0.;
  140.   IE = 0;
  141.   REPETER BOUC NE;
  142.     IE = IE+1;
  143.     GEO1 = BOBINE ELEM IE; 
  144.     MOD1 = MODE GEO1 MECANIQUE ELASTIQUE;
  145.     MAT1 = MATE MOD1 'RHO' 1. 'YOUN' 1. 'NU' 1.;
  146.     VMAS = MASSE MOD1 MAT1;
  147.     CUNI = MANU 'CHPO' GEO1 1 UZ 1.;
  148.     VOEL = VMAS*CUNI;
  149.     VOLU = @TOTAL VOEL GEO1 FZ;
  150.     LVOL = LVOL ET (PROG VOLU);
  151.   FIN BOUC;
  152.   NEP1=NE+1;
  153.   LENT = LECT 2 PAS 1 NEP1;
  154.   LVOL = EXTR LVOL (LENT);
  155.   CVOL = MANU 'CHPO' GEO2 1 SCAL LVOL;
  156. *
  157. * CALCUL DE LA NORME DU 
  158. * POTENTIEL VECTEUR
  159. *
  160.   LCOM = MOTS AX AY AZ;
  161.   ANOR = PSCA AIND AIND LCOM LCOM;
  162.   ANOR = ANOR**0.5;
  163. *
  164. * PONDERATION PAR LE VOLUME
  165. * ELEMENTAIRE : CALCUL DE LA MUTUELLE
  166. *
  167.   LCOM = MOTS SCAL;
  168.   MUTUELLE=PSCA ANOR CVOL LCOM LCOM;
  169.   MUTUELLE = @TOTAL MUTUELLE GEO2 SCAL;
  170.   MUTUELLE = MUTUELLE/S;
  171. FINPROC MUTUELLE;
  172. ***************************************************
  173. ***************************************************
  174. OPTI DIME 3 ELEM CUB8 MODE TRIDIM COUL ROUG ;
  175. DENS 0.1;
  176. O0 = 0. 0. 0. ;
  177. O1 = 0. 0. 1. ;
  178. O2 = 1. 0. 0. ;
  179. O3 = 0. 1. 0. ;
  180. P1 = 0.9 0. -0.1;
  181. P2 = 1.1 0. -0.1;
  182. P3 = 1.1 0. 0.1;
  183. P4 = 0.9 0. 0.1 ;
  184. N1 = 3;
  185. N2 = 3;
  186. NC = 16;
  187. L1 = P1 D N1 P2 ; 
  188. L2 = P2 D N2 P3 ; 
  189. L3 = P3 D N1 P4 ; 
  190. L4 = P4 D N2 P1 ; 
  191. S1 = L1 L2 L3 L4 DALL PLAN;
  192. BOBINE = VOLU S1 ROTA NC 360 O0 O1;
  193. ELIM 0.01 BOBINE;
  194. OEIL = 1000. 1000. 1000.;
  195. *TRAC OEIL BOBINE CACHE;
  196. *
  197. * L'INDUCTEUR EST UNE BOBINE CIRCULAIRE :
  198. * ON MODELISE UN SEUL INDUCTEUR
  199. *
  200. TBIOT = TABLE 'INDUCTEUR';
  201. TBIOT . 1 = TABLE 'INDUCTEUR1';
  202. TBIOT . 1 . 'GEOTYPE' = 'CIRC';
  203. TBIOT . 1 . 'POINT1' = O0;
  204. TBIOT . 1 . 'POINT2' = O2;
  205. TBIOT . 1 . 'POINT3' = O3;
  206. TBIOT . 1 . 'FLOT1' = 0.9;
  207. TBIOT . 1 . 'FLOT2' = 1.1;
  208. TBIOT . 1 . 'FLOT3' = 0.2;
  209. TBIOT . 1 . 'SECTION' = 'RECTANGLE';
  210. SELF = INDUCTAN BOBINE TBIOT;
  211. LIST SELF;
  212. SOLREF = 3.15e-6;
  213. ERREL = ABS(SOLREF-SELF)/SOLREF;
  214. LIST ERREL;
  215. SI (ERREL > 0.02);
  216.    ERREUR 5;
  217. FINSI;
  218. FIN;
  219.  
  220.  
  221.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales