C TIMRIG    SOURCE    CHAT      05/01/13    03:40:51     5004
      SUBROUTINE TIMRIG(REL,LRE,CARAC,COORD,WORK,KERRE)
C-----------------------------------------------------------------------
C  ROUTINE DE CALCUL DE LA MATRICE DE RAIDEUR ELEMENTAIRE DE L ELEMENT D
C  POUTRE DE TIMOSCHENKO DANS LES AXES GLOBAUX
C
C  ENTREE
C          LRE     DIMENSION DU TABLEAU REL
C          CARAC   TABLEAU DE CARACTERISTIQUES GEOMETRIQUES ET
C                  MATERIELLES DE LA POUTRE  ( 11 VALEURS )
C          COORD   COORDONNEES DES 2 NOEUDS
C
C  SORTIE
C          REL     MATRICE DE RIGIDITE ELEMENTAIRE
C          KERRE   CODE D ERREUR  NON NUL SI PROBLEME , NUL SINON
C  TRAVAIL
C          WORK(300)
C
C     CLONE DE POURIG PP 3/9/92
C-----------------------------------------------------------------------
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION REL(LRE,*),CARAC(*),COORD(3,*),VECT(3),P(3,3),
     .          XE(2),YE(2),ZE(2),WORK(*)
C
      KERRE=0
      XINX=CARAC(1)
      XINY=CARAC(2)
      XINZ=CARAC(3)
      SD=CARAC(4)
      SREDY=CARAC(5)
      SREDZ=CARAC(6)
      DO 1 I=1,3
1     VECT(I)=CARAC(6+I)
      YOUN=CARAC(10)
      CISAIL=CARAC(11)
      DO 2 I=1,2
      XE(I)=COORD(1,I)
      YE(I)=COORD(2,I)
  2   ZE(I)=COORD(3,I)
      XL=(XE(2)-XE(1))**2+(YE(2)-YE(1))**2+(ZE(2)-ZE(1))**2
      XL=SQRT(XL)
      IF(XL.EQ.0.) GO TO 999
C
C  CALCUL DE LA RIGIDITE EN AXES LOCAUX
C
      CALL TIRILO(WORK,XL,YOUN,CISAIL,SD,SREDY,SREDZ,XINX,XINY,XINZ)
C
C  CALCUL DE LA MATRICE DE PASSAGE
C
      CALL POUPAS(XE,YE,ZE,VECT,P,KERRE)
      IF(KERRE.NE.0) RETURN
C
C  PASSAGE DE LA MATRICE DE RIGIDITE EN AXES GLOBAUX
C
      CALL POUROT(REL,LRE,P,WORK)
      RETURN
999   KERRE=1
      RETURN
      END