C FONCRE    SOURCE    CB215821  25/04/08    21:15:16     12227          
C   SOURCE BERTHOLLET
C
      SUBROUTINE FONCRE(FLU,FI,TFLU,DUR,ELAS0,BETJEF,BETFLU)
C
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
-INC CCREEL
C
C*****************************************************************
C
      SEGMENT BETJEF
       REAL*8 AA,BETA,FC,ALPHA,EX,XNU,GFC,GFT,CAR,ETA,TDEF,
     &          TCON,DPSTF1,DPSTF2,TETA,PDT,TP00
       INTEGER ICT,ICC,IMOD,IVIS,ITER,
     &                ISIM,IBB,IGAU,IZON
      ENDSEGMENT
      SEGMENT BETFLU
       REAL*8 DATCOU,DATCUR,DATSEC,E28,PGTZO,PGDUR,TAU1,TAU2,
     &        TP0,TZER
       INTEGER ITYPE,IMD,NBRC,NCOE,NTZERO,NTPS,IFOR
      ENDSEGMENT
C
C MODELE B3 ET BP-KX
C*****************************************************************
C
      CIMENT = 266.D0
      EAU    = 161.D0
      AGREG  = 1615.D0
      SABLE  = 1133.D0
      RH     = 50.D0
C POUR LE CAS D UNE EPROUVETTE 16*32
      RAYON = 0.08D0
      HAUT  = 0.32D0
C U = PERIMETRE EN CONTACT AVEC L EXTERIEUR EN M
      U = 2.D0*XPI*RAYON
C
C AC = SURFACE EN CONTACT AVEC L ATMOSPHERE EN M2
      AC = XPI*(RAYON**2)
C
C VOL = VOLUME DE L ELEMENT CONSIDERE EN M3
      VOL = XPI*(RAYON**2)*HAUT
C
      SILICE = 40.3D0
      FINES  = 57.0D0
      ADJUV  = 9.98D0
C
C*****************************************************************
C    CHOIX DU MODELE DE FLUAGE
C*****************************************************************
C
      IF (ITYPE.LT.1.OR.ITYPE.GT.8) THEN
      WRITE(*,*)'MAUVAIS CHOIX DE FONCTION DE FLUAGE'
      GO TO 100
      ENDIF
C
C  1 / MODELE ACI209 :FLUAGE TOTAL
      IF (ITYPE.EQ.1) GO TO 10
C
C  2 / MODELE ESPION ET HALLEUX : FLUAGE TOTAL
      IF (ITYPE.EQ.2) GO TO 20
C
C  3 / MODELE B3 :FLUAGE PROPRE ET DE DESSICCATION
      IF (ITYPE.EQ.3) GO TO 30
C
C  4 / MODELE CEB FIP : BETON GENERAL
      IF (ITYPE.EQ.4) GO TO 40
C
C  5 / MODELE EUROCODE 2 : BETON GENERAL
      IF (ITYPE.EQ.5) GO TO 40
C
C  6 / MODELE BEPL91 : BHP
      IF (ITYPE.EQ.6) GO TO 40
C
C  7 / MODELE AFREM :BHP : FLUAGE PROPRE ET DE DESSICCATION
      IF (ITYPE.EQ.7) GO TO 50
C
C  8 / MODELE BP-KX :BETON ORDINAIRE
      IF (ITYPE.EQ.8) GO TO 60
C
C*****************************************************************
C     1 : MODELE ACI209
C*****************************************************************
C*****************************************************************
C
   10 E28=4734.D0*SQRT(FC)
      FLU = 1.D0/E28*SQRT((4.D0+0.85D0*TFLU)/TFLU)*
     *(1.D0+2.35D0*(TFLU**(-0.118D0))*(DUR**(0.6D0))/(10.D0+
     *(DUR**(0.6D0))))
      ELAS0 = E28*SQRT(TFLU/(4.D0+0.85D0*TFLU))
      TFLU = 0.D0
      DUR  = 0.D0
C
      FI = FLU*ELAS0-1.D0
      GO TO 100
C
C*****************************************************************
C     2 : MODELE ESPION ET HALLEUX
C*****************************************************************
C*****************************************************************
C
   20 FLU = 1.D0/26.D3*(1.D0+2.867D0*(TFLU**(-0.118D0))*
     *(DUR**(0.6D0))/(15.D0+(DUR**(0.6D0))))
