* fichier :  Test_celsius.dgibi

*******************************************
* Section : Thermique Conduction
* Section : Thermique Transitoire
*******************************************

*******************************************************
*           Test Test_celsius.dgibi: Jeux de données  *
*           ---------------------------------         *
*                                                     *
*  - Suite a une anomalie, ce cas-test permet de      *
*    tester que les reactions rendues par PASAPAS sont*
*    correctes en THERMIQUE suivant si l'indice       *
*   'CESLIUS' est defini a VRAI ou FAUX dans la TABLE *
*******************************************************

OPTI DIME 2 ELEM QUA8 ;
OPTI TRAC PSC;

T_IMP = 100.;
T_INI_AIR = 25.;
TPSFIN = 40000.;
N_PAS = 100;


P0 = 0. 0.;
P1 = 0.1 0.;



CERC1 = CERC 50 'ROTA' 360. P1 P0;
ELIM CERC1 1E-10;


SURF_CERC = SURF CERC1;

MOD_COND = MODE SURF_CERC 'THERMIQUE';
MAT_COND = MATE MOD_COND 'K' 10. 'C' 1000. 'RHO' 1000. 'TINI' T_INI_AIR;

*On impose la temperature au point de chauffe
PIMP = SURF_CERC POIN 'PROC' P0;

BL_PANIER = BLOQ PIMP 'T';
FL_PANIER = DEPI BL_PANIER T_IMP;



LISTE1  = PROG 0. TPSFIN;
LISTE2  = PROG 1. 1.;
EVT1    = EVOL 'MANU' LISTE1 LISTE2;
CHATIMP = CHAR 'TIMP' FL_PANIER EVT1;

TPS_CALC = PROG 0. PAS (TPSFIN/N_PAS) TPSFIN ;



TRAC SURF_CERC;


TAPAS                      = TABL;
TAPAS.CELSIUS              = VRAI ;
TAPAS.PRECISION            = 1E-5;
TAPAS.MODELE               = MOD_COND;
TAPAS.CARACTERISTIQUES     = MAT_COND;
TAPAS.BLOCAGES_THERMIQUES  = BL_PANIER ;
TAPAS.CHARGEMENT           = CHATIMP ;
TAPAS.TEMPS_CALCULES       = TPS_CALC ;

PASAPAS TAPAS;


MAIL_CAL ='EXTR' (TAPAS.MODELE) 'MAIL';



NB_PAS   ='DIME' TAPAS.'TEMPS';



CTK1 = (TAPAS.TEMPERATURES. 0)  ;
CTC1 = CTK1  ;
titre  'Temperature rayonnement t=0' ;
TRAC CTC1 MAIL_CAL ;
CTK1 = (TAPAS.TEMPERATURES.(NB_PAS - 1))   ;
CTC1 = CTK1  ;
titre  'Temperature rayonnement t=t_{final}' ;
TRAC CTC1 MAIL_CAL ;


OPTI EPTR 5;

* suivi de la temperature
TEMP1 = PROG ;TEMP2 = PROG ;LISTPUI = PROG;
ITER  = 0 ;
NBT1  = NB_PAS ;
REPETER BCL1  NBT1 ;
  TP1    = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) SURF_CERC   ;
  T1     = MINI ( TP1 ) ;
  TEMP1  = TEMP1 'ET' T1 ;
  TEMP2  = TEMP2 ET T_IMP;
  CH_PUI = REAC BL_PANIER (TAPAS.'TEMPERATURES'.ITER );
  VAL_PUI = MAXI (RESU CH_PUI);
  LISTPUI = LISTPUI ET VAL_PUI;
ITER = ITER + 1;
FIN BCL1 ;

TITRE 'EVOLUTION DES TEMPERATURES EN CELSIUS' ;
EV1  = EVOL VERT MANU 'TEMPS (s)' TPS_CALC 'T (C)' TEMP1 ;
EV2  = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'T (C)' TEMP2 ;


TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1  = 'Temperature minimale du cercle' ;
TABDES.'TITRE'. 2  = 'Temperature imposee' ;
DESS (EV1 ET EV2) TABDES 'MIMA' 'LEGE';


TITRE 'Evolution de la puissance avec temperature en celsius' ;
EV3 = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'Q (W)' LISTPUI ;
EV4 = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'E (J)' LISTPUI ;


TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1 = 'Puissance de chauffe' ;

DESS (EV3) TABDES 'MIMA' 'LEGE' ;


EV5 = PRIM EV4;
TITRE 'Evolution de energie avec temperature en celsius' ;
TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1 = 'Energie totale du systeme' ;
DESS(EV5) TABDES 'MIMA' 'LEGE';


E_four_vrai = INTG EV3;
LIST E_four_vrai;










*** Température en kelvin

TAPAS                      = TABL;
TAPAS.CELSIUS              = FAUX ;
TAPAS.PRECISION            = 1E-5;
TAPAS.MODELE               = MOD_COND;
TAPAS.CARACTERISTIQUES     = MAT_COND;
TAPAS.BLOCAGES_THERMIQUES  = BL_PANIER ;
TAPAS.CHARGEMENT           = CHATIMP ;
TAPAS.TEMPS_CALCULES       = TPS_CALC ;

PASAPAS TAPAS;


MAIL_CAL ='EXTR' (TAPAS.MODELE) 'MAIL';



NB_PAS   ='DIME' TAPAS.'TEMPS';






* suivi de la temperature
TEMP1 = PROG ;TEMP2 = PROG ;LISTPUI = PROG;
ITER  = 0 ;
NBT1  = NB_PAS ;
REPETER BCL1  NBT1 ;
  TP1    = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) SURF_CERC   ;
  T1     = MINI ( TP1 ) ;
  TEMP1  = TEMP1 'ET' T1 ;
  TEMP2  = TEMP2 ET T_IMP;
  CH_PUI = REAC BL_PANIER (TAPAS.'TEMPERATURES'.ITER );
  VAL_PUI = MAXI (RESU CH_PUI);
  LISTPUI = LISTPUI ET VAL_PUI;
ITER = ITER + 1;
FIN BCL1 ;

TITRE ' EVOLUTION DES TEMPERATURES EN KELVIN' ;
EV11  = EVOL VERT MANU 'TEMPS (s)' TPS_CALC 'T (K)' TEMP1 ;
EV21  = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'T (K)' TEMP2 ;


TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1  = 'Temperature minimale du cercle' ;
TABDES.'TITRE'. 2  = 'Temperature imposee' ;
DESS (EV11 ET EV21) TABDES 'MIMA' 'LEGE';


TITRE 'Evolution de la puissance en fonction du temps avec temperature en kelvin' ;
EV31 = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'Q (W)' LISTPUI ;
EV41 = EVOL ROUG MANU 'TEMPS (s)' TPS_CALC 'E (J)' LISTPUI ;


TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1 = 'Puissance de chauffe' ;

DESS (EV31) TABDES 'MIMA' 'LEGE' ;


EV51 = PRIM EV41;
TITRE 'Evolution de energie en fonction du temps avec temperature en kelvin' ;
TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1 = 'Energie du totale du systeme' ;
DESS(EV51) TABDES 'MIMA' 'LEGE';


E_four_faux = INTG EV31;
LIST E_four_faux;

E_four_diff = E_four_faux - E_four_vrai;
EV_pui_diff = EV31 - EV3;

TITRE 'Evolution de la difference de puissance entre les cas temperature en kelvin et en celsius' ;
TABDES = TABLE; TABDES.'TITRE' = TABLE ;
TABDES.'TITRE'. 1 = 'Difference de puissance' ;
DESS EV_pui_diff TABDES 'MIMA' 'LEGE';

Critere='MAXI' 'ABS' ('EXTR' EV_pui_diff 'ORDO' 1);

  MESS 'Critere :' Critere ;
  
SI ((ABS Critere) >EG 1E-10 );
  MESS 'Erreur de puissance';
  ERRE 21 ;
FINSI;



FIN;