* fichier : meric2.dgibi
* section : Mecanique Viscoplastique
*----------------------------------------------------------------------*
*                        M E R I C 2 . D G I B I                       *
*----------------------------------------------------------------------*
*
* Objet :
* -------
*
* Exemple d'utilisation et test de validation de la loi de comportement
* MERIC_CAILLETAUD.
*
* Exemple derivé de chaboche1.dgibi.
*
*
* Description :
* -------------
* Essai de traction-compression.
*
* Type de calcul : Mecanique
* Mode de calcul : 3D
* Type d'element : CUB8
* Chargement     : Deplacement impose
* Reference      : solution comparee a la loi de Chaboche
* Objectif       : Ecart relatif sur la contrainte SMYY < 5.e-3
*
* Remarque : La loi de Chaboche n'est pas strictement identique a la
* ---------- loi cristalline de Meric_Cailletaud. Les parametres sont
*            ajustes pour que les 2 solutions soient tres proches.
*
*----------------------------------------------------------------------*

* Pour afficher les traces, mettre IGRAPH a vrai :
IGRAPH = faux ;

*opti trac psc ;

*------------------------ Maillage (1 element) ------------------------*

opti dime 3 elem CUB8 ;

ne1 = 1 ;
l1  = (0 0 0) droi ne1 (1 0 0) ;
S1  = l1 tran ne1 (0 1 0) ; 
V1  = S1 volu tran ne1 (0 0 1) ;

S2  = V1 face 2 ;
p1  = V1 poin proc (0 0 1) ;
px0 = (V1 coor 1) poin mini ;
py0 = (V1 coor 2) poin mini ;

si IGRAPH ;
  trac qual V1 titr ' Maillage ' ;
fins ;
*
*---------------------- Modele & Carateristiques ----------------------*
*
* Par rapport aux parametres du modele presentes dans le L&M, p. 310 :
*   - CLM : coefficient C d'ecrouissage cinematique du L&M
*   - Gam : coefficient gamma d'ecrouissage cinematique du L&M
* les coefficients d'ecrouissage du modele de Cast3M sont :
*   - C = Gam
*   - A = CLM / Gam
* Valeurs des parametres du modele pour acier 316L a 20 degC (L&M, p. 319) :
SIGY1 = 82.e6 ;
N1    = 24. ;
K1    = 151.e6 ;
CLM   = 162400.e6 ;
Gam   = 2800. ;
A1    = CLM / Gam ;
C1    = Gam   ;
Q1    = 142.e6 - SIGY1 ;
B1    = 8. ;

* Valeurs parametres modele Meric_Cailletaud pour avoir une solution
* proche de la loi de Chaboche :
TAU0  = 0.5 * SIGY1 ;
K0    = 0.5 * K1 / (3. ** (1. / N1)) ;
C0    = 0.5 * C1 ;
Q0    = 0.5 * Q1 ;

* Module d'Young et coeff. de Poisson :
YM1   = 200.e9 ;
NU1   = 0.3 ;

* Modeles & Caracteristiques :
mo1 = 'MODE' V1  'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE'  'MERIC_CAILLETAUD' 'BBAR' ;
ma1 = 'MATE' mo1 'YOUN' YM1 'NU' NU1 'TAU0' TAU0 'NX' 1 'NY' 0 'NZ' 1 'BX' -1 'BY' 0 'BZ' 1 
                 'K'    K0  'N'  N1  'A'    A1   'C'    C0 'B' B1 'Q' Q0 ;

mo2 = 'MODE' V1  'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE'  'CHABOCHE' 'BBAR' ;
ma2 = 'MATE' mo2 'YOUN' YM1 'NU' NU1 'SIGY' SIGY1 
                 'K'    K1  'N'  N1  'A'    A1    'C'    C1 'B' B1 'Q' Q1 ;

*-------------------------- CL & Chargement ---------------------------*
*
cl1 = bloq uz S1 ;
cl2 = bloq ux px0 ;
cl3 = bloq uy py0 ;
cl4 = bloq uz s2 ;

u1  = 0.002 ;
f1  = depi cl4 u1 ;

xt1  = 100. ;
yt1  =  1. ;
ev1  = evol manu temp (xt1 * (prog 0. 1. 2.  3. 4. 6.))
                      (yt1 * (prog 0. 1. 0. -1. 0. 2.)) ;
cgu1 = char dimp f1 ev1 ;

si IGRAPH ;
  trac qual (V1 et (S1 coul roug) et (S2 coul vert) et ((px0 et py0) coul bleu))
    titr ' CL : Uz=0 en S1 (rouge), Ux=0 en x=y=0 (bleu) et Uz impose sur S2 (vert)' ;
  dess (u1*ev1) titre ' Evolution temporelle du deplacement impose ';
fins ;

*------------------------- Resolution PASAPAS -------------------------*
*
* Modele de Chaboche :
ta1 = tabl ;
ta1.modele = mo1 ;
ta1.caracteristiques = ma1 ;
ta1.blocages_mecaniques = cl1 et cl2 et cl3 et cl4 ;
ta1.chargement = cgu1 ;
ta1.temps_calcules = (prog 0. pas 0.1 6.) * xt1 ;

ta1.mes_sauvegardes = tabl ;
ta1.mes_sauvegardes.defto = vrai ;
ta1.mes_sauvegardes.defin = vrai ;

pasapas ta1 ;

* Modele Chaboche :
ta2 = tabl ;
ta2.modele = mo2 ;
ta2.caracteristiques = ma2 ;
ta2.blocages_mecaniques = cl1 et cl2 et cl3 et cl4 ;
ta2.chargement = cgu1 ;
ta2.temps_calcules = ta1.temps_calcules ;

ta2.mes_sauvegardes = tabl ;
ta2.mes_sauvegardes.defto = vrai ;
ta2.mes_sauvegardes.defin = vrai ;

pasapas ta2 ;

*-------------------- Postraitement des resultats ---------------------*

* Courbe force-deplacement, puis contrainte-deformation :
evuz1    = evol temp ta1 deplacements p1 uz ;
evfz1    = evol temp ta1 reactions p1 fz ;
evfu1    = evol roug manu lege 'Meric' 'MARQ' 'ROND' 'TAIL' 'S' '\e' (extr evuz1 ordo) '\s (MPa)' (extr evfz1 ordo) ;
evfu1    = evfu1 * 1.e-6 ; comm 'force => contrainte (MPa)' ;

evuz2    = evol temp ta2 deplacements p1 uz ;
evfz2    = evol temp ta2 reactions p1 fz ;
evfu2    = evol vert manu lege 'Chaboche' '\e' (extr evuz2 ordo) '\s (MPa)' (extr evfz2 ordo) ;
evfu2    = evfu2 * 1.e-6 ; comm 'force => contrainte (MPa)' ;

* Comparaison modeles Meric-Chaboche
si IGRAPH ;
  dess (evfu1 et evfu2) titr 'Comparaison Meric_Cailletaud / Chaboche' lege gril poin gris posy exce ;
fins ;

*------------------------- Test de validation -------------------------*
*
err0 = (intg (abs (evfz1 - evfz2))) / (maxi abs (extr evfz2 absc)) / (maxi abs (extr evfz2 ordo)) ;

opti echo 0 ;
saut 1 lign ;
mess '   Comparaison solutions Meric-Chaboche' ;
mess '   ------------------------------------' ;
mess '   Ecart relatif moyen contrainte =' err0 ;
saut 1 lign ;
opti echo 1 ;

si (err0 > 5.e-3) ;
  erre 5 ;
fins ;

fin ;