Télécharger tens.dgibi

Retour à la liste

* fichier :  tens.dgibi
'OPTI' echo 0 ;
************************************************************************
************************************************************************
************************************************************************
* NOM         : TENS
* DESCRIPTION : Test de l'operateur TENS.
*               En particulier PRIN et de TENS PRIN
*               qui doivent donner les memes resultats.
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stephane GOUNAND (CEA/DES/ISAS/DM2S/SEMT/LTA)
*               mel : stephane.gounand@cea.fr
**********************************************************************
* VERSION    : v1, 27/07/2025, version initiale
* HISTORIQUE : v1, 27/07/2025, création
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
*
interact=faux ;
*
'DEBP' testtens ;
   'ARGU' cha ;
   tcha = 'TYPE' cha ;
   'SI' ('ET' ('NEG' tcha 'CHPOINT') ('NEG' tcha 'MCHAML')) ;
      'ERRE' 39 avec tcha ;
   'FINS' ;
* Lecture des valeurs propres
   vdim = 'VALE' 'DIME' ;
   'ARGU' lvp/'LISTREEL' ;
   'SI' ('NON' ('EXIS' lvp)) ;
      lvp = 'PROG' ;
      'REPE' bdim vdim ;
         'ARGU' vp*'FLOTTANT' ;
         lvp = 'ET' lvp vp ;
      'FIN' bdim ;
   'FINS' ;
*
   svp = 'SOMM' lvp ;
   pvp = 'EXP' ('SOMM' ('LOG' lvp)) ;
   svp2 = '**' ('SOMM' ('**' lvp 2)) 0.5 ;
   tol1 = ('VALE' prec) '*' ('MAXI' lvp 'ABS') '*' 10. ;
   tol2 = ('VALE' prec) '*' pvp  '*' 10. ;
   tol3 = ('VALE' prec) '*' svp2 '*' 10. ;
   tol4 = ('VALE' prec) '*' ('EXP' ('SOMM' ('ABS' lvp))) '*' 10. ;
   tol5 = ('VALE' prec) '*' ('SOMM' ('EXP' lvp)) '*' 10. ;
   tolabs = tol1 '*' 10. ;
   lok = vrai ;
* Debut des test
*  NORM2
   ch2 = 'TENS' 'NORM2' cha ;
   vch2 = 'MINI' ch2 ;
   d2 = 'ABS' ('-' vch2 svp2) ;
*   vch2b = 0. ;
*   lcomp = 'EXTR' cha 'COMP' ; dlcomp = 'DIME' lcomp ;
*   'REPE' icomp dlcomp ;
*      mcomp = 'EXTR' lcomp &icomp ;
*      vcomp = 'MINI' ('EXCO' cha mcomp) ;
*      vch2b = vch2b '+' ('**' vcomp 2) ;
*   'FIN' icomp ;
*   vch2b = '**' vch2b 0.5 ;
   td2 = '<' d2 tol3 ;
   lok = lok 'ET' td2 ;
   'SI' ('NON' td2) ; 'MESS' '!!! Calcul norm2' d2 ' > ' tol3 ; 'FINS' ;
* NORMINF
   chi = 'TENS' cha 'NORMINF' ;
   vchi = 'MINI' chi ;
   vchi2 = 0. ;
   lcomp = 'EXTR' cha 'COMP' ; dlcomp = 'DIME' lcomp ;
   'REPE' icomp dlcomp ;
      mcomp = 'EXTR' lcomp &icomp ;
      vchi2 = 'MAXI' vchi2 ('MINI' ('EXCO' cha mcomp)) 'ABS' ;
   'FIN' icomp ;
   di = 'ABS' ('-' vchi2 vchi) ;
   tdi = '<' di tol1 ;
   lok = lok 'ET' tdi ;
   'SI' ('NON' tdi) ; 'MESS' '!!! Calcul norminf' di ' > ' tol1 ; 'FINS' ;
* DET
   chd = 'TENS' cha 'DET' ;
   vchd = 'MINI' chd ;
   dd = 'ABS' ('-' vchd pvp) ;
   tdd = '<' dd tol2 ;
   lok = lok 'ET' tdd ;
   'SI' ('NON' tdd) ; 'MESS' '!!! Calcul det' dd ' > ' tol2 ; 'FINS' ;
