Fichier de données

OPTION ECHO 0;                                                                  
TITRE 'POUTRE EN FLEXION  ';
OPTION DIME 3 ELEM SEG2 ;
*
*---------------------DEFINITION DE LA GEOMETRIE--------------------*
*
P1 = 0.  0.  0. ; 
P2 = 10. 0.  0. ;
L1 = P1 D 1 P2  ; 
TRACE QUAL L1 ;
*
*-----------------CHOIX DU COMPORTEMENT ET DU MODELE----------------*
*
MOD1  = MODEL L1 MECANIQUE ELASTIQUE PLASTIQUE CINEMATIQUE POUT ;
MAT1 = MATE MOD1 YOUN 1.E7 NU 0.3 SIGY 1.E4 H (0.1*1.E7) ;
CAR1 = CARA MOD1 SECT 0.1 INRY 8.333E-5 INRZ 8.333E-3 TORS 0.0001 
       VECT (0. 1. 0.) DX 0. DY 0. DZ 0.3333 ;
*
*------------------FORCES ET CONDITIONS AUX LIMITES-----------------*
*
AMPFY = -10. ; 
F1 = FORCE (0. AMPFY 0.) P2 ;
CL1 = BLOQ  DEPLA ROTA P1 ;
* 
*-----------------------------CHARGEMENT----------------------------*
*
LI1 = PROG 0. 3. 6. ; 
LI2 = PROG 0. 3. 0. ;
EV = EVOL MANU 'Temps' LI1 'F(t)' LI2 ;
CHA1 = CHAR MECA F1 EV ;
DESS EV TITRE 'Ftot= -10.F(t)' ;          
*
*--------------------------CALCUL PAS A PAS-------------------------*
*
LIS_TPS = PROG 0. PAS 0.05 6. ;
TAB1 = TABLE ;
TAB1.'MODELE'              = MOD1 ;
TAB1.'CARACTERISTIQUES'    = MAT1 ET CAR1 ;
TAB1.'CHARGEMENT'          = CHA1 ;
TAB1.'BLOCAGES_MECANIQUES' = CL1  ;
TAB1.'TEMPS_CALCULES'      = LIS_TPS ;
TAB1.'TEMPS_SAUVES'        = LIS_TPS ;
PASAPAS TAB1 ;
*
*-------------------------POST TRAITEMENT--------------------------*
*
SI (TAB1.ERREUR) ;
  MESS 'Erreur reperee lors de l execution du calcul' ;
SINON ;
  MESS 'Aucune erreur lors de l execution du calcul' ;
  SI TAB1.CONV ;
    MESS 'Convergence du calcul' ;
  SINON ;
    MESS 'Pas de convergence du calcul pour le nombre d'iterations demande' ;
  FINSI ;
FINSI ;        
TAB2 = TAB1.DEPLACEMENTS ;
NDIM = DIME TAB2 ;
IB = 0 ;
LIS1 = PROG ;
LIS2 = PROG ;
REPETER BOUC1 NDIM ; 
  DDD = EXTR (TAB2.IB) P2 UY ;
  LIS1 = PROG 0. PAS 0.5 30. PAS -0.5 0. ;
  LIS2 = INSER LIS2 &BOUC1 (-1.*DDD) ;
  IB = IB+1 ;
FIN BOUC1 ;
TITRE 'COURBE DEPLACEMENT-FORCE' ;
EV1 = EVOL MANU LIS2 'DEPLACEMENT' LIS1 'FORCE' ;
DESS EV1 ;
*
FMAX = (NDIM/2) ;
FFIN = NDIM - 1 ;
CHDEPM = TAB2.FMAX ;
CHDEPF = TAB2.FFIN ;
DEF0 = DEFO L1 CHDEPF 0. BLAN ;
DEF1 = DEFO L1 CHDEPM 1. ROUGE ;
DEF2 = DEFO L1 CHDEPF 1. VERT ;
OEIL = 0. 0. 1000. ;
TITRE 'DEFORMEE DE LA POUTRE APPLICATION FORCE MAXI' ;
TRAC OEIL (DEF0 ET DEF1)  ;
TRAC OEIL (DEF0 ET DEF2) TITRE 'DEFORMEE DE LA POUTRE APRES RELACHE' ;
*
FIN;