C
      E28=4734.D0*SQRT(FC)
      ELAS0 = E28*SQRT(TFLU/(4.D0+0.85D0*TFLU))
      FI = FLU*ELAS0-1.D0
      GO TO 100
C
C*****************************************************************
C     3 : MODELE B3
C*****************************************************************
C*****************************************************************
C
C DATCUR = TEMPS DE CURE MINIMAL DU BETON
C DATSEC = AGE DE DEBUT DE SECHAGE DU BETON POUR LE TERME DE DESSICCATION
C
C VOL EN M3, AC EN M2, RH EN % (EX : RH = 50)
C
C
C
C VALIDITE DU MODELE
C*****************************************************************
C
C     LA COMPOSITION DE BETON EST REDUITE A L UTILISATION DE CIMENT
C     PORTLAND AVEC :
C
C     17MPA<FC<70MPA
C     0.3<W/C<0.85
C     160kg/m3<CIMENT<720kg/m3
C     2.5<A/C<13.5
C
C     DATCUR = JOURS DE CURE OBLIGATOIRE
   30 IF (DATCUR.LT.1.D0) THEN
      WRITE(*,*)'LA CURE MINI DU BETON EST DE 1 JOUR'
      ENDIF
C
C
C COMMENTAIRES
C*****************************************************************
C
C     FLU= FONCTION DE FLUAGE OU DE COMPLAISANCE POUR TFLU ET DUR
C     FI = COEFFICIENT DE FLUAGE : FI = ET*FLU-1
C     ET = MODULE D ELASTICITE A TFLU
C     TFLU = DATE D'APPLICATION DE LA CHARGE
C     DUR = DUREE D APPLICATION DE LA CHARGE
C
C     FLU0= TERME DE FLUAGE PROPRE POUR TFLU ET DUR
C     FLUD= TERME DE FLUAGE DE DESSICCATION POUR TFLU ET DUR
C
C     E28 = 4734*SQRT(FC) = MODULE D ELASTICITE
C                          A 28 JOURS DU BETON (MPA)
C
C     EAU : EAU DE COMPOSITION DE BETON : VALEUR EN KG/M3
C     CIMENT : VALEUR EN KG/M3
C     AGREGA : VALEUR EN KG/M3
C     FC = RESISTANCE CARACTERISTIQUE A 28 JOURS DU BETON (MPA)
C     WSURC = W/C = RAPPORT EAU SUR CIMENT DE LA COMPO. DE BETON
C
C
C
C COMPOSITION DE CIMENT DE LA CENTRALE DE CIVAUX / BHP
C*****************************************************************
C VALEURS EN kg/m3
C      EAU = 161.
C      CIMENT = 266.
C      SILICE = 40.3
C      AGREG = 1133.0 + 482.0
C      SABLE = 1133.0
C      FINES = 57.0
C      FC = 30.
C      ADJUV = 9.98
C
C
C
C CIMENT PORTLAND
C*****************************************************************
C LA VALEUR DE CIMENT S EXPRIME EN kg/m3
      C = CIMENT
      IF (C.LT.160.D0.OR.C.GT.720.D0) THEN
        WRITE(*,*)'QUANTITE DE CIMENT NON RESPECTEE'
      ENDIF
C
C
C RAPPORT AGREGAT/CIMENT
C*****************************************************************
C LA VALEUR D AGREGAT S EXPRIME EN kg/m3
      A = AGREG
      ASURC = A/C
      IF (ASURC.GT.2.50.OR.ASURC.LT.13.50) THEN
        WRITE(*,*)'RAPPORT A/C NON RESPECTE'
      ENDIF
C
C
C RAPPORT EAU/CIMENT
C*****************************************************************
C LA VALEUR D EAU S EXPRIME EN kg/m3
      W = EAU
      WSURC = W/C
C
      IF (WSURC.EQ.0.D0.OR.WSURC.GT.1.D0) THEN
        WSURC = 1.D0 /((FC/22.8D0)+0.535D0)
      ELSE
        IF (WSURC.LT.0.35D0.OR.WSURC.GT.0.85D0) THEN
        WRITE(*,*)'RAPPORT W/C NON RESPECTE'
        ENDIF
      ENDIF
