C ELFBL4    SOURCE    CHAT      05/01/12    23:31:23     5004
      SUBROUTINE ELFBL4(N,DC,DNORM,P,VPOCHA)
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
C
C  =====================================================================
C    SOUS-PROGRAMME FORTRAN APPELE PAR ELFRES
C    CALCUL DES COMPOSANTES DNCN DANS LE REPERE GENERAL
C            N*2   : NOMBRE D'ELEMENTS  (2 PTS PAR ELEMENT)
C            DNORM : VECTEUR DE NORMALISATION
C            P     : MATRICES DE CHANGEMENT DE REPERE
C            DC    : VECTEUR DNCN LOCAL
C            VPOCHA: VECTEUR DNCN GLOBAL
C    CREATION    :  4/11/86
C    PROGRAMMEUR : GUILBAUD
C  =====================================================================
C
      DIMENSION DC(1),DNORM(1),P(1),DN(3),VPOCHA(N,1)
      IP=0
      NSTR=N/2
      NN=0
      DO 60 NS=1,NSTR
      MP=9*(NS-1)
        DO 50 NP=1,2
        NN=NN+1
          DO 40 KI=1,4
          I3=3*(KI-1)
          I3P=I3+IP
            DO 10 J=1,3
            DN(J)=DNORM(I3P+J)*DC(I3P+J)
   10       CONTINUE
              DO 30 I=1,3
              AVI=0.D0
              MPI=MP+3*(I-1)
                DO 20 J=1,3
                AVI=AVI+P(MPI+J)*DN(J)
   20           CONTINUE
              VPOCHA(NN,I3+I)=AVI
   30       CONTINUE
   40     CONTINUE
        IP=IP+12
   50   CONTINUE
   60   CONTINUE
      RETURN
      END