Test flam1 Description sheet

Test name

Calculation type

Finite element type

Topic

Eulerian buckling of a beam clamped at one end.

The beam is clamped at one end. A force, parallel to the beam, is applied to the free end.

Goal

Reference

Version

Model description

Test flam1 Results

Results

CASTEM figures

*           Test Flam1.dgibi: Jeux de données         *
*           ---------------------------------         *
*                                                     *
OPTION ECHO 0;                                                                  
GRAPH='N';                                                                      
SAUT PAGE ;                                                                     
*                                                                               
*******************************************************       
*                                                                               
*  TEST FLAM1                                                                   
*                                                                               
*           FLAMBAGE EULERIEN D'UNE POUTRE 
*             ENCASTREE A UNE EXTREMITE                     
*                                                                               
* Dans cet exemple on se propose d'étudier le flambage              
* d'une poutre encastrée à une de ses extrémités et            
* soumise à une force parallele à la poutre et 
* appliquée à l'extrémité libre de la poutre.                    
*                                                                               
* Le flambage est visualisé en fin de calcul et le             
* multiplicateur de chargement calculé est comparé à 
* celui obtenu par la théorie (41.123).        
*                                                                               
*******************************************************    
TITRE ' FLAMBAGE D UNE POUTRE ENCASTREE ' ;
OPTION DIME 2 ELEM SEG2  MODE PLAN CONT ;


TEMPS ;
*
*------------- DEFINITION DU MAILLAGE -----------------
*
DENSITE  1. ;
P1 = 50. 0. ;
P2 = 50. 10. ;
L1 = P1 D P2 ;
*
SI (NEG GRAPH 'N');
TRAC L1 ;
FINSI;
*
*--------- CREATION DU MODELE ET DE MMODEL ------------
*
MOD1 = MODL L1 MECANIQUE ELASTIQUE COQ2;

*
* -------- DEFINITION DES CARACTERISTIQUES ------------
* ----------- MATERIELLES ET GEOMETRIQUES  ------------
*
MAT1   = MATR MOD1 YOUN   20000.    NU 0.3     ;
CAR1   = CARB MOD1 EPAI 1. ;
MAT1=MAT1 ET CAR1;
*
*--------- CALCUL DES RIGIDITES ELEMENTAIRES ----------
*----------- ET DEFINITIONS DES BLOCAGES --------------
*
RIG1   = RIGI  MOD1 MAT1 ;
BL1    = BLOQUE DEPL ROTA P1 ;
RIG11  = RIG1 ET BL1;
*
*------------- DEFINITION DU CHARGEMENT ---------------
*
FE1 = FORCE ( 0 -1. ) P2 ;
*
*------- RESOLUTION ET CALCUL DES CONTRAINTES ---------
*
DEP1   = RESO  RIG11    FE1 ;
SIG1 = SIGM MOD1 MAT1  DEP1 ;
*
*--- CALCUL DE LA MATRICE DES CONTRAINTES INITIALES ---
*
KSI1   = KSIGMA  MOD1 SIG1 CAR1 'FLAM' ;
*
*----------- INITIALISATION DE LA TABLE ---------------
*--------- EN ENTREE DE LA PROCEDURE FLAMBAGE ---------
*
ETAB   = TABLE    ;
ETAB.'CLIM' = BL1 ;
*ETAB.'RIGI' = RIG1 ;
*ETAB.'KSIG' = KSI1 ;
ETAB.'SIG1'=SIG1;
ETAB.'MATE'=MAT1;
ETAB.'LAM1' = 0.001 ;
ETAB.'LAM2' =  100. ;
ETAB.'NMOD' = 1   ;
ETAB.'OBJM'=MOD1;
*
*--------- APPEL A LA PROCEDURE DE FLAMBAGE -----------
*
SAUT PAGE ;
STAB = FLAMBAGE ETAB ;
*
*------------ RECUPERATION DES RESULTATS --------------
*
LA1  =  STAB . 1 . LAMB ;
SAUT PAGE ;
*
*------------ DESSIN DU MODE DE FLAMBAGE --------------
*
MM1 = STAB . 1 . DEPL ;
DE  = DEFO MM1 L1 1. ROUGE ;
DA  = DEFO MM1 L1 0. BLEU  ;

SI (NEG GRAPH 'N');
TRAC ( DE ET DA ) ;
FINSI;

*
MESS ' ' ;
MESS ' ' ;
MESS ' MULTIPLICATEUR DU CHARGEMENT ' ;
MESS '                              ' ;
MESS '   SOLUTION ANALYTIQUE  :   41.123 ' ;
MESS '   SOLUTION CALCULEE    : ' LA1 ;
*
TEMPS ;
*------------ CODE DE BON FONCTIONNEMENT --------------
ERR=100*(ABS(41.123 - LA1)/41.123);
SI (ERR < 5);
ERRE 0;
SINON;
ERRE 5;
FINSI;

FIN;

Test flam1 Comments

1. Computation of initial stresses matrix

   KSI1 = KSIGMA MOD1 SIG1 CAR1 'FLAM' ; It is necessary to compute the initial stresses matrix in order to make a buckling analysis. The operator KSIGMA builds the geometrical rigidity matrix joined to a field of stress. The keyword FLAM is necessary to specify that the matrix will be used for a buckling analysis, the created object is also a mass matrix (without the keyword FLAM, the object would be a rigidity matrix).

2. Initialisation of input table of the 'flambage' subroutine

   ETAB = TABLE ; ETAB.'CLIM' = BL1 ;
   ETAB.'RIGI' = RIG1 ; ETAB.'KSIG' = KSI1 ;
   ETAB.'SIG1' = SIG1; ETAB.'MATE' = MAT1;
   ETAB.'LAM1' = 0.001 ; ETAB.'LAM2' = 100. ;
   ETAB.'NMOD' = 1 ; ETAB.'OBJM'= MOD1;
   ETAB is a table which contains the input data for the using of 'flambage' subroutine. This table is defined by different indices. The indices CLIM, LAM1, LAM2, NMOD and OBJM are necessary. The both other indices are either SIG1 and MATE or RIGI and KSIG.

   -

   CLIM : matrix joined to the clampings

   -

   LAM1 : minimal multiplier coefficient

   -

   LAM2 : maximal multiplier coefficient

   -

   NMOD : number of eigen shapes

   -

   OBJM : model object

   -

   SIG1 : yield of stress changing with the strength multiplier

   -

   MATE : material properties

   -

   RIGI : rigidity matrix

   -

   KSIG : geometrical rigidity matrix

3. 'Flambage' subroutine

   STAB = FLAMBAGE ETAB ;
   LA1 = STAB . 1 . LAMB ;
   MM1 = STAB . 1 . DEPL ;
   STAB is a table which contains the output data given by the 'flambage' subroutine. The index of STAB square with every mode shape number so there are as many tables as number of computed moden shapes.
   Each table joined to a mode shape contains four objects which are indexed by :
   

   -

   LAMB : strength multiplier coefficient

   -

   DEPL : deformed and normed shape

   -

   MODN : number of Fourier harmonic

   -

   MODM : number of azimuth mode shape