C
C
C RESISTANCE CARACTERISTIQUE DU BETON
C*****************************************************************
C LA VALEUR DE RESISTANCE S EXPRIME EN MPa
C
      IF (FC.LT.17.D0.OR.FC.GT.70.D0) THEN
        WRITE(*,*)'VALEUR DE RESISTANCE NON RESPECTEE'
      ENDIF
C
C
C*****************************************************************
C TERME DE FLUAGE PROPRE FLU0
C*****************************************************************
C
      E28= 4734.D0*SQRT(FC)
      Q1 = 0.6D0*1D6/E28
      Q2 = 185.4D0*SQRT(C)*FC**(-0.9D0)
      Q3 = 0.29D0*(WSURC**4)*Q2
      Q4 = 20.3D0*(ASURC)**(-0.7D0)
C
C*****************************************************************
C DANS LE MODELE B3
C BETON NORMAUX : C1=m=0.5 ET C2=n=0.1
      C1 = 0.5D0
      C2 = 0.1D0
C*****************************************************************
C
      R = 1.7D0*(TFLU**(0.12D0))+8.D0
      QF = 1.D0/(0.086D0*(TFLU**(2.D0/9.D0))+1.21D0*(TFLU**(4.D0/9.D0)))
C
      Z = (TFLU**(-C1))*LOG(1.D0+(DUR)**(C2))
      Q = QF*(1+QF/(Z**R))**(-1.D0/R)
C
      FLU0 = Q2*Q+Q3*LOG(1.D0+DUR**(C2))
     &+Q4*LOG((DUR+TFLU)/TFLU)
C
C
C*****************************************************************
C TERME DE FLUAGE DE DESSICCATION : FLUD
C*****************************************************************
C     ALPHA1 = COEFFICIENT DU TYPE DE CIMENT
C     ALPHA1 = 1.00 = CIMENT TYPE 1
C     ALPHA1 = 0.85 = CIMENT TYPE 2
C     ALPHA1 = 1.10 = CIMENT TYPE 3
C
      ALPHA1 = 1.D0
C
C     ALPHA2 = TYPE DE CURE
C     ALPHA2 = 0.75 = EVAPORATION
C     ALPHA2 = 1.00 = CURE DANS L EAU OU A 100% HR
C     ALPHA2 = 1.20 = CURE NORMALE OU CONFINE AVEC PROTECTION
C                     CONTRE LE SECHAGE
C
      ALPHA2 = 1.D0
C
C
C TERME DE RETRAIT INFINI : ESINF
C*****************************************************************
      ESINF = (-ALPHA1*ALPHA2*(1.9D0*1D-2*(W**(2.1D0))*
     *(FC**(-0.28D0))+270.D0))*1D-6
C
      COEFT = 8.5D0*(DATSEC**(-0.08D0))*(FC**(-1.D0/4.D0))
C
C
C TERME DE FORME : COEFS
C*****************************************************************
C     COEFS = 1.00 : PLAQUE INFINIE
C     COEFS = 1.15 : CYLINDRE INFINI
C     COEFS = 1.25 : PRISME
C     COEFS = 1.30 : SPHERE
C     COEFS = 1.35 : CUBE
C
      COEFS = 1.D0
C
C
C TERME DE TEMPS DU A LA TAILLE : TAUSH
C*****************************************************************
C LES DIMENSIONS SONT DONNEES EN M3 & M2 : TRANSFORMATION EN MM
C
      DIM = 2*(VOL*1E9)/(AC*1E6)
      TAUSH = COEFT*((COEFS*DIM)**2)
C
C
C TERME DEPENDANT DU RETRAIT ULTIME : ESHINF
C*****************************************************************
      E607 = E28*SQRT(607.D0/(4.D0+0.85D0*607.D0))
C
      ESEC = E28*SQRT((DATSEC+TAUSH)/
     *(4.D0+0.85D0*(DATSEC+TAUSH)))
C
      ESHINF = ESINF*E607/ESEC
C
C
C TERME DEPENDANT DE LA DUREE DE SECHAGE : ST
C*****************************************************************
      Q5 = 7.57D0*1D5/FC*((ABS(ESINF))**(-0.6D0))
      ST = TANH(SQRT((TFLU+DUR-DATSEC)/TAUSH))
