* fichier : tasse.dgibi
************************************************************************
* Section : Entree-Sortie Entree-Sortie
* Section : Maillage Autres
************************************************************************

*******************************************************
*           Test tasse.dgibi: Jeux de données         *
*           ---------------------------------         *
*******************************************************
* Presentation : Ce cas-test de verification permet de 
*                lire un fichier au format 'STL' 
*                representant une tasse avec le logo 
*                Cast3M dessus.
*               
* Creation : 03/12/2020
* Createur : F. DI PAOLA
*******************************************************

* Le fichier tasse.stl est en binaire "little-endian" et 
* n'est pas lisible sous IBM-RS6000
* Cette limitation du format STL n'est pas portable
* Le cas-test est commente
  FIN;

* repertoire des fichiers "divers"
DIVERS = VENV 'CASTEM_DIVERS';
*
'OPTI' 'TRAC' 'PSC' ;
 tasse ='LIRE' 'STL' ('CHAINE' DIVERS '/tasse.stl') ;
'ELIM' tasse 1.E-10 ;
 atasse = ARET tasse ;

 COMPLET=FAUX;
 
 TASSE2='VIDE' 'MAILLAGE';
 TAB1  ='PART' tasse 'SEPA' atasse 'MAIL' ;
 DIM1  ='DIME' TAB1 - 2;
'REPE' SURi DIM1;
   
  'SI' ((&SURi '>EG' 66) 'ET' (&SURi '<EG' 72));
     TAB1. &SURi='COUL' TAB1. &SURi 'ROUG' ;
  'SINO';
     TAB1. &SURi='COUL' TAB1. &SURi 'GRIS' ;
  'FINS';
   TASSE2=TASSE2 'ET' TAB1. &SURi;
   
  'SI' COMPLET;
     TIT1='CHAI' 'PARTIE NUMERO:' &SURi ;
    'TRAC' 'FACE' TAB1. &SURi 'TITR' TIT1 'ARET' atasse;
  'FINS';
'FIN'  SURi;

'TRAC' 'FACE' TASSE2 'ARET' atasse (1136.6     1975.3     797.37);
'TRAC' 'FACE' TASSE2 'ARET' atasse (516.51    -2216.1     837.11);

 FIN ;