Test name
rupt7
Calculation type
MECHANICS ELASTIC
Finite element type
QUA8 DIME 2
Topic
STRESS INTENSITY FACTOR FOR AN OBLIQUE EDGE CRACK IN A PLATE SUBJECTED TO UNIFORM TENSILE STRESS
The structure is a finite plate enclosing an oblique edge crack .
This structure is subject to uniform tensile stress.
The CASTEM solution for the stress intensity factors K is given
with the displacements method in 3 nodes at the crack tip (including the mid-node)
from the local displacements wich are computed
in the local basis (
) for the crack by the relationship :
c and d are the coefficients of the line : 
a and b are the coefficients of the line : 
u : is the displacement following the ox axis.
v : is the displacement following the oy axis .
r : is the distance between the point, where K is computed, and the local origin.
This CASTEM K value for the stress intensity factor is compared to the result obtained with the
analytical method .
Reference CASTEM
Test NAFEMS : D.P.Rooke and D. J. Cartwright in Copendium of Intensity Factors HMSO (1976) :
rupt7 Modélisation des structures élastiques dans CASTEM 2000.
Version
97' customer version
Model description
Test rupt7 Results
RESULTS
CASTEM FIGURES
* Test Rupt7.dgibi: Jeux de données *
* --------------------------------- *
* *
*******************************************************
***** CALCUL DU FACTEUR D'INTENSITE DE *****
***** CONTRAINTES D'UNE PLAQUE AVEC FISSURE *****
***** RECTILIGNE INCLINEE DEBOUCHANTE CHARGEE *****
***** EN TRACTION UNIFORME *****
***** LARGEUR DE LA PLAQUE : 100 mm ; *****
***** LONGUEUR : 250 mm *****
***** LONGUEUR DE FISSURE : 50 mm ; *****
***** ANGLE / OX : 45° *****
***** CONTRAINTE UNIFORME : 10 daN/mm2 *****
*******************************************************
opti dime 2 elem qua8 mode plan defo echo 0;
*--------------DEFINITION DU MAILLAGE-----------------;
p0=0. 0.;p11=100. 0.;p12=p11 plus (0. 0.);p2=250. 0.;
p3=0. 100.;
a=50. * (cos 45);
pf=p11 plus (a a);
p4=(p11 plus (a 0.)) plus (0. 100.);p5=250. 100.;
i=0; pd=prog 1. 2.5 5. 9. 13. 19. 25. ;
cim1=pf;cim2=pf;cim3=pf;cim41=pf;cim42=pf;
plfim1=pf;plfim2=pf;pim2=pf;
repeter bbbb 7;
i= i + 1;v=extr pd i;
pi1=pf moin (v 0.);pi2=pf plus (0. v);
pi3=pf plus (v 0.);pi4=pf moin (0. v);
ci4=cerc 2 pi4 pf pi1;
plfi1=ci4 poin 2;plfi2=plfi1 plus (0. 0.);
n=2;si ((i ega 6 ) ou (i ega 7));n=4;finsi;
m = n / 2;
ci1=cerc n pi1 pf pi2;
ci2=cerc n pi2 pf pi3;
ci3=cerc n pi3 pf pi4;
ci41=cerc m pi4 pf plfi1;
ci42=cerc m plfi2 pf pi1;
sui1=cout cim1 ci1;
sui2=cout cim2 ci2;
sui3=cout cim3 ci3;
sui41=cout cim41 ci41;
sui42=cout cim42 ci42;
elim 0.001 (sui42 et sui1);
elim 0.001 (sui1 et sui2 et sui3 et sui41);
lfi1=(cont sui41) comp plfim1 plfi1;
lfi2=(cont sui42) comp plfim2 plfi2;
lhi=pim2 d 1 pi2;
cim1=ci1;cim2=ci2;cim3=ci3;cim41=ci41;cim42=ci42;
plfim1=plfi1;plfim2=plfi2;pim2=pi2;
sut1=sui42 et sui1;
sut2=sui2 et sui3 et sui41;
si (i ega 1);
sutt1=sut1;sutt2=sut2;lf1=lfi1;lf2=lfi2;lh=lhi;
sinon;
sutt1=sutt1 et sut1;sutt2=sutt2 et sut2;
lf1=lf1 et lfi1;lf2=lf2 et lfi2;lh=lh et lhi;
finsi;
fin bbbb;
lg=p0 d 5 p3;ld=p2 d 5 p5;
lhc= p4 d 2 pi2;
lig1=lg et (p3 d 8 p4) et lhc;
lig1=lig1 et (inve ci1) et ci42;
lig1=lig1 et (plfi2 d 2 p12 d 5 p0);
su1=surf lig1 plan;obj1=su1 et sutt1;elim 0.001 obj1;
lig2=ld et (p5 d 8 p4) et lhc;
lig2=lig2 et ci2 et ci3 et ci41;
lig2=lig2 et (plfi1 d 2 p11 d 8 p2);
su2=surf lig2 plan;obj2=su2 et sutt2;elim 0.001 obj2;
perobj1 = inve ( cont sutt1);
perobj2 = inve ( cont sutt2);
lifis1 = perobj1 comp pf plfi2;
lifis2 = perobj2 comp pf plfi1;
obj=obj1 et obj2;
*-----------DEFINITION DU MATERIAU-------------------;
objaf = modl obj MECANIQUE ELASTIQUE ISOTROPE;
mat=mate objaf youn 20000 nu 0.3;
*-----------MATRICE DE RIGIDITE----------------------;
rig=rigi mat objaf;
*-----------DEFINITION DU CHARGEMENT-----------------;
cdl=(bloq ux uy p0) et (bloq uy p2);
f1=pres mass objaf lg -10.;
f2=pres mass objaf ld -10.;
*-----------RESOLUTION ET CONTRAINTES----------------;
u=reso (rig et cdl) (f1 et f2);
sig=sigm mat objaf u;
*----CALCUL DU FACTEUR D'INTENSITE DE CONTRAINTES----;
*----APPEL DE LA PROCEDURE SIF ---------------------;
SUPTAB = TABLE;
SUPTAB.'MODMIXTE' = VRAI;
SUPTAB.'LIFIS1' = lifis2;
SUPTAB.'LIFIS2' = lifis1;
SUPTAB.'FRTFISS' = pf;
SIF SUPTAB MAT U;
K1MOY = SUPTAB.K1;
K2MOY = SUPTAB.K2;
*-----DEPOUILLEMENT ---------------------------------;
mess '***********************';
mess '* SOLUTION ANALYTIQUE *';
mess '***********************';
mess 'K1th = 150.37 ';
EC1 = (K1MOY - 150.37) / K1MOY * 100;
mess 'ECART entre K1MOY et K1TH : 'EC1'%';
mess 'K2th = -71.4 ';
EC2 = (K2MOY + 71.4) / K2MOY * 100;
mess'ECART entre K2MOY et K2TH : 'EC2'%';
*-----------------------------------------------------;
*------------------MESSAGE D'ERREUR-------------------*
SI ((EC1 < 0.6) ET (EC2 < 0.25));
MESS 'ERR 0';
ERRE 0;
SINON;
MESS 'ERR 5';
ERRE 5;
FINSI;
*-----------------------------------------------------*
fin;