* TRACE
   cht = 'TENS' cha 'TRACE' ;
   vcht = 'MINI' cht ;
   dt = 'ABS' ('-' vcht svp) ;
   tdt = '<' dt tol1 ;
   lok = lok 'ET' tdt ;
   'SI' ('NON' tdt) ; 'MESS' '!!! Calcul trace' dt ' > ' tol1 ; 'FINS' ;
* LOG
   chl = 'TENS' cha 'LOG' ;
   trchl = 'TENS' chl 'TRACE' ;
   vtrchl  = 'MINI' trchl ;
   vtrchl2 = 'SOMM' ('LOG' lvp) ;
   dvtr  = 'ABS' ('-' vtrchl vtrchl2) ;
   tdvtr = '<' dvtr tol1 ;
   lok = lok 'ET' tdvtr ;
   'SI' ('NON' tdvtr) ; 'MESS' '!!! Calcul trace(Log)' dvtr ' > ' tol1 ; 'FINS' ;
   dtchl = 'TENS' chl 'DET' ;
   vdtchl  = 'MINI' dtchl ;
   vdtchl2 = 'EXP' ('SOMM' ('LOG' ('LOG' lvp))) ;
   dvdtl  = 'ABS' ('-' vdtchl vdtchl2) ;
   tdvdtl = '<' dvdtl tol3 ;
   lok = lok 'ET' tdvdtl ;
   'SI' ('NON' tdvdtl) ; 'MESS' '!!! Calcul det(Log)' dvdtl ' > ' tol3 ; 'FINS' ;
   'SI' ('NON' lok) ; 'ERRE' stop ; 'FINS' ;
* EXP
   chx = 'TENS' cha 'EXP' ;
   trchx = 'TENS' chx 'TRACE' ;
   vtrchx  = 'MINI' trchx ;
   vtrchx2 = 'SOMM' ('EXP' lvp) ;
   dvtr  = 'ABS' ('-' vtrchx vtrchx2) ;
   tdvtr = '<' dvtr tol5 ;
   lok = lok 'ET' tdvtr ;
   'SI' ('NON' tdvtr) ; 'MESS' '!!! Calcul trace(Exp)' dvtr ' > ' tol5 ; 'FINS' ;
   dtchx = 'TENS' chx 'DET' ;
   vdtchx  = 'MINI' dtchx ;
   vdtchx2 = 'EXP' ('SOMM' lvp) ;
   dvdtx  = 'ABS' ('-' vdtchx vdtchx2) ;
   tdvdtx = '<' dvdtx tol4 ;
   lok = lok 'ET' tdvdtx ;
   'SI' ('NON' tdvdtx) ; 'MESS' '!!! Calcul det(Exp)' dvdtx ' > ' tol4 ; 'FINS' ;
   'SI' ('NON' lok) ; 'ERRE' stop ; 'FINS' ;
* INVERSE
   chv  = 'TENS' cha 'INVERSE' ;
   chv2 = 'TENS' 'EXP' ('*' ('TENS' 'LOG' cha) -1.D0) ;
   dv = 'MAXI' ('-' chv chv2) 'ABS' ;
   tdv = '<' dv tol1 ;
   lok = lok 'ET' tdv ;
   'SI' ('NON' tdv) ; 'MESS' '!!! Calcul inverse' dv ' > ' tol1 ; 'FINS' ;
* ABS
   chabs  = 'TENS' ('*' cha -1.) 'ABS' ;
   da = 'MAXI' ('-' chabs cha) 'ABS' ;
   tda = '<' da tolabs ;
   lok = lok 'ET' tda ;
   'SI' ('NON' tda) ; 'MESS' '!!! Calcul abs' da ' > ' tolabs ; 'FINS' ;
