Test joi22 Description sheet

Test name

Calculation type

Finite element type

Topic

The structure is a 2D-joint subjected to a tensile strength on its upper surface, in the direction perpendicular to its plan. It is embedded from its lower surface.

Goal

Version

Model description

Test joi22 Results

RESULTS

*           Test Joi22.dgibi: Jeux de données         *
*           ---------------------------------         *
*                                                     *
OPTI ECHO 0 ;
SAUT PAGE ;
MESS'!==============================================!';
MESS'!                                              !';
MESS'!                    TEST JOI22                !'; 
MESS'!                                              !'; 
MESS'!       ESSAI DE TRACTION SUR UN JOINT 2D      !';  
MESS'!                                              !'; 
MESS'!  Un joint 2D JOI2 a son bord inferieur       !';
MESS'!  encastre.                                   !'; 
MESS'!  Son bord superieur est libre. Un effort de  !';  
MESS'!  traction est exercé sur son bord superieur. !'; 
MESS'!                                              !'; 
MESS'!                                              !';
MESS'!  Solution analytique :                       !'; 
MESS'!                                              !';
MESS'!     En ecrivant le principe des travaux      !'; 
MESS'!  virtuels,on montre que le deplacement delta !'; 
MESS'!  en chaque noeud est egal, dans le cas d un  !'; 
MESS'!  essai de traction uniaxial, a :             !';
MESS'!                       F                      !'; 
MESS'!        delta = ----------------              !'; 
MESS'!                   k * L * l                  !';  
MESS'!  ou                                          !'; 
MESS'!    F = force totale exercee sur la structure !'; 
MESS'!    k = raideur                               !'; 
MESS'!    L = longueur de l element joint           !'; 
MESS'!    l = largeur de l element joint            !'; 
MESS'!                                              !';   
MESS'!  Application numerique :                     !'; 
MESS'!                                              !'; 
MESS'!    F = 100000.0                              !';
MESS'!    k = 4.2E10                                !';
MESS'!    L = 2.0                                   !'; 
MESS'!    l = 1.0                                   !'; 
MESS'!                                              !';
MESS'!    Delta   =  100000 / (4.2E10 * 2.0 * 1.0)  !';
MESS'!            =  1.19047619E-6                  !';
MESS'!                                              !';
MESS'!==============================================!';
OPTION DIME 2 ;
OPTION ELEM SEG2 MODE PLAN CONT  ;
*
SOLANA = 1.190476E-6 ;
SOLNUL = 0.0 ;
*
* ------- DEFINITION DE LA SURFACE TOP DU JOINT -------
*
A1 = 0.00 0.00 ;
B1 = 2.00 0.00 ;
*
* ----------          MAILLAGE          ----------
*
H1 = A1 DROIT 1 B1 ;
*
L1 = H1 ;
*
* ------ DEFINITION DE LA SURFACE BOT DU JOINT --------
*
IA1 = 0.00 0.00 ;
IB1 = 2.00 0.00 ;
*
* ----------          MAILLAGE          ----------
*
IH1 = IA1 DROIT 1 IB1 ;
*
IL1 = IH1 ;
*
* ----------   CREATION DU JOINT JOI2   ----------
*
OPTION ELEM RAC2 ;
VOL = RACCORD 0.00001 L1 IL1 ;
*
* --------- DEFINITION DES CONDITIONS LIMITES ---------
*
CL11 = BLOQ IA1 UX ;
CL12 = BLOQ IA1 UY ;
CL1 = CL11 ET CL12 ;
*
CL21 = BLOQ IB1 UX ;
CL22 = BLOQ IB1 UY ;
CL2 = CL21 ET CL22 ;
*
CL = CL1 ET CL2 ;
*
* -----    DEFINITION DU MODELE DU JOINT      ---------
*
MOD1 =MODL VOL 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' JOI2;
MA1 = MATR MOD1 KS 4.2E08 KN 4.2E10 ;
*
* -------------    MATRICE DE HOOK         ------------
*
HOO1 = HOOKE MOD1 MA1 ;
******LIST HOO1 ;
*
* ----------       MATRICE DE RIGIDITE        ---------
*
******RI1 = RIGI MOD1 MA1 ;
RI1 = RIGI MOD1 HOO1 ;
RI2 = RI1 ET CL ;
*
* ----------        FORCE DE TRACTION         ---------
*
FO1 = FORCE ( 0. 100000.0 ) L1 ;
*
* ---------            RESOLUTION            ----------
*
RE = RESO RI2 FO1 ;
MESS '                                              ' ;
MESS '                                              ' ;
MESS ' Solution Analytique :'                         ;
MESS '                                              ' ;
MESS '    UX =' SOLNUL  ;
MESS '    UY =' SOLANA  ;
MESS '                                              ' ;
MESS '                                              ' ;
MESS '                                              ' ; 
MESS ' Solution Calculee :'                           ;
MESS '                                              ' ;
LIST RE ;
*
* ----------    CODE DE FONCTIONNEMENT       ----------
*
DEPA1 = EXTR RE UY A1 ;
RESI = ABS( (DEPA1-SOLANA)/SOLANA ) ;
*
SI (RESI <EG 1E-4 ) ;
   ERRE  0 ;