C
      IF (TFLU.GE.DATSEC) THEN
      STTFLU = TANH(SQRT((TFLU-DATSEC)/TAUSH))
      ELSE
      STTFLU = TANH(SQRT((DATSEC-DATSEC)/TAUSH))
      ENDIF
C
      HTDUR  = 1.D0-(1.D0-RH/100.D0)*ST
      HTTFLU = 1.D0-(1.D0-RH/100.D0)*STTFLU
      FLUD=Q5*SQRT(EXP(-8.D0*HTDUR)-EXP(-8.D0*HTTFLU))
C
C
C COEFFICIENT DE FLUAGE FI
C*****************************************************************
      ELAS0 = E28*SQRT(TFLU/(4.D0+0.85D0*TFLU))
      FI    = ELAS0*FLU-1.D0
C
C
C TYPE DE FLUAGE CONSIDERE
C*****************************************************************
C     ICAS = 1 : CALCUL DU FLUAGE PROPRE SEULEMENT
C     ICAS = 2 : CALCUL DU FLUAGE PROPRE + FLUAGE DE DESSICCATION
C
      ICAS = 1
      IF (ICAS.EQ.1) THEN
      FLU = FLU0
      ELSE IF (ICAS.EQ.2) THEN
      FLU = FLU0 + FLUD
      ENDIF
C
C*****************************************************************
C     4 : MODELE CEB FIP
C*****************************************************************
C*****************************************************************
C
C ICODEA = TYPE D AGGREGAT
C ICODEA = 1 = AGGREGAT QUARTZITIQUE
C ICODEA = 2 = AUTRE AGGREGAT
C
   40 ICODEA = 1
C
C ANALYSE ELASTIQUE DES GRANULATS
C IANA = 1 = OUI (SANS FLUAGE)
C IANA = 0 = NON (VISCOELASTIQUE)
C
      IANA = 0
C
C MODULE D ELASTICITE
C*****************************************************************
C      CH0 = HAUTEUR CARACTERISTIQUE
       CH0 = 2.D0*AC*1D6/(U*1D3)
       FCM = FC+8.D0
       FCM0 = 10.D0
       E28 = 21500.D0*((FCM/FCM0)**(1.D0/3.D0))
C
       IF (ICODEA.EQ.2) THEN
C
         IF (IANA.EQ.1) THEN
         E28 = E28*0.85D0
         ELSE
         CONTINUE
         ENDIF
C
       E28MAX = E28*1.20D0
       E28MIN = E28*0.7D0
       E28MOY = (E28MAX+E28MIN)/2.D0
       E28    = E28MOY
C
       ELSE
         IF (IANA.EQ.1) THEN
         E28 = E28*0.85D0
         ELSE
         CONTINUE
         ENDIF
       CONTINUE
       ENDIF
C
C
C RESISTANCE ET MODULE
C*****************************************************************
C   CEMENT = COEFFICIENT FONCTION DU TYPE DE CIMENT
C   CIMALPHA = EFFET DU TYPE DE CIMENT SUR LE FLUAGE
C
C CIMENT A DURCISSEMENT LENT
C*****************************************************************
C       CEMENT = 0.38
C       CIMALPHA = -1.D0
C
C CIMENT NORMAL ET DURCISSEMENT RAPIDE
C*****************************************************************
       CEMENT   = 0.25D0
       CIMALPHA = 0.D0
C
C CIMENT HAUTE RESISTANCE ET DURCISSEMENT RAPIDE
C*****************************************************************
C       CEMENT = 0.20
C       CIMALPHA = 1.D0
C
C
       IF (ITYPE.EQ.4.OR.ITYPE.EQ.5) THEN
       TFLU = TFLU*(9.D0/(2.D0+TFLU**(1.2D0))+1.D0)**(CIMALPHA)
       ENDIF
C
C
C MODULE AU TEMPS T = TFLU+DUR ET RESISTANCE
C*****************************************************************
       BCC = EXP(CEMENT*(1.D0-SQRT(28.D0/(TFLU+DUR))))
       BE = SQRT(BCC)
       ELAS = BE*E28
       FCMT = FCM*BCC