'FINP' lok ;
*
lok = vrai ;
*
'OPTION' 'DIME' 1 'ELEM' 'SEG2' ;
'OPTI' 'MODE' unid plan ;
'MESS' ' ********** ' ;
'MESS' ' *   1D   * ' ;
'MESS' ' ********** ' ;
*
p1 = 'POIN' 0. ; p2 = 'POIN' 1. ;
el = 'MANU' 'SEG2' p1 p2 ;
mod = 'MODE' el 'MECANIQUE' ;
*
tol = '*' ('VALE' 'PREC') 10. ;
d1 = '**' 2 0.5 ;
v1 = 'POIN' 1. ;
vx1 = 'COOR' v1 ;
g11 = (vx1 '*' d1 '*' vx1) ;
*
* Décomposition spectrale
*
'REPE' bcl 3 ;
   ibcl = &bcl ;
   'SI' ('EGA' ibcl 1) ;
      'MESS' 'Operateur PRIN' ;
      cha = 'MANU' 'CHML' mod 'SMXX' g11 'SMYY' 0. 'SMZZ' 0. 'TYPE' 'CONTRAINTES' 'STRESSES' ;
      dec = 'PRIN' cha mod ;
      d1b = 'EXTR' dec el 'SI11' ;
      vx1b = 1. ;
      cha = 'EXCO' cha 'SMXX' ;
   'FINS' ;
   'SI' ('EGA' ibcl 2) ;
      'MESS' 'Operateur TENS PRINCIPA CHPO' ;
      cha = 'MANU' 'CHPO' el 'G11' g11 ;
      dec = 'TENS' 'PRIN' cha ;
      d1b = 'EXTR' dec 'SI11' p2 ;
      vx1b = 'EXTR' dec 'CO11' p1 ;
   'FINS' ;
   'SI' ('EGA' ibcl 3) ;
      'MESS' 'Operateur TENS PRINCIPA CHAM' ;
      cha = 'MANU' 'CHML' mod 'G11' g11 'STRESSES' ;
      dec = 'TENS' 'PRIN' cha ;
      d1b = 'EXTR' dec el 'SI11' ;
      vx1b = 'EXTR' dec el 'CO11' ;
   'FINS' ;
   v1b = 'POIN' vx1b ;
* Test
   dd1 = 'ABS' ('-' d1 d1b) ;
   tdd1 = '<' dd1 tol ;
   lok = lok 'ET' tdd1 ;
   'SI' ('NON' tdd1) ; 'MESS' '!!! Calcul valp1' d1 ' > ' tol ; 'FINS' ;
   dv1m = 'NORM' ('MOIN' v1 v1b) ; dv1p = 'NORM' ('PLUS' v1 v1b) ;
   tdv1 = ('<' dv1m tol) 'OU' ('<' dv1p tol) ;
   lok = lok 'ET' tdv1 ;
   'SI' ('NON' tdv1) ; 'MESS' '!!! Calcul vecp1' ; 'FINS' ;
   'SI' lok ; 'MESS' 'OK' ; 'FINS' ;
*
* Autres fonctions de TENS
*
   ltens = testtens cha d1 ;
   lok = lok 'ET' ltens ;
   'SI' ('NON' ltens) ;
      'MESS' '!!! TESTTENS not ok' ;
   'SINO' ;
      'MESS' 'TESTTENS OK' ;
   'FINS' ;
