$$$$ DEADJACO
* DEADJACO  PROCEDUR  GOUNAND   26/01/12    21:15:02     12448          
************************************************************************
* NOM         : DEADJACO
* DESCRIPTION : Le déterminant de la matrice jacobienne
*               de la transformation géométrique (par élément)
*
*
*
* LANGAGE     : GIBIANE-CAST3M
* AUTEUR      : Stéphane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
*               mél : gounand@semt2.smts.cea.fr
**********************************************************************
* VERSION    : v1, 05/04/2006, version initiale
* HISTORIQUE : v1, 05/04/2006, création
* HISTORIQUE : 2025/12/29 : simplification donnees NLIN
* HISTORIQUE :
* HISTORIQUE :
************************************************************************
* Prière de PRENDRE LE TEMPS de compléter les commentaires
* en cas de modification de ce sous-programme afin de faciliter
* la maintenance !
************************************************************************
*
*
'DEBPROC' DEADJACO ;
'ARGUMENT' _mt*'MAILLAGE' ;
'ARGUMENT' moterrj/'MOT' ;

lerrj = 'EXIS' moterrj ;
'SI' lerrj ;
   'SI' ('NEG' moterrj 'ERRJ') ;
*1052 2
*Mot-cle incorrect "%M1:4". Voici la liste des valeurs admises : %M5:40
      'ERRE' 1052 'AVEC' moterrj 'ERRJ' ;
   'FINS' ;
'FINS' ;

gdisc = DEADUTIL 'TYPM' _mt ;
'SI' ('EGA' gdisc 'LINE') ;
   methgau = 'GAM1' ;
'SINON' ;
   methgau = 'GAM2' ;
'FINSI' ;
*methgau = 'GAU7' ;
*
* Calcul du résidu
*
vdim  = DEADUTIL 'DIMM' _mt ;
numop  = 1 ;
numvar = 1 ;
numder = vdim ;
numdat = 0 ;
numcof = 1 ;
*
   A = ININLIN numop numvar numdat numcof numder ;
   A . 'VAR' . 1 . 'VALEUR' = 1.D0 ;
   A . 'COF' . 1 . 'COMPOR' = 'CHAINE' 'VOLORI' ;
*
   A . 1 . 1 . 0  = 1 ;
*
   numcof = 0 ;
   B = ININLIN numop numvar numdat numcof numder ;
* Le Jacobien est nul ou presque sur les noeuds sommet du TRI6
* donc ce serait contraignant
*   B . 'VAR' . 1 . 'NOMDDL' = 'SCAL' ;
*   B . 'VAR' . 1 . 'DISC'   = gdisc ;
   B . 'VAR' . 1 . 'VALEUR' = 1.D0 ;
   B . 1 . 1 . 0  = 0 ;
*
'SI' lerrj ;
   detj = 'NLIN' gdisc _mt A B 'EREF' 'ERRJ' 'CHAM' methgau ;
'SINO' ;
   detj = 'NLIN' gdisc _mt A B 'EREF' 'CHAM' methgau ;
'FINS' ;
*
'RESPRO' detj ;
*
* End of procedure file DEADJACO
*
'FINPROC' ;