Exemples de jeux de données Cast3M

** Test du krigeage en dimension 2
 
* Sur la base sur la reference suivante :
* Edward H. Isaaks, R. Mohan Srivasta
* Applied Geostatistics, Oxford University Press, 1989 - 561 pages
*
* L'exemple traite ici est situe chapitre 12, pages 290-296
* Consultable sur : https://www.geokniga.org/bookfiles/geokniga-anintroductiontoappliedgeostatistics.pdf
 
 
** Options generales
OPTI 'DIME' 2 'ECHO' 0 ;
itrac = FAUX ;
 
 
** Valeurs des points de mesure
lx    = PROG  61.  63.  64.  68.  71.  73.  75. ;
ly    = PROG 139. 140. 129. 128. 140. 141. 128. ;
lf    = PROG 477. 696. 227. 646. 606. 791. 783. ;
 
 
** Maillage et champs pour visualiser ces points de mesure
ptm   = POIN lx ly ;
x y   = COOR ptm ;
mes   = (NOMC 'X' x) ET (NOMC 'Y' y) ET (MANU 'CHPO' ptm 1 'FONC' lf 'NATURE' 'DIFFUS') ;
 
 
** Variogramme (modele gaussien avec pepite, palier et portee)
c0    = 0. ;
c1    = 10. ;
a     = 10. ;
lh    = PROG 0. 'PAS' 0.01 20. ;
lg    = c0 + (c1 * (1. - (EXP (-3. * lh / a)))) ;
REMP lg 1 0. ;
gam   = EVOL 'VERT' 'MANU' lh lg ;
SI itrac ;
  DESS gam 'TITR' 'Variogramme (modele gaussien)' ;
FINSI ;
 
 
** Covariogramme
lc    = c1 * (EXP (-3. * lh / a)) ;
REMP lc 1 (c0 + c1) ;
cov   = EVOL 'VERT' 'MANU' lh lc ;
SI itrac ;
  DESS cov 'TITR' 'Covariogramme (modele gaussien)' ;
FINSI ;
 
 
** Maillage de points cibles, ou l'on veut interpoler
OPTI 'DENS' 0.2 'ELEM' 'QUA4' ;
lig1  = DROI (60. 120.) (80 120.) ;
mail  = lig1 TRAN (0. 25.) ;
ncib  = NBNO mail ;
con   = CONT mail ;
x y   = COOR mail ;
cib   = (NOMC 'X' x) ET (NOMC 'Y' y) ;
 
 
** Krigeage au points cibles (avec le variogramme)
t     = TABL ;
t . 'COORDONNEES' = MOTS 'X' 'Y' ;
t . 'MESURES'     = mes ;
t . 'COMPOSANTE'  = MOT 'FONC' ;
t . 'CIBLES'      = cib ;
t . 'VARIOGRAMME' = gam ;
TEMP 'ZERO' ;
est1 var1 = KRIG t ;
tps1  = TEMP 'HORL' ;
MESS 'Krigeage avec variogramme sur' ' ' ncib ' points realise en' ' ' tps1 ' ms' ;
 
 
** Krigeage au points cibles (avec le variogramme)
t     = TABL ;
t . 'COORDONNEES'   = MOTS 'X' 'Y' ;
t . 'MESURES'       = mes ;
t . 'COMPOSANTE'    = MOT 'FONC' ;
t . 'CIBLES'        = cib ;
t . 'COVARIOGRAMME' = cov ;
TEMP 'ZERO' ;
est2 var2 = KRIG t ;
tps2  = TEMP 'HORL' ;
MESS 'Krigeage avec covariogramme sur' ' ' ncib ' points realise en' ' ' tps2 ' ms' ;
 
 
** Test d'egalite des resultats variogramme/covariogramme
err1  = MAXI 'ABS' (est2 - est1) ;
err2  = MAXI 'ABS' (var2 - var1) ;
MESS 'Ecart max. sur l''estimation :' err1 ;
MESS 'Ecart max. sur la variance   :' err2 ;
SI ((err1 > 1.E-10) OU (err2 > 1.E-10)) ;
  ERRE 'Ecart entre le krigeage par variance et covariance !' ;
FINSI ;
 
 
** Valeurs au point de reference
xtest = 65. ;
ytest = 137. ;
ptest = mail POIN 'PROC' (xtest ytest) ;
ftest = EXTR est2 'FONC' ptest ;
vtest = EXTR var2 'FONC' ptest ;
MESS ;
MESS 'Point cible de test x y   :' xtest ' ' ytest ;
MESS 'Estimation de la fonction :' ftest ;
MESS 'Variance d''estimation     :' vtest ;
 
 
** Comparaison a la solution de reference et test
fref = 592.7 ;
vref = 8.96 ;
errf = ((FLOT (@ARR ftest 1)) - fref) / fref ;
errv = ((FLOT (@ARR vtest 2)) - vref) / vref ;
MESS ;
MESS 'Erreur relative sur l''estimation :' errf ;
MESS 'Erreur relative sur la variance  :' errv ;
errm = MAXI 'ABS' errf errv ;
SI (errm > 1.E10) ;
  ERRE '--> Mauvaise interpolation :-(' ;
FINSI ;
 
 
** Trace des champs
SI itrac ;
  TRAC est2 mail con 'TITR' 'Interpolation de la fonction par Krigeage' ;
  TRAC var2 mail con 'TITR' 'Variance de l''estimation par Krigeage' ;
FINSI ;
 
 
FIN ;