$$$$ CALACTIV
* CALACTIV  PROCEDUR  AURI      98/12/29    21:16:01     3419           
DEBPROC CALACTIV  TB3*TABLE TB4*TABLE  LILI*LISTENTI ;
**********************************************************************
*     CALCUL DE L'ACTIVITE DES ESPECES DE LA LISTE LILI
*      TB3 table issue de CHI1
*      TB4 table issue de CHI2
**********************************************************************
 ACTIV='COAC' TB3 'FORCEION' TB4.FION ;
 NIDX= DIME(TB3.DESCHI.IDX) ;
 NIDY= DIME(TB3.DESCHI.IDY) ;
 NLILI= DIME LILI ;
*                        initialisation du résultat
 NUESP= 'EXTR' LILI 1 ;
 MO1 NO1 = NOESPCHI TB3  NUESP ;
 CCACT= 'EXCO' MO1 TB4.'SOLU' MO1 ;
 CCACT= CCACT- CCACT ;
*
 'REPE' BOU1 NLILI ;
 NUESP= 'EXTR' LILI &BOU1 ;
 MO1 NO1 = NOESPCHI TB3  NUESP ;
 'SI' ('EGA' ('DIME' ( LILI 'SAUF'('LECT' NUESP)))  NLILI ) ;
          'MESS' NUESP ' n est pas une espèce en solution'
           'QUIT' BOU1 ;
 'FINSI' ;
 REPE BDY NIDY ;
 NUNU1='EXTR' (TB3.DESCHI.IDY) &BDY ;
 'SI' ('EGA' NUNU1 NUESP) ;
 NUDY=&BDY ;
 'FINS' ;
 'FIN' BDY ;
 CHESP=0. ;
 'REPE' BDX NIDX ;
       NUAA= NIDY*(&BDX-1)+NUDY ;
       AAA= 'EXTR'(TB3.DESCHI.MATRICEA) NUAA ;
       CHXX= 'EXTR' (TB3.DESCHI.CHARGE) &BDX ;
       CHESP=CHESP+(AAA*CHXX) ;
 'FIN' BDX ;
 CONC= 'EXCO' MO1 TB4.'SOLU' 'SCAL' ;
 COESP=(('ABS' CHESP)*ACTIV)+(('LOG' CONC)/('LOG' 10.))  ;
 COESP= NOMC MO1 COESP ;
 CCACT= CCACT+COESP ;
FIN BOU1 ;
FINP CCACT ;