C BARRIG    SOURCE    CB215821  26/08/24    21:15:12     12622          
      SUBROUTINE BARRIG(REL,LRE,ES,COORD,KERRE)
C-----------------------------------------------------------------------
C       ROUTINE DE CALCUL DE LA MATRICE DE RIGIDITE ELEMENTAIRE
C                      DE L ELEMENT DE BARRE
C-----------------------------------------------------------------------
C  ENTREE
C          LRE     DIMENSION DU TABLEAU REL
C          ES      YOUN * SECT
C          COORD   COORDONNEES DES 2 NOEUDS
C
C  SORTIE
C          REL     MATRICE DE RIGIDITE ELEMENTAIRE
C          KERRE   0 SI PAS DE PB
C                  1 SI LONGUEUR NULLE
C-----------------------------------------------------------------------
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)

-INC PPARAM
-INC CCOPTIO
      DIMENSION REL(LRE,*),COORD(3,*),V(3)
C
      KERRE=0
      V(3)=0.
      DO 1 I=1,IDIM
      V(I)=COORD(I,2)-COORD(I,1)
    1 CONTINUE
      XL=(V(1)*V(1)+V(2)*V(2)+V(3)*V(3))
      XL=SQRT(XL)
      IF(XL.EQ.0.) GO TO 999
C
      FAC=ES/(XL**3)
      DO 1000 I=1,IDIM
      II=I+IDIM
      DO 2 J=1,IDIM
      JJ=J+IDIM
      FAC2=FAC*V(I)*V(J)
      REL(I,J)=FAC2
      REL(II,J)=-FAC2
      REL(I,JJ)=-FAC2
      REL(II,JJ)=FAC2
  2   CONTINUE
 1000 CONTINUE
      RETURN
 999  KERRE=1
      RETURN
      END