* fichier :  plas_incomp.dgibi
************************************************************************
* Section : Mecanique Plastique
************************************************************************
SAUT PAGE;                                                                      
************************************************************************        
*     CUBE EN TRACTION UNIAXIALE                                                
*     Plastique parfait
*     verification de l'incompressibilite de l'ecoulement plastique
*
*                                                                               
optio elem cub8;

SAUT PAGE;                                                                      
TITRE 'CUBE EN TRACTION UNIAXIALE';                                             
OPTION DIME 3 ;

graph = 'N';

TEMPS ;                                                                         
DENS 1;                                                                         
*-----------------------------------------------------------------------        
***** DEFINITION DE LA GEOMETRIE                                                
*-----------------------------------------------------------------------        

p1 = 0 0 0; p2 = 0 1 0; l1 = p1 d 1 p2; s1 = l1 tran 1 (0 0 1);
s2 = s1 plus (1 0 0);   v1 = volu  1 s1 s2;
en = enve v1; 
e1 = en elem 1; e2 = en elem 2; e3 = en elem 3; e4 = en elem 4; e5 = en elem 5; e6 = en elem 6;

bl1 = bloq ux s1; bl2 = bloq ux s2;
bl3 = bloq uy uz p1; bl4 = bloq uz p2;
bl5 = bloq uz (e2 et e5);
blt = bl1 et bl2 et bl3 et bl4 et bl5;


*-----------------------------------------------------------------------        
* VALEURS IMPOSEES DES DEPLACEMENTS                                             
*-----------------------------------------------------------------------        
di = depi bl1 -1 ;
*-----------------------------------------------------------------------        
***** CALCUL MODELE
*-----------------------------------------------------------------------        
MO = MODE V1  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' CUB8;
MAT1 = MATE MO YOUN 2.5E11 SIGY 5.0E6 NU .499  ;

                                                
*-----------------------------------------------------------------------        
***** CHAMPS RELATIFS A L'OPERATEUR PASAPAS                                     
*-----------------------------------------------------------------------        
LP1 = PROG 0. 20.;
LP2 = PROG 0. 20.;
EV = EVOL MANU T LP1 F(T) LP2;  
CHA1 = CHAR 'DIMP' Di EV;
LIS1 = PROG 0. PAS 1d-1 2                                    ;
*-----------------------------------------------------------------------        
*****  CALCUL NON LINEAIRE                                                      
*-----------------------------------------------------------------------        
TAB1 = TABLE;
TAB1.'BLOCAGES_MECANIQUES' = blt;
TAB1.'CARACTERISTIQUES' = MAT1;
TAB1.'TEMPS_CALCULES' = LIS1;
TAB1.'MODELE' = MO;
TAB1.'CHARGEMENT' = CHA1;                                                                                
TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
TAB1.'SOUS_INCREMENT' = 1 ;
*TAB1.'LAGRANGIEN' = 'MOT' 'FIN_PAS';
TAB1.'LAGRANGIEN' = 'MOT' 'REACTUALISE';
TAB1.'PRECISION' = 1d-9 ;
PASAPAS TAB1;

form tab1.wtable.for0;
repete bou (dime  tab1.deplacements - 2)  ;
dd = tab1.deplacements.&bou;
form dd;
mes = mesu volu v1;
list mes;
form tab1.wtable.for0;
fin bou;

list (mes - 1);
si (abs (mes - 1) > 1d-7) ; erreur 5; finsi;
fin;