Fichier Gibiane

OPTI DIME 2 ELEM QUA4 ;
*
* Variables globales
*
* LX0 : Dimension suivant x
* LY0 : Dimension suivant y
* XMIN,YMIN : Coordonnées du coin inférieur
* NX0 : Nombre de points suivant x
* NY0 : Nombre de points suivant y
*
R0 = 1.D0 ; LX0  = 6.D0 * R0 ; LY0 = 5.D0 * R0 ;
XMIN = LX0 / 2.D0 * -1.D0 ; YMIN = 0.D0 ;
XMAX = LX0 / 2.D0 ; YMAX = LY0 ;
NX1 = 4 ; NX2 = 6 ; NX3 = NX1 + NX1 + NX2 ; NY0 = 5 ;
*
* Création des points
P1 = XMIN YMIN ;
P2 = (R0 * -1.) YMIN ;
P3 = 0.D0 R0   ;
P4 = R0   YMIN ;
P5 = XMAX YMIN ;
P6 = XMAX YMAX ;
P7 = XMIN YMAX ;
*
* Création des droites
P1P2 = P1 DROI NX1 P2 ;
P2P4 = CER3 NX2 P2 P3 P4  ;
P4P5 = P4 DROI NX1 P5 ;
P5P6 = P5 DROI NY0 P6 ;
P6P7 = P6 DROI NX3 P7 ;
P7P1 = P7 DROI NY0 P1 ;
*
* Création du maillage
SURF0 = DALL (P1P2 ET P2P4 ET P4P5) P5P6 P6P7 P7P1 ;
CONT0 = CONT SURF0 ;
*
* Création du modèle NAVIER-STOKES
DISCR = 'LINE' ;
SURF1 = CHAN SURF0 QUAF ;
MOD1  = MODE SURF1 'NAVIER_STOKES' DISCR ;
*
* Tracé du maillage CENTRE
RES1 = DOMA MOD1 'CENTRE' ;
TRAC RES1 ;
*
* Manipulation d'un CHAMPOIN à deux composantes
* qui pourrait être un champ de vitesse
MAIL0 = DOMA MOD1 'MAILLAGE' ;
X0 Y0 = COOR MAIL0 ;
UX0 = NOMC 'UX' (-1. * Y0) ;
UY0 = NOMC 'UY' X0 ;
V0  = UX0 ET UY0 ;
VECT1 = VECT 0.5 V0 'UX' 'UY' ;
TRAC VECT1 MAIL0 'TITR' 'Vitesse' ;
*
* Projection CENTRE-SOMMET de la norme de la vitesse
MOT1 = 'MOTS' 'UX' 'UY' ;
NORM0 = ('PSCA' V0 V0 MOT1 MOT1) '**' 0.5 ;
NORM0 = 'KCHT' MOD1 'SCAL' 'SOMMET' NORM0 ;
NC0 = 'NOEL' MOD1 NORM0 ;
NS0 = 'ELNO' MOD1 NC0 ;
DIFF1 = NORM0 '-' NS0 / NORM0 ;
'TRAC' NORM0 MAIL0 CONT0 'TITR' 'Norme de la vitesse' ;
'TRAC' DIFF1 MAIL0 
       'TITR' 'Erreur relative : r et ELNO(NOEL(r))' ;
*
* Sauvegarde sur disk
OPTI SAUV 'tp2.sauv' ;
SAUV ;
*
* ARRET
*FIN ;

Figure 4: Maillage et points CENTRE

Figure 5: Vitesse et sa norme

Figure 6: Erreur relative entre r et ELNO(NOEL(r))