'FIN' bcl ;
*
'OPTION' 'DIME' 2 'ELEM' 'TRI3' ;
'OPTI' 'MODE' plan defo ;
'MESS' ' ********** ' ;
'MESS' ' *   2D   * ' ;
'MESS' ' ********** ' ;
*
p3 = 0. 1. ;
el = 'MANU' 'TRI3' p1 p2 p3 ;
mod = 'MODE' el 'MECANIQUE' ;
*
v1 = 1. 0. ; v2 = 0. 1. ;
alf = pi '*' 10. ;
d2 = 'EXP' 1. ;
v1 v2 = 'TOUR' v1 v2 alf p1 ;
*
* Recomposition spectrale
*
vx1 vy1 = 'COOR' v1 ;
vx2 vy2 = 'COOR' v2 ;
g11  = (vx1 '*' d1 '*' vx1) '+'  (vx2 '*' d2 '*' vx2) ;
g22  = (vy1 '*' d1 '*' vy1) '+'  (vy2 '*' d2 '*' vy2) ;
g21  = (vy1 '*' d1 '*' vx1) '+'  (vy2 '*' d2 '*' vx2) ;
*
* Décomposition spectrale
*
'REPE' bcl 3 ;
   ibcl = &bcl ;
   'SI' ('EGA' ibcl 1) ;
      'MESS' 'Operateur PRIN' ;
      cha = 'MANU' 'CHML' mod 'SMXX' g11 'SMYY' g22 'SMXY' g21 'SMZZ' 0. 'TYPE' 'CONTRAINTES' 'STRESSES' ;
      dec = 'PRIN' cha mod ;
      d2b = 'EXTR' dec el 'SI11' ;
      d1b = 'EXTR' dec el 'SI22' ;
      vx1b = 'EXTR' dec el 'COX2' ;
      vy1b = 'EXTR' dec el 'COY2' ;
      vx2b = 'EXTR' dec el 'COX1' ;
      vy2b = 'EXTR' dec el 'COY1' ;
      cha = 'EXCO' ('MOTS' 'SMYY' 'SMXY' 'SMXX') cha ;
   'FINS' ;
   'SI' ('EGA' ibcl 2) ;
      'MESS' 'Operateur TENS PRINCIPA CHPO' ;
      cha = 'MANU' 'CHPO' el 'G11' g11 'G22' g22 'G21' g21 ;
      dec = 'TENS' 'PRIN' cha ;
      d2b = 'EXTR' dec 'SI11' p1 ;
      d1b = 'EXTR' dec 'SI22' p2 ;
      vx1b = 'EXTR' dec 'CO12' p3 ;
      vy1b = 'EXTR' dec 'CO22' p1 ;
      vx2b = 'EXTR' dec 'CO11' p2 ;
      vy2b = 'EXTR' dec 'CO21' p3 ;
   'FINS' ;
   'SI' ('EGA' ibcl 3) ;
      'MESS' 'Operateur TENS PRINCIPA CHAM' ;
      cha = 'MANU' 'CHML' mod 'G11' g11 'G22' g22 'G21' g21 'STRESSES' ;
      dec = 'TENS' 'PRIN' cha ;
      d2b = 'EXTR' dec el 'SI11' ;
      d1b = 'EXTR' dec el 'SI22' ;
      vx1b = 'EXTR' dec el 'CO12' ;
      vy1b = 'EXTR' dec el 'CO22' ;
      vx2b = 'EXTR' dec el 'CO11' ;
      vy2b = 'EXTR' dec el 'CO21' ;
   'FINS' ;
   v1b = vx1b vy1b ;
   v2b = vx2b vy2b ;
* Test
   dd1 = 'ABS' ('-' d1 d1b) ;
   tdd1 = '<' dd1 tol ;
   lok = lok 'ET' tdd1 ;
   'SI' ('NON' tdd1) ; 'MESS' '!!! Calcul valp1' d1 ' > ' tol ; 'FINS' ;
   dd2 = 'ABS' ('-' d2 d2b) ;
   tdd2 = '<' dd2 tol ;
   lok = lok 'ET' tdd2 ;
   'SI' ('NON' tdd2) ; 'MESS' '!!! Calcul valp2' d2 ' > ' tol ; 'FINS' ;
   dv1m = 'NORM' ('MOIN' v1 v1b) ; dv1p = 'NORM' ('PLUS' v1 v1b) ;
   tdv1 = ('<' dv1m tol) 'OU' ('<' dv1p tol) ;
   lok = lok 'ET' tdv1 ;
   'SI' ('NON' tdv1) ; 'MESS' '!!! Calcul vecp1' ; 'FINS' ;
   dv2m = 'NORM' ('MOIN' v2 v2b) ; dv2p = 'NORM' ('PLUS' v2 v2b) ;
   tdv2 = ('<' dv2m tol) 'OU' ('<' dv2p tol) ;
   lok = lok 'ET' tdv2 ;
   'SI' ('NON' tdv2) ; 'MESS' '!!! Calcul vecp2' ; 'FINS' ;
   'SI' lok ; 'MESS' 'OK' ; 'FINS' ;
*
* Autres fonctions de TENS
*
   ltens = testtens cha d1 d2 ;
   'SI' ('NON' ltens) ;
      'MESS' '!!! TESTTENS not ok' ;
   'SINO' ;
      'MESS' 'TESTTENS OK' ;
   'FINS' ;
