Test name
precont3
Calculation type
REINFORCED ELASTIC MECHANICS - BARR - 2D
Finite element type
QUA4
Topic
Calculation with active reinforcement and different
loss of prestress
The structure is a reinforced concrete beam. The
reinforcement is made of tendon. The beam is
subjected to pressure on its upper surface, and
embedded from its lower side.
Goal
Test the PREC operators with passive reinforcement.
Reference
J.S. Fleuret 07/96
Version
97' customer version
Model description
Test precont3 Results
CASTEM FIGURES
* Test Precont3.dgibi: Jeux de données *
* ------------------------------------ *
* *
*---------------------------------------------------*
* CALCUL AVEC DIFFERENTES PERTES DE PRECONTRAINTE
* PROGRAMME DE VERIFICATION DE :
* - PREC
*---------------------------------------------------*
* J.S. Fleuret 07/96 modifie JMB 11/97
*---------------------------------------------------*
titr 'precont3.dgibi';
opti echo 1;
graph='N';
tabu= table ;
tabu.1 = 'MARQ CROI TITR Sans_pertes' ;
*tabu.2 = 'MARQ TRIA TITR Sans_pertes_+pre_init' ;
tabu.2 = 'MARQ CARR TITR Pertes_frott' ;
tabu.3 = 'MARQ LOSA TITR Pertes_frott_glis' ;
tabu.4 = 'MARQ ETOI TITR Pertes_frott_glis_rel' ;
opti dime 2 elem qua4 mode plan;
*
* GEOMETRIE
*
long = 10.0;
*---BETON
h = 1. ;h1 = .5 ;
pa=0.0 0.0;
pb=long 0.0;
pc=long h;
pd=0.0 h;
nb1=40;
nb2=4;
c1=pa droi nb1 pb;
c2=pb droi nb2 pc;
c3=pc droi nb1 pd;
c4=pd droi nb2 pa;
sur1=dall c1 c2 c3 c4;
*---ARMATURE
pm=long ( h - h1) ;
pn= 0.0 ( h - h1) ;
nca =15 ;d1 = pm droi nca pn;
d2 = pm droi nca pn;
*---GEOMETRIE TOTALE
si(neg graph 'N');
titr 'Maillage de la poutre';
trac elem (sur1 et d1);
finsi;
*
* MODELE
*
modb=modl sur1 mecanique elastique;
d2 = (kabl sur1 d1 ) coul roug ;
mod2 =modl d2 mecanique elastique armature barr;
si(neg graph 'N');
titr 'Maillage armature apres KABL' ( d2 nbel);
trac elem d2;
finsi;
pmil= (d2 point proche (5. 0.)) ;
x = NORM ( PM moins pmil) ;
*
* CARACTERISTIQUES DU BETON
*
mat1=matr modb youn 0.4e11 nu 0.0;
*
* CONDITIONS AUX LIMITES
*
cl1 = bloq pa ux;
cl2 = bloq pa uy;
cl3 = bloq pb uy;
cl4 = rela ense ux c2;
cl5 = rela ense ux c4;
cltot = cl1 et cl2 et cl3 et cl4 et cl5;
* Contrainte de depart du cable ( pas tension )
ssect = .02 ;Ea = 2.1e11 ;
sig0 = 1200.E6 ;tens = sig0 * ssect ;
si ( neg graph 'N' ) ;
MESS 'POUTRE BETON LONGUEUR 10M HAUTEUR 1M ' ;
MESS 'ARMATURE SECTION ' SSECT;
MESS 'TENSION SOUS VERIN COTE GAUCHE ' TENS ;
sauter 3 lignes ;
mess '********************************************** ';
mess 'PRECONTRAINTE SANS PERTE ' ;
mess '********************************************** ';
finsi ;
*mat2=(mate mod2 youn Ea ff 0.0 phif 0.0
* ganc 0.0 rmu0 0.43 fprg 1700.e9 rh10 2.5)
* et ( cara mod2 sect ssect ) ;
mat2=(mate mod2 youn 2.0e11 ) et
( cara mod2 sect .02 ) ;
tabi = table ;
tabi.'FF' = 0.0 ;
tabi.'PHIF' = 0.0 ;
tabi.'GANC' = 0.0 ;
tabi.'RMU0' = 0.0 ;
tabi.'FPRG'= 0.0 ;
tabi.'RH10'= 0.0 ;
pre1=prec mod2 mat2 tabi tens ;
cpre1 = chan chpo pre1 mod2 ;
prec100 = extr cpre1 effx PN;
prec050 = extr cpre1 effx pmil;
si ( neg graph 'N') ;
titre ' precontrainte sans perte 1 ' ;
ev1 = evol roug chpo cpre1 EFFX d2 ;
dess ev1 xbor 0. 10. ;
finsi ;
err0 = ( (abs(prec100-tens)*100/tens)
+ (abs(prec050-tens)*100/tens) )/2;
mess err0 '%';
*---Code de bon fonctionnement
si ( err0 < 0.005 ) ;
erre 0 ;
sinon ;
erre 5 ;
finsi ;
*
si ( neg graph 'N' ) ;
mess '********************************************** ';
mess ' PRECONTRAINTE avec PERTE PAR FROTTEMENT ' ;
mess '********************************************** ';
finsi ;
*
af = 0.18 ;
aphif = 0.02 ;
ag = 0. ;
amu = 0. ;
afr = 0. ;
arh = 0.;
t10 = tens * (exp ( aphif * 10. * -1.)) ;
t5 = tens * (exp ( aphif * 5. * -1.)) ;
*
*mat2=(mate mod2 youn Ea ff af phif aphif
* ganc ag rmu0 amu fprg afr rh10 arh ) et
* ( cara mod2 sect ssect ) ;
tab1 = table ;
tab1.'FF' = af ;
tab1.'PHIF' = aphif;
tab1.'GANC' = 0.0 ;
tab1.'RMU0' = 0. ;
tab1.'FPRG'=0. ;
tab1.'RH10'= 0. ;
pre1=prec mod2 mat2 tab1 tens ;
cpre1 = chan chpo pre1 mod2 ;
prec101 = extr cpre1 effx PN;
prec051 = extr cpre1 effx pmil;
si ( neg graph 'N' ) ;
mess '10 m ' prec101 'T analytique ' t10
' SIG ' (t10/ssect);
mess ' 5 m ' prec051 'T analytique ' t5
' SIG ' (t5/ssect);
titre ' precontrainte avec frottement ' ;
ev3 = evol vert chpo cpre1 EFFX d2 ;
dess ev3 xbor 0. 10.;
finsi ;
err1 = ( (abs(prec101-t10)*100/t10)
+ (abs(prec051-t5)*100/t5) )/2;
mess err1 '%';
*---Code de bon fonctionnement
si ( err1 < 1. ) ;
erre 0 ;
sinon ;
erre 5 ;
finsi ;
si ( neg graph 'N' ) ;
mess '********************************************** ';
mess ' PRECONTRAINTE avec PERTE PAR FROTTEMENT ' ;
mess ' par GLISSEMENT ' ;
mess '********************************************** ';
finsi ;
*
* CALCUL DE LA PRECONTRAINTE
* AVEC PERTE DUE : AU FROTTEMENT
* AU GLISSEMENT
*
ag = 0.005 ;
tt10 = t10 ;tt5= t5 ;
alamb = (ag * Ea/(sig0 * aphif)) ** .5 ;
si ( 10. < alamb ) ;
dt10 = 2. * tens * aphif * (alamb - 10.) ;
tt10 = tt10 - dt10 ;
finsi ;
si ( 5. < alamb) ;
dt5 = 2. * tens * aphif * (alamb - 5.) ;
tt5 = t5 - dt5 ;
finsi ;
*mat2=(mate mod2 youn Ea ff af phif aphif
* ganc ag rmu0 amu fprg afr rh10 arh ) et
* ( cara mod2 sect ssect ) ;
tab2 = table ;
tab2.'FF' = af ;
tab2.'PHIF' = aphif;
tab2.'GANC' = ag ;
tab2.'RMU0' = amu ;
tab2.'FPRG'= afr ;
tab2.'RH10'= arh ;
pre1= prec mod2 mat2 tab2 tens ;
cpre1 = chan chpo pre1 mod2 ;
prec102 = extr cpre1 effx PN;
prec052 = extr cpre1 effx pmil;
si ( neg graph 'N') ;
mess ' 10 metres lamb ' alamb ' tens ' tt10 ;
mess ' 5 metres lamb ' alamb ' tens ' tt5 ;
mess '10 m ' prec102 'T analytique ' tt10
' SIG ' (tt10/ssect);
mess ' 5 m ' prec052 'T analytique ' tt5
' SIG ' (tt5/ssect);
titre ' precontrainte avec frottement et glissement ' ;
ev4 = evol vert chpo cpre1 EFFX d2 ;
dess ev4 xbor 0. 10.;
finsi ;
err2 = ( (abs(prec102-tt10)*100/tt10)
+ (abs(prec052-tt5)*100/tt5) )/2;
mess err2 '%';
*---Code de bon fonctionnement
si ( err2 < 1. ) ;
erre 0 ;
sinon ;
erre 5 ;
finsi ;
si ( ega ag 0.) ;
tt10= t10 ;
tt5=t5 ;
finsi ;
si ( neg graph 'N' ) ;
mess '********************************************** ';
mess ' PRECONTRAINTE avec PERTE PAR FROTTEMENT ';
mess ' par GLISSEMENT ';
mess ' par RELAXATION ';
mess '********************************************** ';
finsi ;
amu = .43 ;
afr = 1700.e6 ;
arh = 2.5 ;
ttt10 = tt10 ;ttt5=tt5 ;
p10 = 0.06 * (((tt10/(afr*ssect)))-amu) * tt10 * arh ;
p5 = 0.06 * (((tt5/(afr*ssect)-amu))) * tt5 * arh ;
si ( p10 > 0. ) ;
ttt10 = ttt10 - p10 ;
finsi ;
si ( p10 > 0. ) ;
ttt5 = ttt5 - p5 ;
finsi ;
tab3 = table ;
tab3.'FF' = af ;
tab3.'PHIF' = aphif;
tab3.'GANC' = ag ;
tab3.'RMU0' = amu ;
tab3.'FPRG'= afr ;
tab3.'RH10'= arh ;
*mat2=(mate mod2 youn Ea ff af phif aphif
* ganc ag rmu0 amu fprg afr rh10 arh) et
* ( cara mod2 sect ssect ) ;
pre1=prec mod2 mat2 tens tab3;
cpre1 = chan chpo pre1 mod2 ;
prec103 = extr cpre1 effx PN;
prec053 = extr cpre1 effx pmil;
si ( neg graph 'N') ;
mess '10 m ' prec103 'T analytique ' ttt10
' SIG ' (ttt10/ssect) ;
mess ' 5 m ' prec053 'T analytique ' ttt5
' SIG ' (ttt5/ssect);
titre 'precontrainte avec frottement
glissement et relaxation';
ev5 = evol vert chpo ( chan chpo pre1 mod2) EFFX d2 ;
dess ev5 xbor 0. 10. ;
finsi ;
err3 = ( (abs(prec103-ttt10)*100/ttt10)
+ (abs(prec053-ttt5)*100/ttt5) )/2;
mess err3 ' en %';
*---Code de bon fonctionnement
si ( err3 < 4. ) ;
erre 0 ;
sinon ;
erre 5 ;
finsi ;
*
* FIN DU FICHIER
*
si ( neg graph 'N') ;
dess ( ev1 et ev3 et ev4 et ev5) xbor 0. 10.
lege tabu ;
finsi ;
fin ;