* fichier :  test_contact.dgibi
************************************************************************
* Section : Mecanique Contact
************************************************************************
*
* Verifier la creation d'un modele de contact et l'ecriture des
* conditions cinematiques pour les elements lineaires et quadratiques en
* 2D et 3D, avec des objets geometries constitues d'un seul ou de
* plusieurs types d'elements.
*
*----------------------------------------------------------------------
*
*   CREATION DES MODELES DE CONTACT ET DES CONDITIONS CINEMATIQUES
*
* Entrees :
* ---------
* MA1 : Maillage de l'une des lignes/surfaces de contact
* MA2 : Maillage de l'une des lignes/surfaces de contact
* LM1 : Liste des types d'elements consitutant MA1 et MA2
* LM2 : Liste des formulations de contact
* bt  : Logique pour effectuer ou non des traces
*----------------------------------------------------------------------
'DEBP' MODECON MA1*'MAILLAGE' MA2*'MAILLAGE' 
               LM1*'LISTMOTS' LM2*'LISTMOTS' bt*'LOGIQUE' ;
*
  DELEM = ('DIME' LM1) '+' 1 ;
  'REPE' B1 DELEM ;
* 
    'SI' ('NEG' &B1 DELEM) ;
      ELMZ = 'EXTR' LM1 &B1 ;
      M1 = MA1 'ELEM' ELMZ ;
      M2 = MA2 'ELEM' ELMZ ;
      'SI' ('NEG' &B1 1) ;
        ELMT = 'CHAI' ELMT ' ET' ' ' ELMZ ;
      'SINON';
        ELMT = 'CHAI' ELMZ ;
      'FINSI';
    'SINON' ;
      ELMZ = ELMT ;
      M1 = MA1;
      M2 = MA2 ;
    'FINSI' ;
*
    MES0 = 'CHAI' 'ELEMENT='ELMZ ;
    'REPE' B2 ('DIME' LM2) ;
      FORZ = 'EXTR' LM2 &B2 ;
      MOC  = 'MODE' M1 'CONTACT' M2 FORZ ;
*
      MESZ = 'CHAI' MES0 ' FORMULATION='FORZ;
      MESS ' ' ; MESS MESZ ;
**    LIST MOC ;
*
      RCF CHJ = RFCO MOC VRAI ;
*
      'SI' bt ;
        MLX  = 'EXTR' RCF 'MAIL' 'MULT' ;
        CHL  = 'MANU' 'CHPO' MLX 1 'LX' -1. ;
        CHR  = CHL * RCF ;
        VEC  = 'VECT' CHR 'FORCES' 'TURQ' ;
        TITZ = 'CHAI' MESZ ' REACTIONS DE CONTACT' ;
        TRAC (M1 'ET' (M2 'COUL' 'ROUG')) VEC 'TITR' TITZ ;
      'FINSI' ;
*
    'FIN' B2 ;
  'FIN' B1 ;
'FINP' ;
*----------------------------------------------------------------------
* OPTIONS GENERALES
*----------------------------------------------------------------------
ITRAC = FAUX ;
LFORM = 'MOTS' 'MESC' 'SYME' 'FAIB' ;
XL1 = 2.0D0 ;
XL2 = 2.5D0 ;
XL3 = 3.0D0 ;
*----------------------------------------------------------------------
* DIMENSION 2
*----------------------------------------------------------------------
'OPTI' 'DIME' 2 ;
*
P1 = 0. 0. ;
P2 = P1 'PLUS' (XL1 0.) ;
P3 = P2 'PLUS' (XL1 0.) ;
P4 = -1. 0.1 ;
P5 = P4 'PLUS' (XL2 0.) ;
P6 = P5 'PLUS' (XL2 0.) ;
*
'OPTI' 'ELEM' 'SEG2' ;
L1A = 'DROI' 3 P2 P1 ;
L2A = 'DROI' 3 P4 P5 ;
'OPTI' 'ELEM' 'SEG3' ;
L1B = 'DROI' 3 P3 P2 ;
L2B = 'DROI' 3 P5 P6 ;
*
L1T = L1A 'ET' L1B ;
L2T = L2A 'ET' L2B ;
*
'SI' ITRAC ;
  TIT0 = 'CHAI' 'LIGNES DE CONTACT ET ORIENTATION LIGNE INFERIEURE';
  TRAC (L1T 'ET' (L2T 'COUL' 'ROUG')) (@VISOR L1T) 'TITR' TIT0 ;
  TIT0 = 'CHAI' 'LIGNES DE CONTACT ET ORIENTATION LIGNE SUPERIEURE';
  TRAC (L1T 'ET' (L2T 'COUL' 'ROUG')) (@VISOR L2T) 'TITR' TIT0 ;
'FINSI' ;
*
MODECON L1T L2T (L1T 'ELEM' 'TYPE') LFORM ITRAC ;
*----------------------------------------------------------------------
* DIMENSION 3
*----------------------------------------------------------------------
'OPTI' 'DIME' 3 ;
*
LELM1 = 'MOTS' 'TRI3' 'TRI3' 'TRI3' 'QUA4' 'QUA4' 'TRI6';
LELM2 = 'MOTS' 'QUA4' 'TRI6' 'QUA8' 'TRI6' 'QUA8' 'QUA8';
DELMT = 'DIME' LELM1 ;
*
P1 = 0. 0. 0.;
P2 = P1 'PLUS' (XL1 0. 0.) ;
P3 = P2 'PLUS' (XL1 0. 0.) ;
P4 = -1. 0. 0.1 ;
P5 = P4 'PLUS' (XL2 0. 0.) ;
P6 = P5 'PLUS' (XL2 0. 0.) ;
*
'REPE' BC0 DELMT ;
*
  'OPTI' 'ELEM' ('EXTR' LELM1 &BC0) ;
  L1A = 'DROI' 3 P2 P1 ;
  S1A = L1A 'TRAN' 2 (0. XL3 0.) ;
  L2A = 'DROI' 3 P4 P5 ;
  S2A = L2A 'TRAN' 3 (0. XL3 0.) ;
*
  'OPTI' 'ELEM' ('EXTR' LELM2 &BC0) ;
  L1B = 'DROI' 3 P3 P2 ;
  S1B = L1B 'TRAN' 2 (0. XL3 0.) ;
  L2B = 'DROI' 3 P5 P6 ;
  S2B = L2B 'TRAN' 3 (0. XL3 0.) ;
*
  S1T = 'INVE' (S1A 'ET' S1B) ;
  S2T = 'INVE' (S2A 'ET' S2B) ;
  'ELIM' S1T 1.E-9 ;
  'ELIM' S2T 1.E-9 ;
*
  'SI' ITRAC ;
    TIT0 = 'CHAI' 'SURFACES DE CONTACT ET ORIENTATION SURFACE INFERIEURE';
    TRAC (S1T 'ET' (S2T 'COUL' 'ROUG')) (@VISOR S1T) 'TITR' TIT0 ;
    TIT0 = 'CHAI' 'SURFACES DE CONTACT ET ORIENTATION SURFACE SUPERIEURE';
    TRAC (S1T 'ET' (S2T 'COUL' 'ROUG')) (@VISOR S2T) 'TITR' TIT0 ;
  'FINSI' ;
*
  MODECON S1T S2T (S1T 'ELEM' 'TYPE') LFORM ITRAC ;
*
'FIN' BC0 ;
*
'FIN' ;