C DYCHA41   SOURCE    CHAT      05/01/12    23:01:19     5004
C DYCHA41    SOURCE    LAVARENN  96/08/05    21:17:45     2237
      SUBROUTINE DYCHA41(XDEP,XVITN,IDIM,IGP,XPALB,NLIAB,I,XFN,XFT
     &                          ,XPUS,XABSCI,XORDON,NIP,iannul)
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
*--------------------------------------------------------------------*
*                                                                    *
*     Op{rateur DYNE :                                               *
*     ________________________________________________               *
*                                                                    *
*     Calcul de la force de choc pour un choc {l{mentaire.           *
*                Cas d'une loi elastique                             *
*                                                                    *
*     Param}tres:                                                    *
*                                                                    *
* e   XDEP    Valeur du d{placement sur la normale                   *
* e   XVITN   Valeur de la vitesse normale au plan tangent du contact*
* e   IGP     Indice de glissement au pas pr{c{dent                  *
* es  XPALB   Tableau contenant les param}tres de la liaison         *
* e   NLIAB   Nombre de liaisons sur la base B                       *
* e   I       Num{ro de la liaison                                   *
* e   XABSCI  Abscisses loi elastique                                *
* e   XORDON  Ordonnees loi elastique                                *
*  s  XFN     Valeur de la force de choc suivant la normale.         *
*  s  XFT     Module de la force de choc projetee sur le plan tangent*
*  s  XPUS    Valeur de la puissance d'usure instantanee             *
*                                                                    *
*                                                                    *
*     Auteur, date de cr{ation:                                      *
*                                                                    *
*     Bruno FONTAINE, le 26/02/98                                    *
*                                                                    *
*--------------------------------------------------------------------*
      DIMENSION XPALB(NLIAB,*)
      REAL*8 XABSCI(NLIAB,*),XORDON(NLIAB,*)
      XFN = 0.D0
      XFT = 0.D0
      XPUS = 0.D0
      XJEU  = XPALB(I,2)
*
      IF ((XDEP.GE.XJEU).AND.(iannul.EQ.0)) THEN
         ID2 = 7 + IDIM
         ID3 = 7 + 2*IDIM
         ID4 = 7 + 3*IDIM
         ID6 = 7 + 5*IDIM
         ID7 = 7 + 6*IDIM
         XAMON = XPALB(I,7)
         XGLIS = XPALB(I,3)
         XADHE = XPALB(I,4)
         XRAIT = XPALB(I,5)
         XAMOT = XPALB(I,6)
         XVAL = XDEP - XJEU
         CALL LIRANG(XDEP,XABSCI,XORDON,I,NLIAB,NRG,XPENTE,NIP)
         XFN = - (XORDON(I,NRG) + XPENTE*(XDEP-XABSCI(I,NRG)))
     &        - XAMON * XVITN
         CALL DYCHFR(IDIM,IGP,XPALB,NLIAB,I,ID2,ID3,ID4,ID6,ID7,XGLIS,
     &               XADHE,XRAIT,XAMOT,XFN,XFT,XPUS)
         IF ( XFN.GT.0.D0) XFN = 0.D0
      ELSE
         IGP = -1
         ID4 = 7 + 3*IDIM
         DO 10 ID=1,IDIM
            XPALB(I,ID4+ID) = 0.D0
 10         CONTINUE
*        end do
      ENDIF
*
      RETURN
      END