Exemples de jeux de données Cast3M

* fichier :  ligne.dgibi
'OPTI' echo 0 ;
************************************************************************
************************************************************************
************************************************************************
* NOM         : LIGNE
* DESCRIPTION : Test de verification des operations de creations
*               de ligne
*               En particulier les operateurs DROI et CERC
*               En particulier les densites affectees aux noeuds
*               (calcul via decoup.eso) qui etaient incorrectes
*               avant ce cas-test.
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stephane GOUNAND (CEA/DES/ISAS/DM2S/SEMT/LTA)
*               mel : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 12/08/2025, version initiale
* HISTORIQUE : v1, 12/08/2025, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact=faux ;
*
lok = vrai ;
*
* Cas analytique 1D : 2 segments : 1 de taille 1. et 1 de taille 0.5
*    cad une progression geometrique de raison 0.5 sur la taille des elements
*    Pour les densites des noeuds, qui sont au nombre de 3, la progression est
*    egalement de raison 2 mais avec un decalage de sqrt(raison)
*    (probleme des piquets et des intervalles, choix aussi fait dans decoup.eso).
*    D'ou densite des noeuds : sqrt(2), sqrt(2)/2, sqrt(2)/4
*     coordonnees des noeuds : 0.     ,   1.     ,   1.5
*
'OPTI' 'DIME' 1 'ELEM' 'SEG2' ;
tol = ('VALE' 'PREC') '*' 10. ;
n = 1 ;
n2 = '**' 2. ('*' n -1) ;
x2 = '-' 2. n2 ;
sqr2 = 2. '**' 0.5 ;
x1 = 0.   ; x2 = 1.5 ;
d1 = sqr2 ; d2 = sqr2 '/' 4. ;
*'LIST' d1 ; 'LIST' d2 ;
'OPTI' 'DENS' d1 ;
p0g = 'POIN' 0. ;
p1g = 'POIN' x2 ;
'OPTI' 'DENS' d2 ;
p0f = 'POIN' 0. ;
p1f = 'POIN' x2 ;
*
liga = 'DROI' p0g p1f ;
* Test 1 : coordonnees liga
exliga = 'EVOL' 'CHPO' ('COOR' 1 liga) liga ;
xliga = 'EXTR' exliga 'ORDO' 1 ;
xligax = 'PROG' 0. 1. 1.5 ;
dxliga = 'MAXI' ('-' xliga xligax) 'ABS' ;
tst = 'EGA' dxliga 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor liga' ; 'FINS' ;
lok = lok 'ET' tst ;
*  Test 2 : densites liga
edliga = 'EVOL' 'CHPO' ('COOR' 2 liga) liga ;
dliga = 'EXTR' edliga 'ORDO' 1 ;
dligax = 'PROG' d1 ('/' sqr2 2.) d2 ;
ddliga = 'MAXI' ('-' dliga dligax) 'ABS' ;
tst = 'EGA' ddliga 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens liga' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
ligb = 'DROI' p1g p0f ;
* Test 3 : coordonnees ligb
exligb = 'EVOL' 'CHPO' ('COOR' 1 ligb) ligb ;
xligb = 'EXTR' exligb 'ORDO' 1 ;
xligbx = 'PROG' 1.5 0.5 0. ;
dxligb = 'MAXI' ('-' xligb xligbx) 'ABS' ;
tst = 'EGA' dxligb 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor ligb' ; 'FINS' ;
lok = lok 'ET' tst ;
*  Test 4 : densites ligb
edligb = 'EVOL' 'CHPO' ('COOR' 2 ligb) ligb ;
dligb = 'EXTR' edligb 'ORDO' 1 ;
dligbx = 'PROG' d1 ('/' sqr2 2.) d2 ;
ddligb = 'MAXI' ('-' dligb dligbx) 'ABS' ;
tst = 'EGA' ddligb 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens ligb' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
ligc = 'DROI' p0f p1g ;
* Test 5 : coordonnees ligc
exligc = 'EVOL' 'CHPO' ('COOR' 1 ligc) ligc ;
xligc = 'EXTR' exligc 'ORDO' 1 ;
xligcx = 'PROG' 0. 0.5 1.5 ;
dxligc = 'MAXI' ('-' xligc xligcx) 'ABS' ;
tst = 'EGA' dxligc 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor ligc' ; 'FINS' ;
lok = lok 'ET' tst ;
*  Test 6 : densites ligc
edligc = 'EVOL' 'CHPO' ('COOR' 2 ligc) ligc ;
dligc = 'EXTR' edligc 'ORDO' 1 ;
dligcx = 'PROG' d2 ('/' sqr2 2.) d1 ;
ddligc = 'MAXI' ('-' dligc dligcx) 'ABS' ;
tst = 'EGA' ddligc 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens ligc' ; 'FINS' ;
lok = lok 'ET' tst ;
*
* 2D
*
OPTI 'DIME' 2 'ELEM' 'SEG2' 'DENS' 0.3 ;
*
* Lignes droites
*
p0   = 0. 0. ;
p1   = 1. sqr2 ;
lig0  = 'DROI' p0 p1 ;
edlig0 = 'EVOL' 'CHPO' ('COOR' 3 lig0) lig0 ;
dlig0 = 'EXTR' edlig0 'ORDO' 1 ;
nlig0 = 'NBEL' lig0 ;
* Test 7 Verif de consistance qd on impose le nombre de mailles
lig0b = 'DROI' ('*' nlig0 -1) p0 p1 ;
edlig0b = 'EVOL' 'CHPO' ('COOR' 3 lig0b) lig0b ;
dlig0b = 'EXTR' edlig0b 'ORDO' 1 ;
ddlig0 = 'MAXI' ('-' dlig0 dlig0b) 'ABS' ;
tst = 'EGA' ddlig0 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens lig0b' ; 'FINS' ;
* Test 8 Verif de consistance quand on inverse le sens
lig0c = 'DROI' p0 p1 'DINI' 0.14 ;
edlig0c = 'EVOL' 'CHPO' ('COOR' 3 lig0c) lig0c ;
dlig0c = 'EXTR' edlig0c 'ORDO' 1 ;
lig0d = 'INVE' ('DROI' p0 p1 'DFIN' 0.14) ;
edlig0d = 'EVOL' 'CHPO' ('COOR' 3 lig0d) lig0d ;
dlig0d = 'EXTR' edlig0d 'ORDO' 1 ;
ddlig00 = 'MAXI' ('-' dlig0c dlig0d) 'ABS' ;
tst = 'EGA' ddlig00 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens lig0d' ; 'FINS' ;
*
* Arcs de cercle faits de 3 manieres differentes
*
den = 0.1234 ;
'OPTI' 'DENS' den ;
cen  = 0. 0. ;
p1   = 0. 1. ;
lig1 = CERC 'ROTA' -90. p1 cen ;
exlig1 = 'EVOL' 'CHPO' ('COOR' 1 lig1) lig1 ;
xlig1 = 'EXTR' exlig1 'ORDO' 1 ;
eylig1 = 'EVOL' 'CHPO' ('COOR' 2 lig1) lig1 ;
ylig1 = 'EXTR' eylig1 'ORDO' 1 ;
edlig1 = 'EVOL' 'CHPO' ('COOR' 3 lig1) lig1 ;
dlig1 = 'EXTR' edlig1 'ORDO' 1 ;
* Test 9 : densites lig1
nlig1 = 'NBEL' lig1 ;
dlig1x = 'PROG' den nlig1 * (PI '/' 2. '/' ('FLOT' nlig1)) ;
ddlig1 = 'MAXI' ('-' dlig1 dlig1x) 'ABS' ;
tst = 'EGA' ddlig1 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens lig1' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
lig2 = CERC p1 cen (1. 0.);
exlig2 = 'EVOL' 'CHPO' ('COOR' 1 lig2) lig2 ;
xlig2 = 'EXTR' exlig2 'ORDO' 1 ;
eylig2 = 'EVOL' 'CHPO' ('COOR' 2 lig2) lig2 ;
ylig2 = 'EXTR' eylig2 'ORDO' 1 ;
edlig2 = 'EVOL' 'CHPO' ('COOR' 3 lig2) lig2 ;
dlig2 = 'EXTR' edlig2 'ORDO' 1 ;
* Test 10 : coordonnees lig2
dxlig2 = 'MAXI' ('-' xlig1 xlig2) 'ABS' ;
tst = 'EGA' dxlig2 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor x lig2' ; 'FINS' ;
lok = lok 'ET' tst ;
dylig2 = 'MAXI' ('-' ylig1 ylig2) 'ABS' ;
tst = 'EGA' dylig2 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor y lig2' ; 'FINS' ;
lok = lok 'ET' tst ;
dlig2x = 'PROG' den ('-' nlig1 1) * (PI '/' 2. '/' ('FLOT' nlig1)) den ;
ddlig2 = 'MAXI' ('-' dlig2 dlig2x) 'ABS' ;
tst = 'EGA' ddlig2 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens lig2' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
aa = ('**' 2 (0.5)) '/' 2 ;
lig3 = CER3 p1  (aa aa) (1. 0.);
exlig3 = 'EVOL' 'CHPO' ('COOR' 1 lig3) lig3 ;
xlig3 = 'EXTR' exlig3 'ORDO' 1 ;
eylig3 = 'EVOL' 'CHPO' ('COOR' 2 lig3) lig3 ;
ylig3 = 'EXTR' eylig3 'ORDO' 1 ;
edlig3 = 'EVOL' 'CHPO' ('COOR' 3 lig3) lig3 ;
dlig3 = 'EXTR' edlig3 'ORDO' 1 ;
* Test 11 : coordonnees lig3
dxlig3 = 'MAXI' ('-' xlig1 xlig3) 'ABS' ;
tst = 'EGA' dxlig3 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor x lig3' ; 'FINS' ;
lok = lok 'ET' tst ;
dylig3 = 'MAXI' ('-' ylig1 ylig3) 'ABS' ;
tst = 'EGA' dylig3 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur coor y lig3' ; 'FINS' ;
lok = lok 'ET' tst ;
ddlig3 = 'MAXI' ('-' dlig2 dlig3) 'ABS' ;
tst = 'EGA' ddlig3 0. tol ;
'SI' ('NON' tst) ; 'MESS' '!!!! Erreur dens lig3' ; 'FINS' ;
lok = lok 'ET' tst ;
*
*
*
'SI' ('NON' lok) ;
   'MESSAGE' ('CHAINE' 'Il y a eu des erreurs') ;
   'ERREUR' 5 ;
'SINON' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file LIGNE
*
'FIN' ;