Exemple : Maillage d'un cylindre creux

Il existe de nombreuses façons de réaliser un maillage. Voici deux exemples de maillage d'un cylindre creux, le premier compliqué, le second plus simple.

EXEMPLE 1

OPTI DIME 3 ELEM CUB8 ;
********************************************************************************
*POINTS
H1 = 5.  ; COMM Hauteur du cylindre ;
R1 = 2.  ; COMM Rayon interieur ;
R2 = 2.5 ; COMM Rayon exterieur ;
O1 = 0. 0. 0. ; O2 = 0. 0. H1 ; COMM Points de l axe du cylindre ;
P11 =     R1  0. 0. ;  P12 = 0.   R1    0. ;
P13 = ((-1.)*R1) 0. 0. ;  P14 = 0. ((-1.)*R1) 0. ;
P21 =     R2  0. 0. ;  P22 = 0.   R2    0. ;
P23 = ((-1.)*R2) 0. 0. ;  P24 = 0. ((-1.)*R2) 0. ;

********************************************************************************
*LIGNES
*Contour interieur de la base
C11 = C 20 P11 O1 P12 ;
C12 = C 20 P12 O1 P13 ;
C13 = C 20 P13 O1 P14 ;
C14 = C 20 P14 O1 P11 ;
CONT1 = C11 ET C12 ET C13 ET C14 ;

*Contour exterieur de la base
C21 = C 20 P22 O1 P21 ;
C22 = C 20 P23 O1 P22 ;
C23 = C 20 P24 O1 P23 ;
C24 = C 20 P21 O1 P24 ;
CONT2 = C21 ET C22 ET C23 ET C24 ;

CONTTOT1 = CONT1 ET CONT2 ;

********************************************************************************
*SURFACE
SURF1 = SURF CONTTOT1 'PLAN' ; 

********************************************************************************
*VOLUME
VOL1 = SURF1 VOLU 10 TRANS (0. 0. H1) ;

********************************************************************************
*TRACAGE
TITRE 'MAILLAGE D UN CYLINDRE CREUX' ;
TRAC CACH QUAL VOL1 ;
FIN;

Remarques sur le fichier d'exemple 1

• OPTI DIME 3 ELEM CUB8 ;
  On travaille en trois dimensions en utilisant des éléments CUB8. En fait, l'option ELEM permet de définir la classe d'éléments (linéaires ou quadratiques) en donnant l'élément de niveau le plus complexe. Ainsi CUB8 autorise autorise aussi les éléments POI1, SEG2, TRI3, QUA4, TET4, PYR5 et PRI6. La définition de CUB8 en début de fichier évite de préciser à chaque étape (lignes, surfaces et volume) le nouveau type d'éléments.
• COMM Hauteur du cylindre ;
  La directive COMM(ENTAIRE) permet d'introduire des commentaires dans le jeu de données. Le commentaire prend fin au point-virgule. Cette directive est équivalente à un astérisque placé en début de ligne.
• Le contour CONT2 doit tourner dans le sens opposé de CONT1 (dans l'optique de l'utilisation de SURFACE avec des contours extérieur et intérieur).
• TRAC CACH QUAL VOL1;
  L'option QUAL de la directive TRAC permet d'afficher sur le dessin le nom des entités qui y figurent.

EXEMPLE 2

OPTI DIME 3 ELEM CUB8 ;
********************************************************************************
*POINTS 
H1 = 5.  ; COMM Hauteur du cylindre ; 
R1 = 2.  ; COMM Rayon interieur ; 
R2 = 2.5 ; COMM Rayon exterieur ; 
O1 = 0. 0. 0. ; O2 = 0. 0. H1 ; COMM Points de l axe du cylindre ; 
P11 =  R1 0. 0. ;
P21 =  R2 0. 0. ;

********************************************************************************
L1   = P11 D 3 P21 ;
SEC1 = L1 TRANS 10 (0. 0. H1) ;
VO1  = SEC1 VOLU 40 ROTA 180 O1 O2 ;
VO2  = VO1 VOLU 40 ROTA 180 O1 O2 ;
VOL1 = VO1 ET VO2 ;
ELIM 0.001 VOL1 ; 

********************************************************************************
*TRACAGE 
TITRE 'MAILLAGE D UN CYLINDRE CREUX' ; 
TRAC CACH VOL1 ; 

FIN;

Remarques sur le fichier d'exemple 2

• ELIM 0.01 VOL1 ;
  La directive ELIM(INATION) remplace dans l'objet VOL1 tous les nuds distants de moins de 0.001 par un seul point. Elle est utilisée pour éliminer les nuds doubles créés par la construction du volume VO2 avec l'opérateur VOLUME ROTA. En effet, VO1 et VO2 ont des faces communes mais qui sont indépendantes et ont leurs propres nuds. Ainsi il existe des nuds doubles qu'il est nécessaire de fusionner.
  Cette directive est à utiliser avec précaution : s'il existe dans un champ par point des valeurs différentes pour les nuds doubles, il sera difficile de savoir quelle valeur garder.
• Parfois une démarche simple est écartée par le souci de nommer au fur et à mesure des objets dont on aura besoin pour l'application des conditions aux limites. Dans cet exemple, on peut donc regretter de ne pas avoir nommé les points du plan XOY si on veut encastrer le cylindre. Dans ce cas il faut les nommer après la réalisation du maillage.