************************************************************************
*                   Cas test de l'opérateur INSErer                    *
************************************************************************


** Petite procédure de test d'égalité de 2 listes a et b
DEBP TEST a b ;
REPE bou (DIME a) ;
  a1 = EXTR a &bou ;
  b1 = EXTR b &bou ;
  SI (NEG a1 b1) ;
    LIST a ;
    LIST b ;
    ERRE 5 ;
  FINSI ;
FIN bou ;
FINP ;


** Cas d'insertion d'un FLOTTANT dans un LISTREEL
obj0 = PROG 4. 8. 15. 16. 23. 42. ;
obj1 = PROG 4. 8. 15.     23. 42. ;
ind1 = 4 ;
obj2 = 16. ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;


** Cas d'insertion d'un ENTIER dans un LISTENTI
obj0 = LECT 4 8 15 16 23 42 ;
obj1 = LECT 4 8 15    23 42 ;
ind1 = 4 ;
obj2 = 16 ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;


** Cas d'insertion d'un MOT dans un LISTMOTS
obj0 = MOTS 'TATA' 'TETE' 'TITI' 'TOTO' 'TUTU' ;
obj1 = MOTS 'TATA' 'TETE' 'TITI'        'TUTU' ;
ind1 = 4 ;
obj2 = 'TOTO' ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;


** Cas d'insertion d'un CHPOINT dans un LISTCHPO
OPTI 'DIME' 1 ;
mail = (POIN 0.) ET (POIN 1.) ET (POIN 2.) ;
chp1 = MANU 'CHPO' mail 'TATA' 1. ;
chp2 = MANU 'CHPO' mail 'TETE' 2. ;
chp3 = MANU 'CHPO' mail 'TITI' 3. ;
chp4 = MANU 'CHPO' mail 'TOTO' 4. ;
chp5 = MANU 'CHPO' mail 'TUTU' 5. ;
obj0 = SUIT chp1 chp2 chp3 chp4 chp5 ;
obj1 = SUIT chp1 chp2 chp3      chp5 ;
ind1 = 4 ;
obj2 = chp4 ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;


** Cas d'insertion d'un OBJET dans un LISTOBJE
*  LISTOBJE contenant des LISTREEL
lis1 = PROG 1. 2. 3. ;
lis2 = PROG 4. 5. 6. ;
lis3 = PROG 7. 8. 9. ;
lis4 = PROG 8. 7. 6. ;
lis5 = PROG 4. 3. 2. ;
obj0 = ENUM lis1 lis2 lis3 lis4 lis5 ;
obj1 = ENUM lis1 lis2 lis3      lis5 ;
ind1 = 4 ;
obj2 = lis4 ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;
*  LISTOBJE contenant des FLOTTANT
obj0 = ENUM 4. 8. 15. 16. 23. 42. ;
obj1 = ENUM 4. 8. 15.     23. 42. ;
ind1 = 4 ;
obj2 = 16. ;
obj3 = INSE obj1 ind1 obj2 ;
TEST obj0 obj3 ;


FIN ;