** Petit cas test pour visualiser le "trajet" des contraintes principales
*  afin de voir les lignes de transmission des efforts

** Application a une structure d'arche sous son poids




** Options generales
OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'TRI6' ;
itrac = FAUX ;

** Maillage de l'arche
OPTI 'DENS' 0.1 ;
p1 = 0. 0. ;
p2 = 0.3 0. ;
p3 = 0.3 4. ;
p4 = 3. 7. ;
p5 = 5.7 4. ;
p6 = 5.7 0. ;
p7 = 6. 0. ;
p8 = 6. 10. ;
p9 = 0. 10. ;
co = DROI p1 p2 DROI p3 CERC p5 p4 CERC p3 p5 DROI p6 DROI p7 DROI p8 DROI p9 DROI p1 ;
lb = (co ELEM 'COMPRIS' p1 p2) ET (co ELEM 'COMPRIS' p6 p7) ;
lh = co ELEM 'COMPRIS' p8 p9 ;
mail = SURF co ;

** Modele et materiau
mo = MODE mail 'MECANIQUE' ;
ma = MATE mo 'YOUN' 35.E9 'NU' 0.25 'RHO' 2500. ;

** Rigidite elastique
ri = RIGI mo ma ;

** Blocages et chargement
bl = BLOQ 'UX' 'UY' lb ;
rg = ((EXCO 'RHO' ma 'FX') * 0.) ET ((EXCO 'RHO' ma 'FY') * -9.81) ;
f  = CNEQ mo rg ;

** Resolution
u = RESO (ri ET bl) f ;

** Deformee
def  = DEFO mail u ;

** Contraintes principales
sig  = SIGM mo ma u ;
sip  = PRIN sig mo ;
sipn = CHAN 'CHPO' mo sip ;

** Contrainte principale 1 : plutot en traction
si11 = EXCO 'SI11' sip ;
* visualisation sous forme de vecteurs
s11v  = sipn * sipn (MOTS 'SI11' 'SI11') (MOTS 'COX1' 'COY1') (MOTS 'SIGX' 'SIGY') ;
s11vn = CHAN 'CHPO' mo (EXCO (MOTS 'SIGX' 'SIGY') s11v) ;
v1    = @VECOUL s11vn 1.E-6 (MOTS 'SIGX' 'SIGY') ;
defv  = DEFO mail u v1 ;
SI itrac ;
  TRAC defv co 'TITR' 'Vecteur contrainte principale SI11' ;
FINSI ;
* lignes de champ de la 1ere contrainte principale (en traction ici)
chv = EXCO (MOTS 'SIGX' 'SIGY') s11vn (MOTS 'UX' 'UY') ;
fc  = FCOURANT mail chv ;
* maillage des lignes d'isovaleurs
maxf = MAXI fc ;
minf = MINI fc ;
nlig = 16 ;
lf   = PROG minf 'PAS' ((maxf - minf) / (nlig + 1)) maxf ;
lig toto = @ISOSURF mail lf fc ;
* interpolation de la composante SI11 sur ces lignes
si11 = CHAN 'NOEUD' si11 mo ;
slig = PROI si11 lig ;
* trace
SI itrac ;
  TRAC fc mail co 'TITR' 'Fonction de courant de SI11' ;
  OPTI 'ISOV' 'LIGN' ;
  TRAC fc mail co nlig 'TITR' 'Isovaleurs de la fonction de courant de SI11' ;
  OPTI 'ISOV' 'SURF' ;
  TRAC slig lig co 'TITR' 'Lignes de champ SI11' ;
FINSI ;

** Contrainte principale 2 : plutot en compression
si22 = EXCO 'SI22' sip ;
* visualisation sous forme de vecteurs
s22v  = sipn * sipn (MOTS 'SI22' 'SI22') (MOTS 'COX2' 'COY2') (MOTS 'SIGX' 'SIGY') ;
s22vn = CHAN 'CHPO' mo (EXCO (MOTS 'SIGX' 'SIGY') s22v) ;
v1    = @VECOUL s22vn 3.E-7 (MOTS 'SIGX' 'SIGY') ;
** Deformee avec vecteur
defv = DEFO mail u v1 ;
SI itrac ;
  TRAC defv co 'TITR' 'Vecteur contrainte principale SI22' ;
FINSI ;

** Lignes de champ de la 2eme contrainte principale (celle de compression ici)
chv = EXCO (MOTS 'SIGX' 'SIGY') s22vn (MOTS 'UX' 'UY') ;
fc  = FCOURANT mail chv ;
* maillage des lignes d'isovaleurs
maxf = MAXI fc ;
minf = MINI fc ;
nlig = 16 ;
lf   = PROG minf 'PAS' ((maxf - minf) / (nlig + 1)) maxf ;
lig toto = @ISOSURF mail lf fc ;
* interpolation de la composante SI22 sur ces lignes
si22 = CHAN 'NOEUD' si22 mo ;
slig = PROI si22 lig ;
* trace
SI itrac ;
  TRAC fc mail co 'TITR' 'Fonction de courant de SI22' ;
  OPTI 'ISOV' 'LIGN' ;
  TRAC fc mail co nlig 'TITR' 'Isovaleurs de la fonction de courant de SI22' ;
  OPTI 'ISOV' 'SURF' ;
  TRAC slig lig co 'TITR' 'Lignes de champ SI22' ;
FINSI ;


FIN ;