C FATDI     SOURCE    STRU      08/12/22    21:15:19     6246
c     Sous-Programme du module MISTRAL0
C     --------------------------------------------------------------------------
      SUBROUTINE FATDI (TT,S,PSI, PAR, V)
C     --------------------------------------------------------------------------
C     Calcul de V = FTT(TT,S,PSI)*FPSI(PSI) en fonction :
C     - de la temperature TT,
C     - d'une contrainte S,
C     - de la variable de durcissement du a l'irradiation PSI,
C     et des parametres transmis dans PAR.
C     --------------------------------------------------------------------------
      IMPLICIT INTEGER (I-N)
      IMPLICIT REAL*8 (A-H, O-Z)
      DIMENSION PAR(1:*)
c     (NPATDM = 14)
C     ------------------------------------------------------------------
      L = NINT(PAR(1))
      IP = 1
        IF (L.EQ.-1) THEN
       IP = IP+1
         FTT = PAR(IP)
        ELSE IF (L.EQ.1) THEN
         FTT = PAR(IP+1)*EXP(-(PAR(IP+2)-PAR(IP+3)*S)/TT)
       IP = IP+3
        ELSE IF (L.EQ.2) THEN
       FT = 1./(1.+EXP(PAR(IP+3)*(TT/PAR(IP+4)-1.)))
       FTT = PAR(IP+1)*FT+PAR(IP+2)*(1.-FT)
       IP = IP+4
        ELSE IF (L.EQ.3) THEN
         FTT = PAR(IP+1)
     &  *EXP(-(PAR(IP+2)+PAR(IP+3)*EXP(PAR(IP+4)*PSI**PAR(IP+5)))/TT)
       IP = IP+5
        ELSE IF (L.EQ.4) THEN
         FTT = PAR(IP+1)*EXP(PAR(IP+2)*TT)
       IP = IP+2
        END IF
C     ------------------------------------------------------------------
      IP = IP+1
      L = NINT(PAR(IP))
        IF (L.EQ.0) THEN
         V = FTT
       RETURN
C     ------------------------------------------------------------------
        ELSE IF (L.EQ.1) THEN
         FPSI = (PSI+PAR(IP+1))**PAR(IP+2)
        ELSE IF (L.EQ.2) THEN
         FPSI = PAR(IP+1)*EXP(PAR(IP+2)*PSI**PAR(IP+3))
     & + (1.-PAR(IP+1))*EXP(PAR(IP+4)*PSI**PAR(IP+5))
        ELSE IF (L.EQ.3) THEN
         PSIPL = PSI+PAR(IP+2)
         FPSI = PAR(IP+1)*PSIPL**PAR(IP+3)*EXP(-PAR(IP+4)*PSI)
     &      + PAR(IP+5)*PSIPL**PAR(IP+6)*(1.-EXP(-PAR(IP+7)*PSI))
        ELSE IF (L.EQ.4) THEN
         FPSI = EXP(PAR(IP+1)*PSI**PAR(IP+2)+PAR(IP+3)*PSI**PAR(IP+4))
        ELSE IF (L.EQ.5) THEN
         FPSI = PAR(IP+1) + (1.-PAR(IP+1))*EXP(PAR(IP+2)*PSI
     &      +PAR(IP+3)*PSI**PAR(IP+5)+PAR(IP+4)*PSI**PAR(IP+6))
        ELSE IF (L.EQ.6) THEN
         FPSI = PAR(IP+1) + PAR(IP+2)*PSI + PAR(IP+3)*PSI**2
        ELSE IF (L.EQ.7) THEN
         FPSI = (PAR(IP+1)*PSI+PAR(IP+2)) / (PAR(IP+3)*PSI+PAR(IP+4))
         FPSI = FPSI**PAR(IP+5)
        END IF
C     ------------------------------------------------------------------
        V = FTT*FPSI
        RETURN
        END