C
C
C MODULE AU TEMPS TFLU ET RESISTANCE
C*****************************************************************
       BCC0 = EXP(CEMENT*(1.D0-SQRT(28.D0/TFLU)))
       BE0 = SQRT(BCC0)
       ELAS0 = BE0*E28
       FCMT0 = FCM*BCC0
C
C
C COEFFICIENT DE FLUAGE : FI
C*****************************************************************
       BFCM = 5.3D0/(SQRT(FCMT0/FCM0))
       BT0 = 1.D0/(0.1D0+TFLU**0.2D0)
C
       REFH = 100.D0
       BH = 150.D0*CH0/REFH*(1.D0+(0.012D0*RH)**18)+250.D0
C
       IF (BH.GT.1500) THEN
       BH = 1500.D0
       ENDIF
C
       BCTT0 = (DUR/(DUR+BH))**(0.3D0)
       PHIRH = 1.D0+(1.D0-(RH/100.D0))/
     &        (0.46D0*((CH0/REFH)**(1.D0/3.D0)))
       PHI0 = PHIRH*BFCM*BT0
C
       IF (ITYPE.EQ.4) THEN
       FI = PHI0*BCTT0*BE0
       FICEB = FI/BE0

       FLU = 1.D0/ELAS0*(1.D0+FI)
       GO TO 100
C
C*****************************************************************
C      5 : MODELE EUROCODE2
C*****************************************************************
C*****************************************************************
C
C
C VALIDITE DU MODELE
C*****************************************************************
C
C     LA COMPOSITION DE BETON EST REDUITE A L UTILISATION DE CIMENT
C     PORTLAND AVEC :
C
C     12 MPA < FC < 60 MPA
C     40% < RH < 100%
C
       ELSE IF (ITYPE.EQ.5) THEN
C
       IF (FC.LT.12.OR.FC.GT.60) THEN
       WRITE(*,*)'MODELE NON VALIDE'
       ELSE IF (RH.LT.12.OR.RH.GT.60) THEN
       WRITE(*,*)'MODELE NON VALIDE'
       ENDIF
C
       E28    = 1.05D0*9500.D0*(FCM)**(1.D0/3.D0)
       FCMT0  = FCM*EXP(CEMENT*(1.D0-SQRT(28.D0/TFLU)))
       ELAS0  = 1.05D0*9500.D0*(FCMT0)**(1.D0/3.D0)
       PHIRH  = 1.D0+(10.D0*(1.D0-RH/100.D0))/(CH0**(1.D0/3.D0))
       BFCM   = 16.8D0/SQRT(FCM)
       PHITT0 = PHIRH*BFCM*BT0*BCTT0
       FI     = PHITT0*ELAS0/E28
       FLU    = 1.D0/ELAS0*(1.D0+FI)
       GO TO 100
C
C*****************************************************************
C      6 : MODELE BPEL91
C*****************************************************************
C*****************************************************************
C
       ELSE IF (ITYPE.EQ.6) THEN
C
       IF (FC.LE.40) THEN
       FCJ = TFLU/(4.76D0+0.83D0*TFLU)*FC
       ELSE
       FCJ = TFLU/(1.40D0+0.95D0*TFLU)*FC
       ENDIF
C
       FCLIMI = 1.1D0*FC
       IF (FCJ.GT.FCLIMI) THEN
       FCJ = FCLIMI
       ENDIF
C
       ELAS0 = 11000.D0*(FCJ)**(1.D0/3.D0)
       E28 = 11000.D0*(FC)**(1.D0/3.D0)
C
       RM = AC*1D6/(U*1D3)
       U1 = 5.D0
       FTT0 = SQRT(DUR)/(SQRT(DUR)+U1*SQRT(RM))
       CASC = (120.D0-RH)/30.D0+2.D0*(100.D0-RH)/(3.D0*(20.D0+RM))
       CAST0 = 100.D0/(100.D0+TFLU)
       CASFL = 0.4D0+CASC*CAST0
       FI = CASFL*FTT0
       FLU = 1.D0/ELAS0+FI/E28
C
       GO TO 100
C
       ENDIF
C
C*****************************************************************
C      7 : MODELE AFREM
C*****************************************************************
C
C FLUAGE PROPRE
C*****************************************************************
C ICOMP = 1 SI BETON AVEC FUMEE DE SILICE
C ICOMP = 0 SI BETON SANS FUMEE DE SILICE
C
   50 ICOMP = 1