'FIN' bcl ;
*
'OPTION' 'DIME' 3 'ELEM' 'TET4' ;
'OPTI' 'MODE' 'TRID' ;
'MESS' ' ********** ' ;
'MESS' ' *   3D   * ' ;
'MESS' ' ********** ' ;
*
tol = '*' ('VALE' 'PREC') 100. ;
p4 = 0. 0. 1. ;
el = 'MANU' 'TET4' p1 p2 p3 p4 ;
mod = 'MODE' el 'MECANIQUE' ;
*
v3 = 0. 0. -1. ;
bet = pi ;
d3 = bet ;
v1 v2 v3 = 'TOUR' v1 v2 v3 bet p1 (2. 3. 5.) ;
*
* Recomposition spectrale
*
vx1 vy1 vz1 = 'COOR' v1 ;
vx2 vy2 vz2 = 'COOR' v2 ;
vx3 vy3 vz3 = 'COOR' v3 ;
g11  = (vx1 '*' d1 '*' vx1) '+'  (vx2 '*' d2 '*' vx2) '+'  (vx3 '*' d3 '*' vx3) ;
g22  = (vy1 '*' d1 '*' vy1) '+'  (vy2 '*' d2 '*' vy2) '+'  (vy3 '*' d3 '*' vy3) ;
g33  = (vz1 '*' d1 '*' vz1) '+'  (vz2 '*' d2 '*' vz2) '+'  (vz3 '*' d3 '*' vz3) ;
*
g21  = (vy1 '*' d1 '*' vx1) '+'  (vy2 '*' d2 '*' vx2) '+'  (vy3 '*' d3 '*' vx3) ;
g31  = (vz1 '*' d1 '*' vx1) '+'  (vz2 '*' d2 '*' vx2) '+'  (vz3 '*' d3 '*' vx3) ;
g32  = (vz1 '*' d1 '*' vy1) '+'  (vz2 '*' d2 '*' vy2) '+'  (vz3 '*' d3 '*' vy3) ;
*
* Décomposition spectrale
*
'REPE' bcl 3 ;
   ibcl = &bcl ;
   'SI' ('EGA' ibcl 1) ;
      'MESS' 'Operateur PRIN' ;
      cha = 'MANU' 'CHML' mod 'SMXX' g11 'SMYY' g22 'SMZZ' g33 'SMXY' g21 'SMXZ' g31 'SMYZ' g32 'TYPE' 'CONTRAINTES' 'STRESSES' ;
      dec = 'PRIN' cha mod ;
      d3b = 'EXTR' dec el 'SI11' ;
      d2b = 'EXTR' dec el 'SI22' ;
      d1b = 'EXTR' dec el 'SI33' ;
      vx1b = 'EXTR' dec el 'COX3' ;
      vy1b = 'EXTR' dec el 'COY3' ;
      vz1b = 'EXTR' dec el 'COZ3' ;
      vx2b = 'EXTR' dec el 'COX2' ;
      vy2b = 'EXTR' dec el 'COY2' ;
      vz2b = 'EXTR' dec el 'COZ2' ;
      vx3b = 'EXTR' dec el 'COX1' ;
      vy3b = 'EXTR' dec el 'COY1' ;
      vz3b = 'EXTR' dec el 'COZ1' ;
   'FINS' ;
   'SI' ('EGA' ibcl 2) ;
      'MESS' 'Operateur TENS PRINCIPA CHPO' ;
      cha = 'MANU' 'CHPO' el 'G11' g11 'G22' g22 'G33' g33 'G21' g21 'G31' g31 'G32' g32 ;
      dec = 'TENS' 'PRIN' cha ;
      d3b = 'EXTR' dec 'SI11' p4 ;
      d2b = 'EXTR' dec 'SI22' p3 ;
      d1b = 'EXTR' dec 'SI33' p2 ;
      vx1b = 'EXTR' dec 'CO13' p1 ;
      vy1b = 'EXTR' dec 'CO23' p4 ;
      vz1b = 'EXTR' dec 'CO33' p3 ;
      vx2b = 'EXTR' dec 'CO12' p2 ;
      vy2b = 'EXTR' dec 'CO22' p1 ;
      vz2b = 'EXTR' dec 'CO32' p4 ;
      vx3b = 'EXTR' dec 'CO11' p3 ;
      vy3b = 'EXTR' dec 'CO21' p2 ;
      vz3b = 'EXTR' dec 'CO31' p1 ;
   'FINS' ;
   'SI' ('EGA' ibcl 3) ;
      'MESS' 'Operateur TENS PRINCIPA CHAM' ;
      cha = 'MANU' 'CHML' mod  'G11' g11 'G22' g22 'G33' g33 'G21' g21 'G31' g31 'G32' g32 'STRESSES' ;
      dec = 'TENS' 'PRIN' cha ;
      d3b = 'EXTR' dec el 'SI11' ;
      d2b = 'EXTR' dec el 'SI22' ;
      d1b = 'EXTR' dec el 'SI33' ;
      vx1b = 'EXTR' dec el 'CO13' ;
      vy1b = 'EXTR' dec el 'CO23' ;
      vz1b = 'EXTR' dec el 'CO33' ;
      vx2b = 'EXTR' dec el 'CO12' ;
      vy2b = 'EXTR' dec el 'CO22' ;
      vz2b = 'EXTR' dec el 'CO32' ;
      vx3b = 'EXTR' dec el 'CO11' ;
      vy3b = 'EXTR' dec el 'CO21' ;
      vz3b = 'EXTR' dec el 'CO31' ;
   'FINS' ;
   v1b = vx1b vy1b vz1b;
   v2b = vx2b vy2b vz2b ;
   v3b = vx3b vy3b vz3b ;
