Fichier de données

TITRE 'TUBE SOUMIS A UNE CONVECTION FORCEE' ;    
OPTION DIME 2 ELEM QUA4 MODE AXIS ;           
OPTION ECHO 0 ; SAUT LIGNE ;      
*                                         
*---  CREATION DE LA GEOMETRIE:       
*                              
P1 = 6. 0. ; P2 = 16.  0.  ;
VEC1 = 0. 4. ;    
* 
L1 = D 8 P1 P2 ;                                
SURF1  = L1 TRANS 5 VEC1 ;   
TRAC SURF1 ;                              
*                 
D1 = COTE 4 SURF1 ;            
D3 = COTE 2 SURF1 ;  
P3 = SURF1 POIN PROC (16. 4.) ;              
*  
*---  DONNEES DU PROBLEME DE THERMIQUE:          
*                                    
*---  MODELISATION:                
*                                
MOD1 = MODEL SURF1 THERMIQUE ISOTROPE ;     
MOD2 = MODEL D3 CONVECTION ;        
*                                      
*---  CARACTERISTIQUES DU MATERIAU:    
*                      
MAT1 = MATER MOD1 K 8. ; 
MAT2 = MATER MOD2 H 5. ;          
*                                    
*---  MATRICE DE CONDUCTIVITE:       
*                                  
COND1 = CONDUCTIVITE MOD1 MAT1 ;    
COND2 = CONDUCTIVITE MOD2 MAT2 ;     
*                           
*---  CONDITIONS AUX LIMITES : TEMPERATURES IMPOSEES          
*    
CL1 = BLOQUE T D1 ;            
DCL1 = DEPI CL1 100. ;      
*                                      
*---  FLUX EQUIVALENTS A LA CONVECTION:         
*                                           
FF1 = CONVECTION MOD2 MAT2 T 125. ;        
*  
*---  ASSEMBLAGE DES PREMIER ET SECOND MEMBRES:      
*                                                
CONTOT = COND1 ET COND2 ET CL1 ;                  
FLUTOT = DCL1 ET FF1 ;       
*                                        
*---  RESOLUTION:                          
*                                    
CHTER1 = RESOUDRE CONTOT FLUTOT ;   
*
*--- POST TRAITEMENT
*
TITRE 'CHAMP DE TEMPERATURES' ;
TRAC CHTER1 SURF1 ;
*                                                 
TETA3 = EXTR CHTER1 T P3 ; 
TTHP3 = 122.68 ;
MESS 'TEMPERATURE THEORIQUE EN P2 :'TTHP3 ;
MESS 'TEMPERATURE CALCULEE EN P2 :'TETA3 ;
*
*--- FIN DU FICHIER 
FIN ;