C
       IF (FC.LE.40) THEN
       FCJ = TFLU/(4.76D0+0.83D0*TFLU)*FC
       ELSE
       FCJ = TFLU/(1.40D0+0.95D0*TFLU)*FC
       ENDIF
C
       FCLIMI = 1.1D0*FC
       IF (FCJ.GT.FCLIMI) THEN
       FCJ = FCLIMI
       ENDIF
C
       ELAS0 = 11000.D0*(FCJ)**(1.D0/3.D0)
       E28 = 11000.D0*(FC)**(1.D0/3.D0)

       IF (ICOMP.EQ.1) THEN
       FLU0 = 3.60D0/E28*SQRT(DUR)/(SQRT(DUR)
     *+0.37D0*EXP(2.8D0*FCJ/FC))
C
       ELSE IF (ICOMP.EQ.0) THEN
       FLU0 = 1.40D0/E28*SQRT(DUR)/(SQRT(DUR)
     *+0.40D0*EXP(3.1D0*FCJ/FC))
       ENDIF
C
C RETRAIT
C*****************************************************************
C
       IF (FC.GE.57) THEN
       CASFC28 = 30.D0-0.21D0*FC
       ELSE
       CASFC28 = 18.D0
       ENDIF
C
       IF (ICOMP.EQ.1) THEN
       ERET1 = CASFC28*(72.D0*EXP(-0.046D0*FC)+75.D0-RH/100.D0)
     **DATSEC/(DATSEC+2.8D0*(RM**2))
       ERET  = CASFC28*(72.D0*EXP(-0.046D0*FC)+75.D0-RH/100.D0)
     **DUR   /(DUR   +2.8D0*(RM**2))
       GO TO 51
C
       ELSE IF (ICOMP.EQ.0) THEN
C
       ERET1 = CASFC28*(72.D0*EXP(-0.046D0*FC)+75.D0-RH/100.D0)
     **DATSEC/(DATSEC+8.4D0*(RM**2))
       ERET = CASFC28*(72.D0*EXP(-0.046D0*FC)+75.D0-RH/100.D0)
     **DUR/(DUR+8.4D0*(RM**2))
       GO TO 52
C
       ENDIF
C
C FLUAGE DE DESSICCATION
C*****************************************************************
   51 IF (ICOMP.EQ.1) THEN
       FLUD = 3.2D0*1D3/E28*(ERET-ERET1)
       ENDIF
C
   52 IF (ICOMP.EQ.0) THEN
       FLUD = 1D3/E28*(ERET-ERET1)
       ENDIF
C
C
C TYPE DE FLUAGE CONSIDERE
C*****************************************************************
C     ICAS = 1 : CALCUL DU FLUAGE PROPRE SEULEMENT
C     ICAS = 2 : CALCUL DU FLUAGE PROPRE + FLUAGE DE DESSICCATION
C
      ICAS = 1
      IF (ICAS.EQ.1) THEN
      FLU = FLU0
      ELSE IF (ICAS.EQ.2) THEN
      FLU = FLU0 + FLUD
      ENDIF
C
      GO TO 100
C
C*****************************************************************
C     8 : MODELE BP-KX
C*****************************************************************
C*****************************************************************
C
   60 E28=4734.D0*SQRT(FC)
      Q1 = 4597.D0/E28
      WSURC = EAU/CIMENT
      Q2 = 0.00045D0*WSURC**(0.8D0)*C**(1.5D0)
     **(1.D0-A/2500.D0)**(-0.9D0)*FC**(-0.5D0)-0.39D0
      Q3 = 0.025D0*Q2
      Q4 = 0.017D0*WSURC**(2.3D0)*C**(0.2D0)
     **(1.D0-A/2500.D0)**(0.39D0)*FC**(0.46D0)
      Q5 = 3.321D0*FC**(-0.5D0)

      R = 1.7D0*(TFLU**(0.12D0))+8.D0
      ZTT0 = TFLU**(-0.5D0)*LOG(1.D0+DUR**(0.1D0))
      QFT0 = 1.D0/(0.086D0*(TFLU**(2.D0/9.D0))+1.21D0
     **(TFLU**(4.D0/9.D0)))
      QTT0 = QFT0*((1.D0+((QFT0/ZTT0)**(R)))**(-1.D0/R))
      FLU0 = Q1+Q2*QTT0+Q3*LOG(1+DUR)
     *+Q4*LOG((TFLU+DUR)/TFLU)