* Test
   dd1 = 'ABS' ('-' d1 d1b) ;
   tdd1 = '<' dd1 tol ;
   lok = lok 'ET' tdd1 ;
   'SI' ('NON' tdd1) ; 'MESS' '!!! Calcul valp1'  d1 ' > ' tol ; 'FINS' ;
   dd2 = 'ABS' ('-' d2 d2b) ;
   tdd2 = '<' dd2 tol ;
   lok = lok 'ET' tdd2 ;
   'SI' ('NON' tdd2) ; 'MESS' '!!! Calcul valp2'  d2 ' > ' tol ; 'FINS' ;
   dd3 = 'ABS' ('-' d3 d3b) ;
   tdd3 = '<' dd3 tol ;
   lok = lok 'ET' tdd3 ;
   'SI' ('NON' tdd3) ; 'MESS' '!!! Calcul valp3'  d3 ' > ' tol ; 'FINS' ;
   dv1m = 'NORM' ('MOIN' v1 v1b) ; dv1p = 'NORM' ('PLUS' v1 v1b) ;
   tdv1 = ('<' dv1m tol) 'OU' ('<' dv1p tol) ;
   lok = lok 'ET' tdv1 ;
   'SI' ('NON' tdv1) ; 'MESS' '!!! Calcul vecp1' ; 'FINS' ;
   dv2m = 'NORM' ('MOIN' v2 v2b) ; dv2p = 'NORM' ('PLUS' v2 v2b) ;
   tdv2 = ('<' dv2m tol) 'OU' ('<' dv2p tol) ;
   lok = lok 'ET' tdv2 ;
   'SI' ('NON' tdv2) ; 'MESS' '!!! Calcul vecp2' ; 'FINS' ;
   dv3m = 'NORM' ('MOIN' v3 v3b) ; dv3p = 'NORM' ('PLUS' v3 v3b) ;
   tdv3 = ('<' dv3m tol) 'OU' ('<' dv3p tol) ;
   lok = lok 'ET' tdv3 ;
   'SI' ('NON' tdv3) ; 'MESS' '!!! Calcul vecp3' ; 'FINS' ;
   'SI' lok ; 'MESS' 'OK' ; 'FINS' ;
*
* Autres fonctions de TENS
*
   ltens = testtens cha d1 d2 d3 ;
   lok = lok 'ET' ltens ;
   'SI' ('NON' ltens) ;
      'MESS' '!!! TESTTENS not ok' ;
   'SINO' ;
      'MESS' 'TESTTENS OK' ;
   'FINS' ;
'FIN' bcl ;
*
'SI' ('NON' lok) ;
   'MESSAGE' ('CHAINE' 'Il y a eu des erreurs') ;
   'ERREUR' 5 ;
'SINON' ;
   'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
'FINSI' ;
*
'SI' interact ;
   'OPTION' 'ECHO' 1 'DONN' 5 ;
'FINSI' ;
*
* End of dgibi file TENS
*
'FIN' ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales