************************************
* Section : Mecanique Rupture
*******************************************
* Verification du modele GURSON2 (GTN) dans
* des cas degeneres ou on doit retrouver de
* la simple plasticite
*
* Verification que par defaut on a bien :
* - Q2 = 1.
* - Q3 = Q**2
*******************************************

OPTI 'DIME' 2 'ELEM' 'QUA8';

* MAILLAGE
P1 = 0. 0.;
P2 = 1. 0.;
P3 = 1. 1.;
P4 = 0. 1.;
D1 = DROI 1 P1 P2;
D2 = DROI 1 P2 P3;
D3 = DROI 1 P3 P4;
D4 = DROI 1 P4 P1;
Q1 = SURF (D1 ET D2 ET D3 ET D4);
* TRAC Q1;FIN;


************************
* PLASTICITE PARFAITE
************************

* GTN
MO_GTN = MODE Q1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE_ENDOM' 'GURSON2';
EV1 = EVOL 'MANU' (PROG 0. 1.) (PROG 5.E8 5.E8);
MA_GTN = MATE MO_GTN 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV1 'Q' 0. 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0.;

BL1 = BLOQ 'UY' D1;
BL2 = BLOQ 'UY' D3;
BL3 = BLOQ 'UX' D4;

X_DEP_I = 5.E-2;
DEP_I = DEPI BL2 X_DEP_I;
EV1 = EVOL 'MANU' (PROG 0. 1.)  (PROG 0. 1.);
CHAR1 = CHAR 'DIMP' DEP_I EV1;

TAB1 = TABLE ;
TAB1.'MODELE' = MO_GTN;
TAB1.'CARACTERISTIQUES' = MA_GTN;
TAB1.'BLOCAGES_MECANIQUES' = BL1 ET BL2 ET BL3;
TAB1.'CHARGEMENT' = CHAR1;
TAB1.'TEMPS_CALCULES' = PROG 0. PAS 0.1 1.;
TAB1.'VARIABLES_INTERNES' = TABL;
TAB1.'VARIABLES_INTERNES'.(0) = (ZERO MO_GTN 'VARINTER') + 
        (MANU 'CHML' MO_GTN 'VHWF' 0. 'TYPE' 'VARINTER' 'STRESSES');

PASAPAS TAB1;
PCUM_GTN = EVOL 'TEMP' TAB1 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

* PLASTICITE PARFAITE
MO_PP = MODE Q1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT';
MA_PP = MATE MO_PP 'YOUN' 2.E11 'NU' 0.3 'SIGY' 5.E8;

TAB2 = TABLE ;
TAB2.'MODELE' = MO_PP;
TAB2.'CARACTERISTIQUES' = MA_PP;
TAB2.'BLOCAGES_MECANIQUES' = TAB1.'BLOCAGES_MECANIQUES';
TAB2.'CHARGEMENT' = TAB1.'CHARGEMENT';
TAB2.'TEMPS_CALCULES' = TAB1.'TEMPS_CALCULES';

PASAPAS TAB2;
PCUM = EVOL 'TEMP' TAB2 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

ECART = (INTG (PCUM - PCUM_GTN)**2)**0.5;
LIM = ((INTG PCUM**2)**0.5) * 1.E-3;
MESS ECART LIM;
SI (ECART > LIM);
    MESS 'ERREUR DANS GURSON2 EN PLASTICITE PARFAITE';
    ERRE 5;
FINSI;


************************
* ECROUISSAGE LINEAIRE
************************

* GTN
EV2 = EVOL 'MANU' (PROG 0. 1.) (PROG 5.E8 1.E9);
MA_GTN = MATE MO_GTN 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV2 'Q' 0. 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0.;


TAB1 = TABLE ;
TAB1.'MODELE' = MO_GTN;
TAB1.'CARACTERISTIQUES' = MA_GTN;
TAB1.'BLOCAGES_MECANIQUES' = BL1 ET BL2 ET BL3;
TAB1.'CHARGEMENT' = CHAR1;
TAB1.'TEMPS_CALCULES' = PROG 0. PAS 0.1 1.;
TAB1.'VARIABLES_INTERNES' = TABL;
TAB1.'VARIABLES_INTERNES'.(0) = (ZERO MO_GTN 'VARINTER') + 
        (MANU 'CHML' MO_GTN 'VHWF' 0. 'TYPE' 'VARINTER' 'STRESSES');

