************************************************************************
*  Cas test :  test_repr_modl_ther.dgibi
*  --------
*
*  Categorie : Verification en cas de changement de modele
*  ---------
*
*  Description :
*  -----------
*  plaque 2D sur laquelle on applique 2 ou 3 modeles selon etapes
*    1- Diffusion de la chaleur
*    2- Source de chaleur
*    3a- Pas de convection a etapes 1 et 3
*    3b- Convection avec exterieur a etape 2
*
************************************************************************
 
GRAPH = FAUX ;

'OPTI' 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' ;
'OPTION' 'ECHO' 0 ;
 
*************** Geometrie *************************************************
P1  =  0.     0.    ;
P2  =  5.e-3  0.    ;
P3  =  5.e-3 10.e-3 ;
P4  =  0.    10.e-3 ;
 
n   = 20 ;
L23 = P2 'DROI' n  P3 ;
L14 = P1 'DROI' n  P4 ;
 
n   = 10 ;
su1 = L14 'REGL' n L23 ;
 
L_BAS = ('COTE' 4 su1) 'COUL' 'BLEU' ;
mpoi1 ='POIN' su1 'DROI' P1 P2 1.D-10 ;
S_BAS = ('ELEM' su1 'APPU' 'LARG' MPOI1) 'COUL' 'VERT' ;

L_HAU = ('COTE' 2 su1) 'COUL' 'ORANGE' ;
mpoi1 = 'POIN' su1 'DROI' P3 P4 1.D-10 ;
S_HAU = ('ELEM' su1 'APPU' 'LARG' MPOI1) 'COUL' 'ROUG' ;

**************** Modeles et caracteristiques ***********************************
modthe ='MODE' su1   'THERMIQUE' 'CONDUCTION' 'CONS' 'CON1' ;
moconv ='MODE' L_HAU 'THERMIQUE' 'CONVECTION' 'CONS' 'COV1' ;
 
rho1   = 4500.    ; cp1    = 900.     ;
 
matthe = 'MATE' modthe 'C'  cp1   'K' 10. 'RHO' rho1 ;
maconv = 'MATE' moconv 'H   ' 150. ;
 
*************** Pas de temps ***************************************************
listt1 = prog 0. 'PAS' 10. 1000. ;
listt2 = prog (1000.+20.) 'PAS' 20. 3000. ;
listt3 = prog (3000.+10.) 'PAS' 10. 4000. ;
 
T_ini = 'MANU' 'CHPO' su1 1 'T'  0. 'NATURE' 'DIFFUS' ;
'SI' GRAPH ;
  'TRAC' su1 T_ini 'TITR' 'Temperature initiale' ;
'FINS';

T_air = 25. ;
EvTECO = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 1.E+9)
                       'T'     ('PROG' 1. 1.)  ;
ChpTECO  = 'MANU' 'CHPO' L_HAU 1 'T' T_air      ;
CharTECO = 'CHARGEMENT' 'TECO' ChpTECO EvTECO  ;
 
* CHARGEMENT
srcth1  = 'SOURCE' ('REDU' modthe s_bas) s_bas 1.D7 ;
EvS    = EVOL MANU 'TEMP' (PROG 0. 1.E+9) 'Q   ' (PROG 1. 1.) ;
charths ='CHAR' 'Q'  srcth1 EvS ;
 
ltps = 'PROG'0. ; lT1 = 'PROG' 0. ; lT3 = 'PROG' 0. ;

* ETAPE 1 : On chauffe la piece fermee (adiabatiquement)
xtab                       = TABL    ;
xtab.'MODELE'              = modthe  ;
xtab.'CARACTERISTIQUES'    = matthe  ;
xtab.'CHARGEMENT'          = charths  ;
xtab.'TEMPS_CALCULES'      = listt1  ;
 
xtab.'TEMPERATURES'        = table   ;
xtab.'TEMPERATURES' . 0    = T_ini   ;

xtab.'PROCESSEURS'         = 'MOT' 'MONO_PROCESSEUR' ;

PASAPAS xtab ;

* Post-traitement fin etape 1
II = ('DIMENSION' xtab.'TEMPS') - 1 ;
ltps = ltps 'ET' xtab.'TEMPS'. II ;
chp_T = 'EXCO' 'T   ' xtab.'TEMPERATURES'. II 'T   ' ;
lT1 = lT1 'ET' ('EXTR' chp_T 'T' P1) ;
lT3 = lT3 'ET' ('EXTR' chp_T 'T' P3) ;
 
* ETAPE 2 : On chauffe la piece qui a une fenetre ouverte (convection avec exterieure)

xtab.'MODELE'              = modthe 'ET' moconv  ;
xtab.'CARACTERISTIQUES'    = matthe 'ET' maconv ;
xtab.'CHARGEMENT'          = charths 'ET' charteco ;
xtab.'TEMPS_CALCULES'      = listt2 ;

PASAPAS xtab ;

* Post-traitement fin etape 2
II = ('DIMENSION' xtab.'TEMPS') - 1 ;
ltps = ltps 'ET' xtab.'TEMPS'. II ;
chp_T = 'EXCO' 'T   ' xtab.'TEMPERATURES'. II 'T   ' ;
lT1 = lT1 'ET' ('EXTR' chp_T 'T' P1) ;
lT3 = lT3 'ET' ('EXTR' chp_T 'T' P3) ;
 
* ETAPE 3 : On chauffe a nouveau la piece fermee (adiabatiquement)

xtab.'MODELE'              = modthe ;
xtab.'CARACTERISTIQUES'    = matthe ;
xtab.'CHARGEMENT'          = charths ;
xtab.'TEMPS_CALCULES'      = listt3 ;

PASAPAS xtab ;

* Post-traitement fin etape 3
II = ('DIMENSION' xtab.'TEMPS') - 1 ;
ltps = ltps 'ET' xtab.'TEMPS'. II ;
chp_T = 'EXCO' 'T   ' xtab.'TEMPERATURES'. II 'T   ' ;
lT1 = lT1 'ET' ('EXTR' chp_T 'T' P1) ;
lT3 = lT3 'ET' ('EXTR' chp_T 'T' P3) ;
 
* POST-TRAITEMENT FINAL
*'OPTI' 'EPTR' 10 ;

'SI' GRAPH ;
  ev_p1 = EVOL 'ROUG' 'TEMP' xtab 'TEMPERATURES' 'T' P1 ;
  ev_p3 = EVOL 'VERT' 'TEMP' xtab 'TEMPERATURES' 'T' P3 ;
  dess (ev_p1 et ev_p3) ;
'FINSI' ;

lister ltps ; lister lT1 ; lister lT3 ;

err = 'MAXIMUM' (lT3 '-' ('PROG' 0. 122.626 58.399 183.524)) 'ABS' ;
list err ;
'SI' ('>EG' err 1.E-3) ;
  'MESS' ;
  'MESS' 'ERREUR : Temperature(s) au point 3 erronee(s)' ;
  'ERREUR' 5 ;
'FINSI' ;

'FIN';