C POUGR2    SOURCE    CB215821  26/10/26    21:15:53     12682          
      SUBROUTINE POUGR2(COORD,DEPLA,CARAC,GRAD,WORK)
C-----------------------------------------------------------------------
C  ROUTINE DE CALCUL DES GRADIENTS POUR LA POUTRE DROITE EN 2D
C
C  ENTREE
C          DEPLA   DEPLACEMENTS
C          CARAC   TABLEAU DE CARACTERISTIQUES GEOMETRIQUES ET
C                  MATERIELLES DE LA POUTRE  ( 11 VALEURS )
C          COORD   COORDONNEES DES 2 NOEUDS
C
C  SORTIE
C          GRAD    GRADIENTS AUX 2 NOEUDS    3 PAR NOEUD
C  TRAVAIL
C          WORK(300)
C-----------------------------------------------------------------------
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION WORK(*)
      DIMENSION GRAD(*),CARAC(*),COORD(3,*),P(2,2),
     .          XE(2),YE(2),DEPLA(*)
C
      DO 2 I=1,2
      XE(I)=COORD(1,I)
      YE(I)=COORD(2,I)
  2   CONTINUE
      XL=(XE(2)-XE(1))**2+(YE(2)-YE(1))**2
      XL=SQRT(XL)
C
C  CALCUL DE LA MATRICE DE PASSAGE
C
      CALL POUPA2(XE,YE,P,KERRE)
C
C  PASSAGE DES DEPLACEMENTS EN AXES LOCAUX
C
      CALL POUVE2(DEPLA,WORK,P,1)
C
C  CALCUL DES GRADIENTS AUX 2 NOEUDS
C
      GRAD(1)=(WORK(4)-WORK(1))/XL
      GRAD(3)=GRAD(1)
      GRAD(2)=WORK(3)
      GRAD(4)=WORK(6)
      RETURN
      END