Télécharger la plaquette Cast3M


fr en

Télécharger cg2.eso

Retour à la liste

Numérotation des lignes : 

cg2

  1. C CG2       SOURCE    GOUNAND   25/07/15    21:15:02     12322          
  2.       SUBROUTINE CG2(KMORS,KISA,B,X,
  3.      $     KPREC,INVDIA,ILUM,ILUI,
  4.      $     LRES,LNMV,
  5.      $     R,P,Q,Z,
  6.      $     ITER,INMV,RESID,BRTOL,ICALRS,IDDOT,IMVEC,IMPR,IRET)
  7.       IMPLICIT INTEGER(I-N)
  8.       IMPLICIT REAL*8 (A-H,O-Z)
  9. C***********************************************************************
  10. C NOM         : CG2
  11. C DESCRIPTION :
  12. C     Résolution d'un système linéaire Ax=b
  13. C     par la méthode du gradient conjugué préconditionné.
  14. C
  15. C LANGAGE     : FORTRAN 77 + chouhia ESOPE (pour les E/S)
  16. C AUTEUR      : Stéphane GOUNAND (CEA/DRN/DMT/SEMT/TTMF)
  17. C               mél : gounand@semt2.smts.cea.fr
  18. C REFERENCE (bibtex-like) :
  19. C  @BOOK{templates,
  20. C        AUTHOR={R.Barrett, M.Berry, T.F.Chan, J.Demmel, J.Donato,
  21. C                J.Dongarra, V.Eijkhout, R.Pozo, C.Romine,
  22. C                H. Van der Vorst},
  23. C        TITLE={Templates for the Solution of Linear Systems :
  24. C               Building Blocks for Iterative Methods},
  25. C        PUBLISHER={SIAM}, YEAR={1994}, ADDRESS={Philadelphia,PA} }
  26. C  -> URL : http://www.netlib.org/templates/Templates.html
  27. C***********************************************************************
  28. C APPELES (BLAS 1) : GCOPY, GAXPY (subroutines)
  29. C                    GNRM2, GDOT  (functions)
  30. C APPELES (Calcul) : GMOMV  : produit Matrice Morse - Vecteur
  31. C                    PSOLVE : Preconditionner solve
  32. C***********************************************************************
  33. C ENTREES            :
  34. C ENTREES/SORTIES    :
  35. C SORTIES            :
  36. C CODE RETOUR (IRET) : 0 si ok
  37. C                     <0 si problème (non utilisé !)
  38. C                     >0 si l'algorithme n'a pas convergé
  39. C***********************************************************************
  40. C VERSION    : v1, 09/02/06
  41. C HISTORIQUE : v1, 09/02/06, création
  42. C HISTORIQUE :
  43. C HISTORIQUE :
  44. C***********************************************************************
  45. C Prière de PRENDRE LE TEMPS de compléter les commentaires
  46. C en cas de modification de ce sous-programme afin de faciliter
  47. C la maintenance !
  48. C***********************************************************************
  49. *
  50. *     .. Includes .. a commenter si mise au point ok
  51.  
  52. -INC PPARAM
  53. -INC CCOPTIO
  54. -INC CCREEL
  55. -INC SMLREEL
  56.       POINTEUR LRES.MLREEL
  57. -INC SMLENTI
  58.       POINTEUR LNMV.MLENTI
  60.       POINTEUR KMORS.PMORS
  61.       POINTEUR KISA.IZA
  62.       POINTEUR INVDIA.IZA
  63.       POINTEUR ILUM.PMORS
  64.       POINTEUR ILUI.IZA
  65.       POINTEUR B.IZA
  66.       POINTEUR X.IZA
  67. *     .. Work Vectors for CG
  68.       POINTEUR R.IZA,P.IZA,Q.IZA,Z.IZA
  69. *     .. Scalar Arguments ..
  70.       INTEGER ITER, KPREC, IMPR, IRET
  71.       REAL*8  RESID
  72. *
  73. *
  74. *     .. Variables locales
  75. *     .. Parameters
  76.       REAL*8     ZERO      , ONE
  77.       PARAMETER (ZERO=0.0D0, ONE=1.0D0)
  78. *     ..
  79.       INTEGER MAXIT
  80.       REAL*8 ALPHA,BETA,RHO,RHO1,TOL,GNRM2,OMEGA
  81.       REAL*8 GDOT,BNRM2
  82. *     ..
  83. *     .. External subroutines and functions..
  84.       EXTERNAL GAXPY,GCOPY,GDOT,GNRM2
  85. *     ..
  86. *     .. Executable Statements ..
  87. *
  88.  
  89.       IRET  = 0
  90.       INMV  = 0
  91.       IWARN = 0
  92.       MWARN = 20
  93.       IGRAN = 0
  94.       MGRAN = 5
  95.       MAXIT = ITER
  96.       TOL   = RESID
  97.       IF(IMPR.GT.5) WRITE(IOIMP,*) 'Entrée dans cg2.eso'
  98. *
  99. *     Set parameter tolerances.
  100. *
  101.       RHOTOL = XPETIT**0.8D0
  102.       OMETOL = RHOTOL
  103. *      RRMAX = 10.D0
  104.       RRMAX = 1.D0/(XZPREC**0.25D0)
  105. *      write(ioimp,*) 'RHOTOL,OMETOL,RRMAX=',RHOTOL,OMETOL,RRMAX
  106. *
  107. *     Calcul du résidu initial
  108. *
  109. C                    r(0)=b
  110.       CALL GCOPY(B,R)
  111.  
  112. C                    r(0)=b-Ax
  113.       CALL GMOMV(IMVEC,'N',-ONE,KMORS,KISA,X,ONE,R)
  114.       INMV=INMV+1
  115. *
  116.       ITER = 0
  117.       BNRM2 = GNRM2(B)
  118.       IF(IMPR.GT.5) THEN
  119.          WRITE(IOIMP,*) '||B||=',BNRM2
  120.       ENDIF
  121.       RNRM2 = GNRM2(R)
  122.       IF (ICALRS.EQ.1) BNRM2=RNRM2
  123.       IF (BNRM2.LT.XPETIT) BNRM2 = ONE
  124.       RESID = RNRM2 / BNRM2
  125.       IF(IMPR.GT.5) THEN
  126.          WRITE(IOIMP,*) 'Initial residual=',RESID
  127.       ENDIF
  128.       RESMAX = RESID * RRMAX
  129.       LRES.PROG(ITER+1)=RESID
  130.       LNMV.LECT(ITER+1)=INMV
  131. *
  132.       IF (RESID.LE.TOL) THEN
  133.          IRET = 0
  134.          GOTO 30
  135.       ENDIF
  136.  
  137. *
  138.  10   CONTINUE
  139. * Gestion du CTRL-C
  140.       if (ierr.NE.0) return
  141. *
  142. *     Perform (Preconditioned) Conjugate Gradient Iteration.
  143. *
  144.       ITER = ITER +1
  145.       IF(IMPR.GT.7) THEN
  146.          WRITE(IOIMP,*) 'ITER=',ITER
  147.       ENDIF
  148. *
  149. *     Preconditioner Solve
  150. C                    Mz(i-1)=r(i-1)
  151.       CALL PSOLVE('N',KPREC,KMORS,KISA,INVDIA,ILUM,ILUI
  152.      $     ,Z,R)
  153. C                   rho(i-1)=r(i-1)'z(i-1)
  154.       RHO = GDOT(R,Z,IDDOT)
  155. *      WRITE(IOIMP,*) '  RHO=',RHO
  156.       IF (ABS(RHO).LT.RHOTOL) THEN
  157.          RHO=SIGN(RHOTOL,RHO)
  158.          IWARN=IWARN+1
  159. *         WRITE(IOIMP,*) '  RHOCORR,IWARN=',RHO,IWARN
  160.       ENDIF
  161. *
  162. *     Compute direction vector P
  163. *
  164.       IF (ITER.GT.1) THEN
  165. C                   beta(i-1)=rho(i-1)/rho(i-2)
  166.          BETA = RHO / RHO1
  167. C                   p(i)=z(i-1)+beta(i-1)p(i-1)
  168.          CALL GAXPY(BETA,P,Z)
  169.          CALL GCOPY(Z,P)
  170.       ELSE
  171. C                   p(1)=z(0)
  172.          CALL GCOPY(Z,P)
  173.       ENDIF
  174. *
  175. *     Compute scalar ALPHA (save A*p to q)
  176. *
  177. C                   q(i)=Ap(i)
  178.       CALL GMOMV(IMVEC,'N',ONE,KMORS,KISA,P,ZERO,Q)
  179.       INMV=INMV+1
  180. C                   alpha(i)=rho(i-1)/(p(i)'q(i))
  181.       OMEGA = GDOT(P,Q,IDDOT)
  182. *      WRITE(IOIMP,*) '  OMEGA=',OMEGA
  183.       IF (ABS(OMEGA).LT.OMETOL) THEN
  184.          OMEGA=SIGN(OMETOL,OMEGA)
  185.          IWARN=IWARN+1
  186. *         WRITE(IOIMP,*) '  OMEGACORR,IWARN=',OMEGA,IWARN
  187.       ENDIF
  188.       ALPHA = RHO / OMEGA
  189. *
  190. *     Compute current solution vector x
  191. *
  192. C                   x(i)=x(i-1)+alpha(i)p(i)
  193.       CALL GAXPY(ALPHA,P,X)
  194. *
  195. *     Compute residual vector R, find norm,
  196. *     then check for tolerance
  197. *
  198. C                   r(i)=r(i-1)-alpha(i)r(i)
  199.       CALL GAXPY(-ALPHA,Q,R)
  200. *
  201.       RESID = GNRM2(R) / BNRM2
  202.       IF(IMPR.GT.7) THEN
  203.          WRITE(IOIMP,*) 'Résidu=',RESID
  204.       ENDIF
  205.       LRES.PROG(ITER+1)=RESID
  206.       LNMV.LECT(ITER+1)=INMV
  207.       IF (RESID.GT.RESMAX) THEN
  208.          IGRAN=IGRAN+1
  209. *         WRITE(IOIMP,*) 'Résidu grand,IGRAN=',RESID,IGRAN
  210.       ELSE
  211.          IGRAN=0
  212.       ENDIF
  213. *
  214. *     Iteration successful
  215. *
  216.       IF (RESID.LE.TOL) THEN
  217.          IRET = 0
  218. *
  219. *     Iteration fails
  220. *
  221. *      ELSE IF (ITER.EQ.MAXIT.OR.IGRAN.GT.MGRAN) THEN
  222.       ELSE IF (INMV.GE.MAXIT.OR.IGRAN.GT.MGRAN.OR.IWARN.GT.MWARN) THEN
  223.          IRET = 1
  224. *
  225. *     Do some more
  226. *
  227.       ELSE
  228.          RHO1 = RHO
  229.          GOTO 10
  230.       ENDIF
  231. *
  232. *     Normal termination
  233. *
  234.  30   CONTINUE
  235.       IF (IWARN.GT.0.AND.IMPR.GT.0) THEN
  236.          WRITE(IOIMP,*) 'CG nearly failed ',IWARN
  237.      $        ,' times.'
  238.       ENDIF
  239.       RETURN
  240. *
  241. *     End of CG2
  242. *
  243.       END
  244.  
  245.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales