************************************************************************
*               Test de l'operateur BIOT pour le calcul                *
*                   du champ d'induction magnetique                    *
*                                                                      *
* Calcul du champ d'induction magnetique B cree par des bobines de     *
* Helmholtz                                                            *
*                                                                      *
* Reference : https://fr.wikipedia.org/wiki/Bobines_de_Helmholtz       *
*                                                                      *
************************************************************************

** Indicateur de trace
itrac = FAUX ;



*------------------------- P A R A M E T R E S ------------------------*

** Bobines (rayon, nombre de tours, courant)
r     = 1. ;
nt    = 100 ;
i     = 42. ;

** Dimensions du domaine de calcul et parametre de discretisation
l     = 4. ;
dens1 = 0.05 ;

** Permeabilite magnetique du milieu
mu = 12.566E-7 ;




** Options de calcul
OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' 'DENS' dens1 ;

** On maille le domaine de calcul (points cibles)
ligz  = DROI (0. 0.) (0. l) ;
cib   = ligz TRAN ((l / 2.) 0.) ;
ccib  = CONT cib ;

** Calcul du champ d'induction magnetique (cas particuler d'inducteurs filaires puisque
*  rayon int=ext et section nulle, on donne donc le courant et non la desnite de courant)
b1    = BIOT 'INDU' cib 'CERC' ((l - r) / 2.) r r 0. (-1. * nt * i) mu ;
b2    = BIOT 'INDU' cib 'CERC' ((l + r) / 2.) r r 0. (-1. * nt * i) mu ;
b     = b1 + b2 ;

SI itrac ;
  vb    = @VECOUL b (MOTS 'BR' 'BZ') 1.E1 ;
  TRAC vb ccib 'TITR' 'Champ B dans le domaine' ;
FINSI ;

** Lignes de champ
v     = EXCO (MOTS 'BR' 'BZ') b (MOTS 'UR' 'UZ') ;
fc    = FCOURANT cib v ;
maxf  = MAXI fc ;
minf  = MINI fc ;
nlig  = 15 ;
lf    = PROG minf 'PAS' ((maxf - minf) / (nlig + 1)) maxf ;
lig o = @ISOSURF cib lf fc ;
chbm  = CHAN 'CHAM' b cib ;
bm    = (((EXCO 'BR' chbm 'SCAL') ** 2) + ((EXCO 'BZ' chbm 'SCAL') ** 2)) ** 0.5 ;
blig  = PROI bm lig ;
SI itrac ;
  TRAC blig lig ccib 'TITR' 'Lignes de champ B' ;
FINSI ;

** Verification du champ le long de l'axe des bobines
bz1   = EVOL 'BLEU' 'CHPO' b1 'BZ' ligz ;
bz2   = EVOL 'JAUN' 'CHPO' b2 'BZ' ligz ;
bz    = EVOL 'VERT' 'CHPO' b  'BZ' ligz ;
lz    = PROG 0. 'PAS' dens1 l ;
lbth1 = mu * nt * i * r * r / (2. * (((r ** 2) + ((lz - ((l - r) / 2.)) ** 2)) ** 1.5)) ;
lbth2 = mu * nt * i * r * r / (2. * (((r ** 2) + ((lz - ((l + r) / 2.)) ** 2)) ** 1.5)) ;
lbth  = lbth1 + lbth2 ;
bth   = EVOL 'ROUG' 'MANU' lz lbth ;
lb    = EXTR bz 'ORDO' ;
lerr  = (lb - lbth) / lbth ;
err   = MAXI 'ABS' lerr ;
SI itrac ;
  tl    = TABL ;
  tl . 'TITRE' = TABL ;
  tl . 'TITRE' . 1 = 'Theorie' ;
  tl . 'TITRE' . 2 = 'Calcul BIOT bobine 1' ;
  tl . 'TITRE' . 3 = 'Calcul BIOT bobine 2' ;
  tl . 'TITRE' . 4 = 'Calcul BIOT total' ;
  DESS (bth ET bz1 ET bz2 ET bz) 'TITR' 'Champ B le long de l''axe' 'LEGE' tl
  'TITX' 'Position Z (m)' 'TITY' 'Champ mag. B (T)' ;
FINSI ;

MESS 'Erreur relative max. :' err ;
SI (err > 1.E-6) ;
  ERRE 'Erreur dans le calcul du champ d''induction magnetique' ;
FINSI ;



FIN ;