C
C
C TERME D HUMIDITE : COEFH
C*****************************************************************
      HUMI = RH/100.D0
      IF(HUMI.EQ.1.D0) THEN
      COEFH = -0.2D0
      ELSE IF(HUMI.LE.0.98D0) THEN
      COEFH = 1.D0-(HUMI)**3
      ELSE
      COEFH = (1.D0-0.98D0**3)-((1.D0-0.98D0**3)
     *+0.2D0)/0.02D0*(HUMI-0.98D0)
      ENDIF
C
      RAP = AGREG/SABLE
      IF (RAP.GT.2.6D0) THEN
      ALPHA4 = 0.7D0+0.3D0*(RAP)**(-3)
      ELSE
      ALPHA4 = 1.D0
      ENDIF

      ALPHA1 = 0.0175D0*WSURC**(1.5D0)*C**(1.1D0)
     **FC**(-0.2D0)*(1.D0-A/2500.D0)*ALPHA4
C
C     ALPHA2 = COEFFICIENT DU TYPE DE CIMENT
C     ALPHA2 = 1.00 = CIMENT TYPE 1
C     ALPHA2 = 0.85 = CIMENT TYPE 2
C     ALPHA2 = 1.15 = CIMENT TYPE 3
C
      ALPHA2 = 1.D0
C
C     ALPHA3 = TYPE DE CURE
C     ALPHA3 = 0.74 = EVAPORATION OU CURE SECHE
C     ALPHA3 = 1.00 = CURE DANS L EAU OU A 100% HR
C     ALPHA3 = 1.40 = CURE CONFINE AVEC PROTECTION
C                     CONTRE LE SECHAGE
C
      ALPHA3 = 1.D0
C
      ESINF = (1.15D0*ALPHA1+0.16D0)*ALPHA2*ALPHA3
C
      DIM = 2.D0*(VOL*1D9)/(AC*1D6)
C
C
C TERME DE FORME : COEFS
C*****************************************************************
C     COEFS = 1.00 : PLAQUE INFINIE
C     COEFS = 1.15 : CYLINDRE INFINI
C     COEFS = 1.25 : PRISME
C     COEFS = 1.30 : SPHERE
C     COEFS = 1.35 : CUBE
C
      COEFS = 1.D0
C
      IF (ALPHA3.EQ.0.74D0) THEN
      TCUR = 25.D0+TFLU
      ELSE
      TCUR = TFLU
      ENDIF
C
      C1TCUR = 10.D0*(0.6D0+SQRT(4.5D0/TCUR))
      IF (C1TCUR.GT.18.D0) THEN
      C1TCUR = 18.D0
      ENDIF
C
      TAUSH = 0.32D0*((COEFS*DIM)**2)/C1TCUR
      X1 = 17.D0+TAUSH/40.D0
      X2 = 12.D0+TCUR
      GX1 = SQRT(X1/(4.D0+0.9D0*X1))
      GX2 = SQRT(X2/(4.D0+0.9D0*X2))
      ESHINF = ESINF/(GX1*GX2)
C
      FLUD = Q5*COEFH*ESHINF*(TANH(SQRT((TFLU+DUR-DATSEC)
     **(2.D0*TAUSH)))-TANH(SQRT((TFLU-DATSEC)*(2.D0*TAUSH))))**(0.5D0)
C
C
C TYPE DE FLUAGE CONSIDERE
C*****************************************************************
C     ICAS = 1 : CALCUL DU FLUAGE PROPRE SEULEMENT
C     ICAS = 2 : CALCUL DU FLUAGE PROPRE + FLUAGE DE DESSICCATION
C
      ICAS = 1
      IF (ICAS.EQ.1) THEN
      FLU = 145.D0*FLU0*1D-6
      ELSE IF (ICAS.EQ.2) THEN
      FLU = 145.D0*(FLU0 + FLUD)*1D-6
      ENDIF
C
      GO TO 100
C
C*****************************************************************
C
  100 RETURN
      END