Exemples de jeux de données Cast3M

** Test de l'operateur de KRIGEAGE en dimension 1
 
 
** Options generales
OPTI 'DIME' 1 'ECHO' 0 ;
itrac = FAUX ;
 
 
** Valeurs des points de mesure
lxm   = PROG 0.3  1.9  1.1  3.3  4.7 ;
lfm   = PROG 0.47 0.56 0.74 1.47 1.74 ;
evm   = EVOL 'VERT' 'MANU' 'LEGE' 'Donnees d''entree' 'STYL' 'NOLI' 'MARQ' 'ROND' 'X' lxm 'F' lfm ;
 
 
** Rangement des mesures dans un CHPOINT
mpm   = POIN lxm ;
mes   = MANU 'CHPO' mpm 2 'X' lxm 'F' lfm 'NATURE' 'DIFFUS' ;
 
 
** Creation d'un CHPOINT des cibles ou interpoler
lxc   = PROG -1. 'PAS' 0.01 6. ;
mail  = POIN lxc ;
cib   = MANU 'CHPO' mail 1 'X' lxc 'NATURE' 'DIFFUS' ;
 
 
** Variogramme des mesures (modele gaussien)
c     = 0.5 ;
a     = 2. ;
ld    = PROG 0. 'PAS' 0.01 10. ;
lgam  = c * (1. - (EXP (-3. * ((ld / a) ** 2)))) ;
gam   = EVOL 'VERT' 'MANU' 'Distance' ld 'Semivariance' lgam ;
 
 
** Krigeage au points cibles (avec le variogramme)
t     = TABL ;
t . 'COORDONNEES' = MOTS 'X' ;
t . 'MESURES'     = mes ;
t . 'COMPOSANTE'  = MOT 'F' ;
t . 'CIBLES'      = cib ;
t . 'VARIOGRAMME' = gam ;
est1 var1 = KRIG t ;
 
 
** Covariogramme
lcov  = c * (EXP (-3. * ((ld / a) ** 2))) ;
cov   = EVOL 'VERT' 'MANU' 'Distance' ld 'Covariance' lcov ;
 
 
** Krigeage au points cibles (avec le covariogramme)
t     = TABL ;
t . 'COORDONNEES'   = MOTS 'X' ;
t . 'MESURES'       = mes ;
t . 'COMPOSANTE'    = MOT 'F' ;
t . 'CIBLES'        = cib ;
t . 'COVARIOGRAMME' = cov ;
est2 var2 = KRIG t ;
 
 
** Test d'egalite des resultats
err1  = MAXI 'ABS' (est2 - est1) ;
err2  = MAXI 'ABS' (var2 - var1) ;
MESS 'Ecart max. sur l''estimation :' err1 ;
MESS 'Ecart max. sur la variance   :' err2 ;
SI ((err1 > 1.E-10) OU (err2 > 1.E-10)) ;
  ERRE 'Ecart entre le krigeage par variance et covariance !' ;
FINSI ;
 
 
** Trace des resultats
SI itrac ;
  lfk   = EXTR est1 'VALE' ;
  fk    = EVOL 'ROUG' 'MANU' 'LEGE' 'Estimation par krigeage' 'X' lxc 'F' lfk ;
  lvk   = EXTR var1 'VALE' ;
  lv1   = lfk + lvk ;
  lv2   = lfk - lvk ;
  vk1   = EVOL 'ORAN' 'MANU' 'LEGE' 'Esitmation + variance' 'STYL' 'TIRR' 'X' lxc 'F' lv1 ;
  vk2   = EVOL 'ORAN' 'MANU' 'LEGE' 'Estimation - variance' 'STYL' 'TIRR' 'X' lxc 'F' lv2 ;
  DESS (evm ET fk ET vk1 ET vk2) 'TITR' 'Interpolation par krigeage + variance d''estimation' 'LEGE' ;
FINSI ;
 
 
FIN ;