PASAPAS TAB1;
PCUM_GTN = EVOL 'TEMP' TAB1 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

* ECROUISSAGE LINEAIRE
MO_PEL = MODE Q1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE';
MA_PEL = MATE MO_PEL 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV2;

TAB2 = TABLE ;
TAB2.'MODELE' = MO_PEL;
TAB2.'CARACTERISTIQUES' = MA_PEL;
TAB2.'BLOCAGES_MECANIQUES' = TAB1.'BLOCAGES_MECANIQUES';
TAB2.'CHARGEMENT' = TAB1.'CHARGEMENT';
TAB2.'TEMPS_CALCULES' = TAB1.'TEMPS_CALCULES';

PASAPAS TAB2;
PCUM = EVOL 'TEMP' TAB2 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

ECART = (INTG (PCUM - PCUM_GTN)**2)**0.5;
LIM = ((INTG PCUM**2)**0.5) * 1.E-3;
MESS ECART LIM;
SI (ECART > LIM);
    MESS 'ERREUR DANS GURSON2 AVEC ECROUISSAGE LINEAIRE';
    ERRE 5;
FINSI;


************************
* Q2 ET Q3 PAR DEFAUT
************************

* Q2 ET Q3 PAR DEFAUT
EV2 = EVOL 'MANU' (PROG 0. 1.) (PROG 5.E8 1.E9);
MA_DEF = MATE MO_GTN 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV2 'Q' 1.5 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0.;


TAB1 = TABLE ;
TAB1.'MODELE' = MO_GTN;
TAB1.'CARACTERISTIQUES' = MA_GTN;
TAB1.'BLOCAGES_MECANIQUES' = BL1 ET BL2 ET BL3;
TAB1.'CHARGEMENT' = CHAR1;
TAB1.'TEMPS_CALCULES' = PROG 0. PAS 0.1 1.;
TAB1.'VARIABLES_INTERNES' = TABL;
TAB1.'VARIABLES_INTERNES'.(0) = (ZERO MO_GTN 'VARINTER') + 
        (MANU 'CHML' MO_GTN 'VHWF' 0. 'TYPE' 'VARINTER' 'STRESSES');

PASAPAS TAB1;
PCUM_DEF = EVOL 'TEMP' TAB1 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

* Q2 ET Q3 DONNES EXPLICITEMENT
EV2 = EVOL 'MANU' (PROG 0. 1.) (PROG 5.E8 1.E9);
MA_EXP = MATE MO_GTN 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV2 'Q' 1.5 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0. 'Q2' 1. 'Q3' (1.5**2);


TAB2 = TABLE ;
TAB2.'MODELE' = MO_GTN;
TAB2.'CARACTERISTIQUES' = MA_EXP;
TAB2.'BLOCAGES_MECANIQUES' = TAB1.'BLOCAGES_MECANIQUES';
TAB2.'CHARGEMENT' = TAB1.'CHARGEMENT';
TAB2.'TEMPS_CALCULES' = TAB1.'TEMPS_CALCULES';
TAB2.'VARIABLES_INTERNES' = TABL;
TAB2.'VARIABLES_INTERNES'.(0) = TAB1.'VARIABLES_INTERNES'.(0);

PASAPAS TAB2;
PCUM_EXP = EVOL 'TEMP' TAB2 'VARIABLES_INTERNES' 'EPSE' 1 1 1;

ECART = (INTG (PCUM_DEF - PCUM_EXP)**2)**0.5;
LIM = ((INTG PCUM_EXP**2)**0.5) * 1.E-3;
MESS ECART LIM;
SI (ECART > LIM);
    MESS 'ERREUR DANS GURSON2 AVEC LES VALEURS PAR DEFAUT DE Q2 ET Q3';
    ERRE 5;
FINSI;

FIN;