C TIMALO    SOURCE    CB215821  26/08/24    21:18:38     12622          
      SUBROUTINE TIMALO(RP,XL,RHO,SD,XINX,XINY,XINZ)
C-----------------------------------------------------------------------
C
C    ROUTINE DE CALCUL DE LA MATRICE DE MASSE ELEMENTAIRE D UNE
C    POUTRE DROITE EN AXES LOCAUX
C    D APRES TEDEL
C    DANS CETTE VERSION,ON PREND EN COMPTE LES INERTIES DE ROTATION
C    MAIS PAS LA DEFORMABILITE A L EFFORT TRANCHANT
C
C  ENTREE
C    XL      LONGUEUR
C    SD      SECTION DROITE
C    XINX    INERTIE IX
C    XINY    INERTIE IY
C    XINZ    INERTIE IZ
C    RHO     MASSE VOLUMIQUE
C  SORTIE
C    RP      MATRICE DE MASSE ELEMENTAIRE 12X12
C
C    PP 8/9/92
C
C-----------------------------------------------------------------------
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION RP(12,12)
C
C  INITIALISATIONS
C
      DO 121 J=1,12
        DO 120 I=1,12
          RP(I,J)=0.D00
  120   CONTINUE
  121 CONTINUE
C
      RHOSL=RHO*SD*XL
      RSP1= RHO*SD*  XL*0.333333333333333333
      RSP2= RHO*SD*  XL*0.166666666666666666
      TOR1= RHO*XINX*XL*0.333333333333333333
      TOR2= RHO*XINX*XL*0.166666666666666666
      FLY1= RHO*XINY*XL*0.333333333333333333
      FLY2= RHO*XINY*XL*0.166666666666666666
      FLZ1= RHO*XINZ*XL*0.333333333333333333
      FLZ2= RHO*XINZ*XL*0.166666666666666666
C
C  REMPLISSAGE DE LA MATRICE
C  FX1
      RP(1,1)=RSP1
      RP(1,7)=RSP2
C  FY1
      RP(2,2)=RSP1
      RP(2,8)=RSP2
C  FZ1
      RP(3,3)=RSP1
      RP(3,9)=RSP2
C  MX1
      RP(4,4)= TOR1
      RP(4,10)= TOR2
C  MY1
      RP(5,5)=FLY1
      RP(5,11)=FLY2
C  MZ1
      RP(6,6)=FLZ1
      RP(6,12)=FLZ2
C  FX2
      RP(7,7)=RSP1
C  FY2
      RP(8,8)=RSP1
C  FZ2
      RP(9,9)=RSP1
C  MX2
      RP(10,10)=TOR1
C  MY2
      RP(11,11)=FLY1
C  MZ2
      RP(12,12)=FLZ1
C
      DO 122 I=1,12
        DO 9 J=I,12
          RP(J,I)= RP(I,J)
    9   CONTINUE
  122 CONTINUE
      RETURN
      END