SINO;
   ERRE  5 ;
FINSI ;
*
* ----------     CALCUL DES DEFORMATIONS     ---------- 
*
EPS1 = EPSI MOD1 RE ;
LIST EPS1 ;
*
* ----------    CALCUL DES CONTRAINTES       ---------- 
*
SIG1 = SIGMA MOD1 MA1 RE ;
LIST SIG1 ;
*
FIN ;

Test joi22 Comments

1. JOINT operator

   MOD1 = MODE VOL MECANIQUE ELASTIQUE ISOTROPE JOI2 ;
   MA1 = MATE MOD1 KS 4.2E08 KN 4.2E10 ;
   

   The JOI2 element is used in the modelling of a 2D-joint. This joint is an element with four nodes associated with the geometrical support RAC2. Within the MATE operator we should specify the shear and the normal stiffnesses, respectively KS and KN.

2. RACCORD operator

   OPTI ELEM RAC2 ;
   VOL = RACCORD 0.00001 L1 IL1 ;
   

   The RACCORD operator enables the user to create an ordinary joint element. It generates a line VOL (MAILLAGE type) composed of double points that connects the objects L1 and IL1 (MAILLAGE type). The objects L1 and IL1 may be segments of 2 or 3 points. An element is created between an element of the L1 object and an element of the IL1 object; the distance between their points is smaller than a distance criterion (FLOTTANT type: 0.00001).
   For the creation of a 2D joint element JOI2 (or JOI3) L1 and IL1 represent respectivelly lines 1 and 2 of the element.These lines should be read in the same direction. This direction is that of line 1. It is defined by considering a vector n normal to this line. When it is orientated positivelly in the direction of the opening of the joint element, n must necessarilly lie on the right handside of the segment going from node 1 to node 2 of line 1. (We define the opening of the element as the separation movement of line 1 from line 2 when line 2 is held fixed).
   

3. HOOKE operator

   HOO1 = HOOKE MOD1 MA1 ;
   

   The HOOKE operator constructs the field of HOOKE's matrix from a field of geometrical and material properties MA1 (MCHAML type, CARACTERISTIQUES subtype). Here HOO1 is a field by element of Hooke's matrices (MCHAML type, MATRICE DE HOOKE subtype).
   MA1 is required only for the types of elements the geometry of wich cannot be deduced from the mesh, for instance, beam, pipe, or shell elements.
   

4. EPSI and SIGMA operators

   EPS1 = EPSI MOD1 RE ;           SIG1 = SIGMA MOD1 MA1 RE ;
   

   The EPSI operator enables to calculate a strain field either from a displacement field, according to usual expressions with or without second order terms (1-st syntax), or by taking the natural logarithm of a symmetric gradient field ( 2-nd syntax). This second possibility is now available only for the massive formulation.
   For some elements, (beams, pipes, thin shells, with or without transverse shear) it describes generalized strains, i.e. membrane-type strains and curvature variations. For the joint elements, it describes relative displacements. The strains for the solid elements are computed in the general basis, those for the shell, plate, and beam elements are computed in the local axes.
   Here MOD1 is a model object (MMODEL type), GRAD1 is a symmetrical gradient field (MCHAML type, GRADIENT subtype) and EPS1 is the generated displacement field (MCHAML type, DEFORMATIONS subtype).
   
   The SIGMA operator calculates a stress field from a displacement field. It is assumed that the material has an elastic linear behaviour and that there is no initial strain. For some elements, it describes forces, (bars, beams, pipes), for others, it describes generalized stresses (thin shells). The stresses are calculated in the general basis for the solid elements, and in the local axes for the shell, plate and beam elements. Here SIG1 is the generated stress field (MCHAML type, CONTRAINTES subtype).