* fichier :  mazars.dgibi
************************************************************************
* Section : Mecanique Endommagement
* Section : Mecanique Plastique
************************************************************************
*******************************************************************
*                                                                 *
* TEST;  MATERIAU ENDOMMAGEMENT MAZARS                            *
*                                                                 *
* EPROUVETTE EN TRACTION AVEC DEPLACEMENTS IMPOSES                *
* CONTRAINTES PLANES, DEFO. LINEAIRES                             *
*                                                                 *
* LES RESULTATS OBTENUS SONT COMPARES  A LA SOLUTION ANALYTIQUE   *
*                                                                 *
*******************************************************************                                                       *

opti echo 0 dime 2 elem qua4 mode plan cont;

                                                                                                          
densite 1.;
p1=0. 0.;                                                               
p2=1. 0.;                                                               
p3=1. 1.;                                                               
p4=0. 1.;
d1=d p1 p2;d2=d p2 p3;d3=d p3 p4;d4=d p4 p1;                                                                         
surf1=daller d1 d2 d3 d4 plane;
at=1.e0;
ac=1.2e0;
bc=1.5e+03;
bt=10000.;
epsd0=1.e-04;
YG=31.E+9;
mod1=mode surf1 mecanique elastique isotrope endommagement mazars;    
mat1=MATE mod1  YOUN YG NU 0.2  RHO 2.3E+03 
 btra bt ktr0 epsd0 atra at acom ac bcom bc beta 1.06e0;
blo1=bloq  ux  p1;
blo2=bloq  uy  d1;
blo3=bloq  uy  d3;
cltot=blo1 et blo2 et blo3 ;                                     
fo1 = depi blo3 1. ;
evol1=evol manu temps (prog 0. 1. ) 
                depl (prog 0. 1 );
char1=charg evol1 fo1 DIMP;                                                  
lit1=prog  1.e-4 pas 25.e-6 5.e-4 ;
tab1=table;                                                             
tab1.mova='D   ';
tab1.blocages_mecaniques=cltot;
tab1.caracteristiques=mat1;
tab1.modele=mod1;
tab1. 'HYPOTHESE_DEFORMATIONS' = MOT 'LINEAIRE';
tab1.chargement=char1;
tab1.temps_calcules=lit1;
pasapas tab1;
*opti donn 5;                                                         
tab2=table;
tab2.1='MARQ CROI';                                  
ev1=@global tab1 blo3 evol1 fy  ;
*
*construction du resultat theorique
*
nb= dime  lit1;
UN=prog nb*1.d0;
LAT = prog nb * AT;
LEPS=prog nb*epsd0;
DT=UN - ( ( EPSD0* (UN-LAT) /lit1 ) + (AT * ( EXP (BT*(LEPS-lit1)))));
lsig0=(un - dt) * YG * lit1;
lsig1 = enle (extr ev1 ordo) 1;
*
*comparaison des deux resultats
*
err1=maxi (( lsig0 - lsig1) / lsig0);
temps;
si (err1 < 1.e-10);
  ERRE 0;
sinon ;
  ERRE 5;
finsi;
fin; ;